设为首页收藏本站

晓东CAD家园-论坛

 找回密码
 立即注册

QQ登录

只需一步,快速开始

扫一扫,访问微社区

查看: 213|回复: 6

[源码] 带数字的字符串表的排序

[复制链接]

已领礼包: 19个

财富等级: 恭喜发财

发表于 2020-2-13 13:39:19 | 显示全部楼层 |阅读模式

马上注册,结交更多好友,享用更多功能,让你轻松玩转社区。

您需要 登录 才可以下载或查看,没有帐号?立即注册

x
本帖最后由 Lisphk 于 2020-2-13 13:49 编辑

  1. ;;Usage (SortStringWithNumberAsNumber '("A9" "A1" "A10" "B11" "B2" "B05"))
  2. ;;Return ("A1" "A9" "A10" "B2" "B05" "B11")
  3. (defun SortStringWithNumberAsNumber (ListOfString)
  4. ;;;Function Normalize (add 0 befor number) number in string
  5. ;;; Count normalize symbols set in variable count
  6.   (defun NormalizeNumberInString (str / ch i pat ret count buf)
  7.     (setq i        0
  8.           pat        '("0" "1" "2" "3" "4" "5" "6" "7" "8" "9")
  9.           ret        ""
  10.           count        4 ;_Count normalize symbols
  11.     ) ;_ end of setq
  12.     (while (/= (setq ch (substr str (setq i (1+ i)) 1)) "")
  13.       (if (vl-position ch pat)
  14.         (progn
  15.           (setq buf ch) ;_ end of setq
  16.           (while
  17.             (vl-position (setq ch (substr str (setq i (1+ i)) 1)) pat)
  18.              (setq buf (strcat buf ch))
  19.           ) ;_ end of while
  20.           (while (< (strlen buf) count) (setq buf (strcat "0" buf)))
  21.           (setq ret (strcat ret buf))
  22.         ) ;_ end of progn
  23.       ) ;_ end of if
  24.       (setq ret (strcat ret ch))
  25.     ) ;_ end of while
  26.     ret
  27.   ) ;_ end of defun
  28.   (vl-load-com)
  29.   (mapcar '(lambda (x) (nth x ListOfString))
  30.           (vl-sort-i (mapcar 'NormalizeNumberInString ListOfString)
  31.                      '<
  32.           ) ;_ end of VL-SORT-I
  33.   ) ;_ end of mapcar
  34. ) ;_ end of defun



  1. ;;Usage (SortStringWithNumberAsNumber '("A9" "A1" "A10" "B11" "B2" "B05") nil)
  2. ;;With ignore case (SortStringWithNumberAsNumber '("A9" "A1" "A10" "B11" "B2" "B05") t)
  3. ;;  CAB added Ignore Case Flag as an argument
  4. ;;Return ("A1" "A9" "A10" "B2" "B05" "B11")
  5. (defun SortStringWithNumberAsNumber
  6.        (ListOfString IgnoreCase / NorStrs count)
  7. ;;;Function Normalize (add 0 befor number) number in string
  8. ;;; Count normalize symbols set in variable count
  9. ;;; CAB added count as an argument
  10.   (defun NormalizeNumberInString (str count / ch i pat ret buf)
  11.     (setq i   0
  12.           pat '("0" "1" "2" "3" "4" "5" "6" "7" "8" "9")
  13.           ret ""
  14.     ) ;_ end of setq
  15.     (while (/= (setq ch (substr str (setq i (1+ i)) 1)) "")
  16.       (if (vl-position ch pat)
  17.         (progn
  18.           (setq buf ch) ;_ end of setq
  19.           (while
  20.             (vl-position (setq ch (substr str (setq i (1+ i)) 1)) pat)
  21.              (setq buf (strcat buf ch))
  22.           ) ;_ end of while
  23.           (while (< (strlen buf) count) (setq buf (strcat "0" buf)))
  24.           (setq ret (strcat ret buf))
  25.         ) ;_ end of progn
  26.       ) ;_ end of if
  27.       (setq ret (strcat ret ch))
  28.     ) ;_ end of while
  29.     ret
  30.   ) ;_ end of defun
  31.   ;;-------------------------------------------------
  32.   ;;  function to Count the longest number in string
  33.   ;;  CAB added to get the correct COUNT
  34.   (defun getcount (lst / count pat)
  35.     (setq count 0)
  36.     (setq pat '("0" "1" "2" "3" "4" "5" "6" "7" "8" "9"))
  37.     (mapcar
  38.       '(lambda (str / i maxlen ch)
  39.          (setq i 0
  40.                maxlen 0
  41.          )
  42.          (while        (/= (setq ch (substr str (setq i (1+ i)) 1)) "")
  43.            (if (vl-position ch pat)        ; number
  44.              (setq maxlen (1+ maxlen))
  45.              (setq count  (max count maxlen)
  46.                    maxlen 0
  47.              )
  48.            )
  49.          )
  50.          (setq count (max count maxlen)) ;_<<< ADD 21.06.2007 by VVA
  51.        )
  52.       Lst
  53.     )
  54.     count
  55.   )
  56.   ;;===============================================
  57.   (setq        count        (GetCount ListOfString)
  58.         NorStrs        (mapcar        '(lambda (x) (NormalizeNumberInString x count))
  59.                         ListOfString
  60.                 )
  61.   )
  62.   (and IgnoreCase (setq NorStrs (mapcar 'strcase NorStrs)))
  63.   (mapcar '(lambda (x) (nth x ListOfString))
  64.           (vl-sort-i NorStrs '<)
  65.   )
  66. ) ;_ end of defun



  1. ;; Alphanumerical Sort  -  Lee Mac
  2. ;; Sorts a list of strings containing a combination of alphabetical & numerical characters.

  3. (defun LM:alphanumsort (lst)
  4.   (mapcar (function (lambda (n) (nth n lst)))
  5.           (vl-sort-i (mapcar 'LM:splitstring lst)
  6.                      (function
  7.                        (lambda (a b / x y)
  8.                          (while
  9.                            (and
  10.                              (setq x (car a))
  11.                              (setq y (car b))
  12.                              (= x y)
  13.                            )
  14.                             (setq a (cdr a)
  15.                                   b (cdr b)
  16.                             )
  17.                          )
  18.                          (cond
  19.                            ((null x) b)
  20.                            ((null y) nil)
  21.                            ((and (numberp x) (numberp y)) (< x y))
  22.                            ((numberp x))
  23.                            ((numberp y) nil)
  24.                            ((< x y))
  25.                          )
  26.                        )
  27.                      )
  28.           )
  29.   )
  30. )


  31. ;; Split String  -  Lee Mac
  32. ;; Splits a string into a list of text and numbers

  33. (defun LM:splitstring (str)
  34.   (
  35.    (lambda (l)
  36.      (read
  37.        (strcat
  38.          "("
  39.          (vl-list->string
  40.            (apply
  41.              'append
  42.              (mapcar
  43.                (function
  44.                  (lambda (a b c)
  45.                    (cond
  46.                      ((= 92 b)
  47.                       (list 32 34 92 b 34 32)
  48.                      )
  49.                      ((or (< 47 b 58)
  50.                           (and (= 45 b) (< 47 c 58) (not (< 47 a 58)))
  51.                           (and (= 46 b) (< 47 a 58) (< 47 c 58))
  52.                       )
  53.                       (list b)
  54.                      )
  55.                      ((list 32 34 b 34 32))
  56.                    )
  57.                  )
  58.                )
  59.                (cons nil l)
  60.                l
  61.                (append (cdr l) '(()))
  62.              )
  63.            )
  64.          )
  65.          ")"
  66.        )
  67.      )
  68.    )
  69.     (vl-string->list str)
  70.   )
  71. )


  1. (defun c:test ()
  2.   (MySort '("T2A" "AS10" "T10B" "T1" "T2" "AS2" "T10" "T1A" "AS1" "T10A" "T1B" "T2B"))
  3. ;|
  4.   ALE=====>  ("AS1" "AS2" "AS10" "T1" "T2" "T10" "T10A" "T10B" "T1A" "T2A" "T1B" "T2B")
  5.   LM:=====>  ("AS1" "AS2" "AS10" "T1" "T1A" "T1B" "T2" "T2A" "T2B" "T10" "T10A" "T10B")
  6.   Antistar>  ("AS1" "AS2" "AS10" "T1" "T2" "T10" "T1A" "T2A" "T10A" "T1B" "T2B" "T10B") desired result
  7.   CAB=====>  ("AS1" "AS2" "AS10" "T1" "T1A" "T1B" "T2" "T2A" "T2B" "T10" "T10A" "T10B")

  8. |;
  9.   )

  10. ;;  CAB 01/30/14
  11. (defun parseNum        (str / lst tnum tstr)
  12.   (mapcar
  13.     (function
  14.       (lambda (x)
  15.         (cond
  16.           ((< 47 x 58)                        ; number
  17.            (if tstr
  18.              (setq lst        (cons (vl-list->string (reverse tstr)) lst)
  19.                    tstr        nil
  20.              )
  21.            )
  22.            (if tnum
  23.              (setq tnum (cons x tnum))
  24.              (setq tnum (list x))
  25.            )
  26.           )
  27.           (t                                ; non-number
  28.            (if tnum
  29.              (setq lst        (cons (atoi (vl-list->string (reverse tnum))) lst)
  30.                    tnum        nil
  31.              )
  32.            )
  33.            (if tstr
  34.              (setq tstr (cons x tstr))
  35.              (setq tstr (list x))
  36.            )
  37.           )
  38.         )
  39.       )
  40.     )
  41.     (vl-string->list str)
  42.   )
  43.   (if tstr
  44.     (setq lst (cons (vl-list->string (reverse tstr)) lst))
  45.   )
  46.   (if tnum
  47.     (setq lst (cons (atoi (vl-list->string (reverse tnum))) lst))
  48.   )
  49.   (reverse lst)
  50. )




  51. (defun MySort (lst)
  52.   (mapcar '(lambda (x) (nth x lst))
  53.           (vl-sort-i (mapcar '(lambda(x) (ParseNum x)) lst)
  54.                      '(lambda (e1 e2)
  55.                         (if (= (car e1) (car e2))
  56.                           (if (= (cadr e1) (cadr e2))
  57.                             (< (caddr e1) (caddr e2))
  58.                             (< (cadr e1) (cadr e2))
  59.                           )
  60.                           (< (car e1) (car e2))
  61.                         )
  62.                       )
  63.           )
  64.   )
  65. )


  1. (defun mysort ( l )
  2.     (vl-sort l
  3.         (function
  4.             (lambda ( a b / x y )
  5.                 (if (= (car  a) (car  b))
  6.                     (< (cadr a) (cadr b))
  7.                     (progn
  8.                         (setq a (LM:splitstring (car a))
  9.                               b (LM:splitstring (car b))
  10.                         )
  11.                         (while
  12.                             (and
  13.                                 (setq x (car a))
  14.                                 (setq y (car b))
  15.                                 (= x y)
  16.                             )
  17.                             (setq a (cdr a)
  18.                                   b (cdr b)
  19.                             )
  20.                         )
  21.                         (cond
  22.                             (   (null x) b)
  23.                             (   (null y) nil)
  24.                             (   (and (numberp x) (numberp y)) (< x y))
  25.                             (   (numberp x))
  26.                             (   (numberp y) nil)
  27.                             (   (< x y))
  28.                         )
  29.                     )
  30.                 )
  31.             )
  32.         )
  33.     )
  34. )

  35. ;; Split String  -  Lee Mac
  36. ;; Splits a string into a list of text and numbers

  37. (defun LM:splitstring ( str )
  38.     (
  39.         (lambda ( l )
  40.             (read
  41.                 (strcat "("
  42.                     (vl-list->string
  43.                         (apply 'append
  44.                             (mapcar
  45.                                 (function
  46.                                     (lambda ( a b c )
  47.                                         (cond
  48.                                             (   (= 92 b)
  49.                                                 (list 32 34 92 b 34 32)
  50.                                             )
  51.                                             (   (or (< 47 b 58)
  52.                                                     (and (= 45 b) (< 47 c 58) (not (< 47 a 58)))
  53.                                                     (and (= 46 b) (< 47 a 58) (< 47 c 58))
  54.                                                 )
  55.                                                 (list b)
  56.                                             )
  57.                                             (   (list 32 34 b 34 32))
  58.                                         )
  59.                                     )
  60.                                 )
  61.                                 (cons nil l) l (append (cdr l) '(( )))
  62.                             )
  63.                         )
  64.                     )
  65.                     ")"
  66.                 )
  67.             )
  68.         )
  69.         (vl-string->list str)
  70.     )
  71. )



  1. ;|
  2. _$ (mysort '(("A.05" 12.34 "Regular") ("A.10" 34.54 "BigSize") ("B.9" 66.73 "Regular") ("A.10" 12.12 "BigSize") ("A.05" 12.55 "BigSize")))
  3. (("A.05" 12.34 "Regular") ("A.05" 12.55 "BigSize") ("A.10" 12.12 "BigSize") ("A.10" 34.54 "BigSize") ("B.9" 66.73 "Regular"))
  4. |;



  1. (setq lst (list "PN375-A10.dwg"
  2.       "PN375-A9.dwg"
  3.       "PN375-A04.dwg"
  4.       "PN375-A555.dwg"               
  5.       "PN375-D1.dwg"
  6.       "PN375-D10.dwg"
  7.       "PN375-D14.dwg"
  8.       "PN375-D2.dwg"
  9.       "PN375-D22.dwg"
  10.       "PN375-D7r3.dwg"
  11.       "PN375-DB.dwg"
  12.       "PN375-DB10a.dwg"
  13.       "PN375-DB9.dwg"))

  14. (mapcar '(lambda(x)(terpri)(princ x))
  15.         (SortStringWithNumberAsNumber lst))



("PN375-A10.dwg" "PN375-A9.dwg" "PN375-A04.dwg" "PN375-A555.dwg" "PN375-D1.dwg" "PN375-D10.dwg" "PN375-D14.dwg" "PN375-D2.dwg" "PN375-D22.dwg" "PN375-D7r3.dwg" "PN375-DB.dwg" "PN375-DB10a.dwg" "PN375-DB9.dwg")
_$

PN375-A04.dwg
PN375-A9.dwg
PN375-A10.dwg
PN375-A555.dwg
PN375-D1.dwg
PN375-D2.dwg
PN375-D7r3.dwg
PN375-D10.dwg
PN375-D14.dwg
PN375-D22.dwg
PN375-DB.dwg
PN375-DB9.dwg
PN375-DB10a.dwg
("PN375-A04.dwg" "PN375-A9.dwg" "PN375-A10.dwg" "PN375-A555.dwg" "PN375-D1.dwg" "PN375-D2.dwg" "PN375-D7r3.dwg" "PN375-D10.dwg" "PN375-D14.dwg" "PN375-D22.dwg" "PN375-DB.dwg" "PN375-DB9.dwg" "PN375-DB10a.dwg")
_$


论坛插件加载方法
发帖求助前要善用【论坛搜索】功能,那里可能会有你要找的答案;
如果你在论坛求助问题,并且已经从坛友或者管理的回复中解决了问题,请把帖子标题加上【已解决】;
如何回报帮助你解决问题的坛友,一个好办法就是给对方加【D豆】,加分不会扣除自己的积分,做一个热心并受欢迎的人!

已领礼包: 75个

财富等级: 招财进宝

发表于 2020-2-13 16:36:15 | 显示全部楼层
疫情时刻,保持一颗安静的心做功课,赞!
论坛插件加载方法
发帖求助前要善用【论坛搜索】功能,那里可能会有你要找的答案;
如果你在论坛求助问题,并且已经从坛友或者管理的回复中解决了问题,请把帖子标题加上【已解决】;
如何回报帮助你解决问题的坛友,一个好办法就是给对方加【D豆】,加分不会扣除自己的积分,做一个热心并受欢迎的人!
回复 支持 反对

使用道具 举报

已领礼包: 3029个

财富等级: 富可敌国

发表于 2020-2-15 00:00:50 | 显示全部楼层
论坛插件加载方法
发帖求助前要善用【论坛搜索】功能,那里可能会有你要找的答案;
如果你在论坛求助问题,并且已经从坛友或者管理的回复中解决了问题,请把帖子标题加上【已解决】;
如何回报帮助你解决问题的坛友,一个好办法就是给对方加【D豆】,加分不会扣除自己的积分,做一个热心并受欢迎的人!
回复

使用道具 举报

已领礼包: 3029个

财富等级: 富可敌国

发表于 2020-2-17 00:00:46 | 显示全部楼层
论坛插件加载方法
发帖求助前要善用【论坛搜索】功能,那里可能会有你要找的答案;
如果你在论坛求助问题,并且已经从坛友或者管理的回复中解决了问题,请把帖子标题加上【已解决】;
如何回报帮助你解决问题的坛友,一个好办法就是给对方加【D豆】,加分不会扣除自己的积分,做一个热心并受欢迎的人!
回复

使用道具 举报

已领礼包: 180个

财富等级: 日进斗金

发表于 2020-3-26 16:59:43 | 显示全部楼层
doslib有个函数,能对这种数字、字母混合的排序,很好用。
(dos_strsort lst -1)
结果为:
("PN375-A04.dwg" "PN375-A9.dwg" "PN375-A10.dwg" "PN375-A555.dwg" "PN375-D1.dwg" "PN375-D2.dwg" "PN375-D7r3.dwg" "PN375-D10.dwg" "PN375-D14.dwg" "PN375-D22.dwg" "PN375-DB.dwg" "PN375-DB9.dwg" "PN375-DB10a.dwg")
论坛插件加载方法
发帖求助前要善用【论坛搜索】功能,那里可能会有你要找的答案;
如果你在论坛求助问题,并且已经从坛友或者管理的回复中解决了问题,请把帖子标题加上【已解决】;
如何回报帮助你解决问题的坛友,一个好办法就是给对方加【D豆】,加分不会扣除自己的积分,做一个热心并受欢迎的人!
回复 支持 反对

使用道具 举报

已领礼包: 391个

财富等级: 日进斗金

发表于 2020-3-27 07:36:47 | 显示全部楼层
很好的帖子,多谢分享了
论坛插件加载方法
发帖求助前要善用【论坛搜索】功能,那里可能会有你要找的答案;
如果你在论坛求助问题,并且已经从坛友或者管理的回复中解决了问题,请把帖子标题加上【已解决】;
如何回报帮助你解决问题的坛友,一个好办法就是给对方加【D豆】,加分不会扣除自己的积分,做一个热心并受欢迎的人!
回复 支持 反对

使用道具 举报

发表于 2020-5-24 13:54:58 | 显示全部楼层
谢谢楼主!!!正在学习这方面的
论坛插件加载方法
发帖求助前要善用【论坛搜索】功能,那里可能会有你要找的答案;
如果你在论坛求助问题,并且已经从坛友或者管理的回复中解决了问题,请把帖子标题加上【已解决】;
如何回报帮助你解决问题的坛友,一个好办法就是给对方加【D豆】,加分不会扣除自己的积分,做一个热心并受欢迎的人!
回复 支持 反对

使用道具 举报

您需要登录后才可以回帖 登录 | 立即注册

本版积分规则

QQ|申请友链|小黑屋|手机版|Archiver|辽公网安备|晓东CAD家园 ( 辽ICP备15016793号 )  

GMT+8, 2020-9-28 03:39 , Processed in 0.147474 second(s), 50 queries , Gzip On, WinCache On.

Powered by Discuz! X3.4

Copyright © 2001-2020, Tencent Cloud.

快速回复 返回顶部 返回列表