块内图元复制到块外

dcl1214 · 发表于 2020-5-19 22:10:35

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

本帖最后由 dcl1214 于 2020-9-4 22:43 编辑

(defun $kuai-nei-fu-zhi-dao-kuai-wai$
(ent lst / dxf ents ents-new pt-blk)
;块内图元复制到块外
(if (and ent
(= (type ent) 'ename)
(= (cdr (assoc 0 (entget ent))) "INSERT")
)
(progn
(SETQ PT-BLK (vl-catch-all-apply
'vlax-safearray->list
(list (vlax-variant-value
(vla-get-insertionpoint
(vlax-ename->vla-object ent)
)
)
) ;插入点
)
)
(progn
(setq ents nil)
(setq Ent (tblobjname "BLOCK" (cdr (assoc 2 (entget ent)))))
(while (and ent (setq Ent (entnext Ent)))
(if (wcmatch (cdr (assoc 0 (setq dxf (entget Ent))))
"[,LINE,*LINE,]"
)
(set 'ents (cons ent ents))
)
)
(setq ents (reverse ents))
)
(setq ents-new (MAPCAR
(FUNCTION
(LAMBDA (ENT / zt new)
(if
(not
(vl-catch-all-error-p
(setq
zt
(vl-catch-all-apply
'vlax-invoke
(LIST
(vla-get-activedocument
(vlax-get-acad-object)
)
'copyobjects
(list (vl-catch-all-apply
'vlax-ename->vla-object
(list ent)
)
)
(vla-get-modelSpace
(vla-get-activedocument
(vlax-get-acad-object)
)
)
)
)
)
)
)
(setq new (entlast))
(vl-catch-all-error-message zt)
)
new
)
)
ents
)
)
(setq ents-new (vl-remove nil ents-new))
(and PT-BLK
ents-new
(MAPCAR (FUNCTION (LAMBDA (A)
(VLA-MOVE (VLAX-ENAME->VLA-OBJECT A)
(VLAX-3D-POINT (LIST 0 0 0))
(VLAX-3D-POINT PT-BLK)
)
)
)
ents-new
)
)
)
)
ents-new
)
($kuai-nei-fu-zhi-dao-kuai-wai$ (car (entsel)) nil)
(defun ncopym (ent / blk en lst lx
ly lz make-anonymous-block mark
mat mat:mxm mat:mxv mat:trp mxm mxv
new news obj ownrobj parent ref
refgeom sclmat sx sy sz trp
trsmat vararray->list vv vx vy
vz
)
;; RefGeom (gile)
;; Returns a list whose first item is a 3x3 transformation matrix and
;; second item the object insertion point in its parent (xref, block or space)
(defun refgeom (ent / ang enx mat ocs)
(and ent
(setq enx (entget ent))
(setq ang (cdr (assoc 050 enx)))
(setq ocs (cdr (assoc 210 enx)))
)
(list
(setq mat
(mxm
(mapcar '(lambda (v) (trans v 0 ocs t))
'((1.0 0.0 0.0)
(0.0 1.0 0.0)
(0.0 0.0 1.0)
)
)
(mxm
(list
(list (cos ang) (- (sin ang)) 0.0)
(list (sin ang) (cos ang) 0.0)
'(0.0 0.0 1.0)
)
(list
(list (cdr (assoc 41 enx)) 0.0 0.0)
(list 0.0 (cdr (assoc 42 enx)) 0.0)
(list 0.0 0.0 (cdr (assoc 43 enx)))
)
)
)
)
(mapcar
'-
(trans (cdr (assoc 10 enx)) ocs 0)
(mxv mat
(cdr (assoc 10 (tblsearch "block" (cdr (assoc 2 enx)))))
)
)
)
)
(defun VarArray->List (vaobj)
(vlax-SafeArray->List
(vlax-Variant-Value vaobj)
)
)
;; Matrix Transpose - Doug Wilson
;; Args: m - nxn matrix
(defun trp (m)
(apply 'mapcar (cons 'list m))
)
;; Matrix x Matrix - Vladimir Nesterovsky
;; Args: m,n - nxn matrices
(defun mxm (m n)
((lambda (a) (mapcar '(lambda (r) (mxv a r)) m)) (trp n))
)
;; Matrix x Vector - Vladimir Nesterovsky
;; Args: m - nxn matrix, v - vector in R^n
(defun mxv (m v)
(mapcar '(lambda (r) (apply '+ (mapcar '* r v))) m)
)
;;;-----------------------------------------------------------;;
;;; 矩阵转置 ;;
;;; MAT:trp Transpose a matrix -Doug Wilson- ;;
;;;-----------------------------------------------------------;;
(defun MAT:trp (m)
(apply 'mapcar (cons 'list m))
)
;;;-----------------------------------------------------------;;
;;; 向量的矩阵变换(向量乘矩阵) ;;
;;; Matrix x Vector - Vladimir Nesterovsky ;;
;;; Args: m - nxn matrix, v - vector in R^n ;;
;;;-----------------------------------------------------------;;
(defun MAT:mxv (m v)
(mapcar (function (lambda (r) (apply '+ (mapcar '* r v))))
m
)
)
;;;-----------------------------------------------------------;;
;;; 矩阵相乘 ;;
;;; MAT:mxm Multiply two matrices -Vladimir Nesterovsky- ;;
;;;-----------------------------------------------------------;;
(defun MAT:mxm (m q)
(mapcar (function (lambda (r) (MAT:mxv (MAT:trp q) r))) m)
)
;;;-----------------------------------------------------------;;
;;; 匿名块程序 ;;
;;;-----------------------------------------------------------;;
(defun make-anonymous-block (obj / BLKOBJ origin bkName *space)
(if obj
(progn
(setq origin (vlax-3d-point '(0.0 0.0 0.0)))
(setq blkobj
(vla-add (vla-get-blocks
(vla-get-activedocument (vlax-get-acad-object))
)
origin
"*U"
)
)
(setq bkName (vla-get-name blkobj))
(vlax-invoke
(vla-get-activedocument (vlax-get-acad-object))
'copyobjects
(list obj)
blkobj
)
(if (zerop (vla-get-ActiveSpace
(vla-get-activedocument (vlax-get-acad-object))
)
)
(setq
*space (vla-get-PaperSpace
(vla-get-activedocument (vlax-get-acad-object))
)
)
(setq
*space (vla-get-modelspace
(vla-get-activedocument (vlax-get-acad-object))
)
)
)
(vla-insertblock *space origin bkName 1 1 1 0)
)
)
blkobj
)
(if (and ent (= (CDR (ASSOC 0 (ENTGET ENT))) "INSERT"))
(PROGN
(setq
mark (VLAX-VLA-OBJECT->ENAME
(VLA-ADDPOINT
(vla-get-ModelSpace
(vla-get-ActiveDocument
(vlax-get-acad-object)
)
)
(VLAX-3D-POINT (LIST 0 0 0))
)
)
) ;获取最后一个图元作为标记位
(progn
(setvar 'errno 0)
(IF (= 'ename (type ent))
(PROGN
(setq obj (vlax-ename->vla-object ent))
(progn
(setq mat
(vlax-tmatrix
(apply
(function
(lambda (mat vec)
(append (mapcar 'append mat (mapcar 'list vec))
'((0.0 0.0 0.0 1.0))
)
)
)
(refgeom ent)
)
)
)
(setq vv (reverse (cdr (reverse (varArray->List mat)))))
;去掉第四行(0 0 0 1)
(setq vX (mapcar 'car vv)) ;X 向量
(setq vY (mapcar 'cadr vv)) ;Y 向量
(setq vZ (mapcar 'caddr vv)) ;Z 向量
(setq lX (distance vX '(0 0 0))) ;X 比例因子
(setq lY (distance vY '(0 0 0))) ;Y 比例因子
(setq lZ (distance vZ '(0 0 0))) ;Z 比例因子
(vlax-for obj (vla-item (vla-get-blocks
(vla-get-activedocument
(vlax-get-acad-object)
)
)
(vla-get-name obj)
)
(setq lst (cons obj lst))
)
(if lst
(foreach obj lst
(if (and (equal lX lY 1e-17) (equal lY lZ 1e-17))
;如果是均匀缩放
(progn
(setq
OwnrObj (vla-get-Modelspace
(vla-get-activedocument
(vlax-get-acad-object)
)
)
)
(vl-catch-all-apply
'vlax-invoke
(list
(vla-get-activedocument
(vlax-get-acad-object)
)
'copyobjects
(list obj)
OwnrObj
)
)
(setq new (vlax-ename->vla-object (entlast)))
(vla-transformby new mat)
)
(progn
(and (setq blk (make-anonymous-block obj))
;先做一个匿名图块
(setq ref (vlax-ename->vla-object (entlast)))
;插入块参照
)
(setq sX (/ 1 lx))
;非均匀缩放则要取得各个比例值
(setq sY (/ 1 lY))
(setq sZ (/ 1 lZ))
(setq sclMat (list (list sX 0 0 1)
;乘以一个比例缩放矩阵使得比例均匀
(list 0 sY 0 1)
(list 0 0 sZ 1)
(list 0 0 0 1)
)
)
(setq
trsmat (MAT:mxm (varArray->List mat) sclMat)
) ;得到一个均匀缩放的变换矩阵
(vla-transformby ref (vlax-tmatrix trsmat))
;变换参照
;;最后需要变换回去
(vla-put-xscalefactor
ref
(* (vla-get-xscalefactor ref) lX)
)
(vla-put-yscalefactor
ref
(* (vla-get-yscalefactor ref) lY)
)
(vla-put-zscalefactor
ref
(* (vla-get-zscalefactor ref) lZ)
)
(vlax-put ref 'insertionpoint (mapcar 'last vv))
;(vla-Explode ref)
(vl-cmdf "explode" (vlax-vla-object->ename ref))
;炸开匿名块参照
(vla-delete blk) ;删除匿名块定义
)
)
)
)
)
)
)
)
(progn
(setq NEWS nil)
(setq en mark)
(while (setq en (entnext en))
(setq NEWS (cons en NEWS))
)
(SETQ NEWS (VL-REMOVE NIL NEWS))
(setq parent nil)
(setq NEWS
(mapcar
(function (lambda (a)
(cond
((and
(= (cdr (assoc 0 (entget a))) "SEQEND")
(cdr (assoc -2 (entget a)))
)
(set 'parent (cdr (assoc -2 (entget a))))
nil
)
((and
parent
(= (cdr (assoc 5 (entget a)))
(cdr (assoc 5 (entget parent)))
)
)
(set 'parent nil)
a
)
((AND parent)
nil
)
(t a)
)
)
)
NEWS
)
)
(ENTDEL mark)
(setq NEWS (reverse (vl-remove nil NEWS)))
(setq
NEWS (vl-remove-if-not
(function (lambda (a) (entget a)))
NEWS
)
)
)
)
)
NEWS
)
(setq dd (ncopym (car (entsel))))

(defun $kuai-nei-fu-zhi-dao-kuai-wai$ 
       (ent lst / dxf ents ents-new pt-blk) 
                                        ;块内图元复制到块外 
  (if (and ent 
           (= (type ent) 'ename) 
           (= (cdr (assoc 0 (entget ent))) "INSERT") 
      ) 
    (progn 
      (SETQ PT-BLK (vl-catch-all-apply 
                     'vlax-safearray->list 
                     (list (vlax-variant-value 
                             (vla-get-insertionpoint 
                               (vlax-ename->vla-object ent) 
                             ) 
                           ) 
                     )                        ;插入点 
                   ) 
      ) 
      (progn 
        (setq ents nil) 
        (setq Ent (tblobjname "BLOCK" (cdr (assoc 2 (entget ent))))) 
        (while (and ent (setq Ent (entnext Ent))) 
          (if (wcmatch (cdr (assoc 0 (setq dxf (entget Ent)))) 
                       "[,LINE,*LINE,]" 
              ) 
            (set 'ents (cons ent ents)) 
          ) 
        ) 
        (setq ents (reverse ents)) 
      ) 
      (setq ents-new (MAPCAR 
                       (FUNCTION 
                         (LAMBDA (ENT / zt new) 
                           (if 
                             (not 
                               (vl-catch-all-error-p 
                                 (setq 
                                   zt 
                                    (vl-catch-all-apply 
                                      'vlax-invoke 
                                      (LIST 
                                        (vla-get-activedocument 
                                          (vlax-get-acad-object) 
                                        ) 
                                        'copyobjects 
                                        (list (vl-catch-all-apply 
                                                'vlax-ename->vla-object 
                                                (list ent) 
                                              ) 
                                        ) 
                                        (vla-get-modelSpace 
                                          (vla-get-activedocument 
                                            (vlax-get-acad-object) 
                                          ) 
                                        ) 
                                      ) 
                                    ) 
                                 ) 
                               ) 
                             ) 
                              (setq new (entlast)) 
                              (vl-catch-all-error-message zt) 
                           ) 
                           new 
                         ) 
                       ) 
                       ents 
                     ) 
      ) 
      (setq ents-new (vl-remove nil ents-new)) 
      (and PT-BLK 
           ents-new 
           (MAPCAR (FUNCTION (LAMBDA (A) 
                               (VLA-MOVE (VLAX-ENAME->VLA-OBJECT A) 
                                         (VLAX-3D-POINT (LIST 0 0 0)) 
                                         (VLAX-3D-POINT PT-BLK) 
                               ) 
                             ) 
                   ) 
                   ents-new 
           ) 
      ) 
    ) 
  ) 
  ents-new 
) 
($kuai-nei-fu-zhi-dao-kuai-wai$ (car (entsel)) nil) 
 
(defun ncopym (ent        /         blk          en           lst            lx 
               ly        lz         make-anonymous-block            mark 
               mat        mat:mxm         mat:mxv  mat:trp  mxm            mxv 
               new        news         obj          ownrobj  parent   ref 
               refgeom        sclmat         sx          sy           sz            trp 
               trsmat        vararray->list          vv           vx            vy 
               vz 
              ) 
  ;; RefGeom (gile) 
  ;; Returns a list whose first item is a 3x3 transformation matrix and 
  ;; second item the object insertion point in its parent (xref, block or space) 
  (defun refgeom (ent / ang enx mat ocs) 
    (and ent 
         (setq enx (entget ent)) 
         (setq ang (cdr (assoc 050 enx))) 
         (setq ocs (cdr (assoc 210 enx))) 
    ) 
    (list 
      (setq mat 
             (mxm 
               (mapcar '(lambda (v) (trans v 0 ocs t)) 
                       '((1.0 0.0 0.0) 
                         (0.0 1.0 0.0) 
                         (0.0 0.0 1.0) 
                        ) 
               ) 
               (mxm 
                 (list 
                   (list (cos ang) (- (sin ang)) 0.0) 
                   (list (sin ang) (cos ang) 0.0) 
                   '(0.0 0.0 1.0) 
                 ) 
                 (list 
                   (list (cdr (assoc 41 enx)) 0.0 0.0) 
                   (list 0.0 (cdr (assoc 42 enx)) 0.0) 
                   (list 0.0 0.0 (cdr (assoc 43 enx))) 
                 ) 
               ) 
             ) 
      ) 
      (mapcar 
        '- 
        (trans (cdr (assoc 10 enx)) ocs 0) 
        (mxv mat 
             (cdr (assoc 10 (tblsearch "block" (cdr (assoc 2 enx))))) 
        ) 
      ) 
    ) 
  ) 
  (defun VarArray->List        (vaobj) 
    (vlax-SafeArray->List 
      (vlax-Variant-Value vaobj) 
    ) 
  ) 
  ;; Matrix Transpose  -  Doug Wilson 
  ;; Args: m - nxn matrix 
  (defun trp (m) 
    (apply 'mapcar (cons 'list m)) 
  ) 
  ;; Matrix x Matrix  -  Vladimir Nesterovsky 
  ;; Args: m,n - nxn matrices 
  (defun mxm (m n) 
    ((lambda (a) (mapcar '(lambda (r) (mxv a r)) m)) (trp n)) 
  ) 
  ;; Matrix x Vector  -  Vladimir Nesterovsky 
  ;; Args: m - nxn matrix, v - vector in R^n 
  (defun mxv (m v) 
    (mapcar '(lambda (r) (apply '+ (mapcar '* r v))) m) 
  ) 
;;;-----------------------------------------------------------;; 
;;; 矩阵转置                                                  ;; 
;;; MAT:trp Transpose a matrix -Doug Wilson-                  ;; 
;;;-----------------------------------------------------------;; 
  (defun MAT:trp (m) 
    (apply 'mapcar (cons 'list m)) 
  ) 
;;;-----------------------------------------------------------;; 
;;; 向量的矩阵变换(向量乘矩阵)                                ;; 
;;; Matrix x Vector - Vladimir Nesterovsky                    ;; 
;;; Args: m - nxn matrix, v - vector in R^n                   ;; 
;;;-----------------------------------------------------------;; 
  (defun MAT:mxv (m v) 
    (mapcar (function (lambda (r) (apply '+ (mapcar '* r v)))) 
            m 
    ) 
  ) 
;;;-----------------------------------------------------------;; 
;;; 矩阵相乘                                                  ;; 
;;; MAT:mxm Multiply two matrices -Vladimir Nesterovsky-      ;; 
;;;-----------------------------------------------------------;; 
  (defun MAT:mxm (m q) 
    (mapcar (function (lambda (r) (MAT:mxv (MAT:trp q) r))) m) 
  ) 
;;;-----------------------------------------------------------;; 
;;; 匿名块程序                                                ;; 
;;;-----------------------------------------------------------;; 
  (defun make-anonymous-block (obj / BLKOBJ origin bkName *space) 
    (if        obj 
      (progn 
        (setq origin (vlax-3d-point '(0.0 0.0 0.0))) 
        (setq blkobj 
               (vla-add        (vla-get-blocks 
                          (vla-get-activedocument (vlax-get-acad-object)) 
                        ) 
                        origin 
                        "*U" 
               ) 
        ) 
        (setq bkName (vla-get-name blkobj)) 
        (vlax-invoke 
          (vla-get-activedocument (vlax-get-acad-object)) 
          'copyobjects 
          (list obj) 
          blkobj 
        ) 
        (if (zerop (vla-get-ActiveSpace 
                     (vla-get-activedocument (vlax-get-acad-object)) 
                   ) 
            ) 
          (setq 
            *space (vla-get-PaperSpace 
                     (vla-get-activedocument (vlax-get-acad-object)) 
                   ) 
          ) 
          (setq 
            *space (vla-get-modelspace 
                     (vla-get-activedocument (vlax-get-acad-object)) 
                   ) 
          ) 
        ) 
        (vla-insertblock *space origin bkName 1 1 1 0) 
      ) 
    ) 
    blkobj 
  ) 
  (if (and ent (= (CDR (ASSOC 0 (ENTGET ENT))) "INSERT")) 
    (PROGN 
      (setq 
        mark (VLAX-VLA-OBJECT->ENAME 
               (VLA-ADDPOINT 
                 (vla-get-ModelSpace 
                   (vla-get-ActiveDocument 
                     (vlax-get-acad-object) 
                   ) 
                 ) 
                 (VLAX-3D-POINT (LIST 0 0 0)) 
               ) 
             ) 
      )                                        ;获取最后一个图元作为标记位 
      (progn 
        (setvar 'errno 0) 
        (IF (= 'ename (type ent)) 
          (PROGN 
            (setq obj (vlax-ename->vla-object ent)) 
            (progn 
              (setq mat 
                     (vlax-tmatrix 
                       (apply 
                         (function 
                           (lambda (mat vec) 
                             (append (mapcar 'append mat (mapcar 'list vec)) 
                                     '((0.0 0.0 0.0 1.0)) 
                             ) 
                           ) 
                         ) 
                         (refgeom ent) 
                       ) 
                     ) 
              ) 
              (setq vv (reverse (cdr (reverse (varArray->List mat))))) 
                                        ;去掉第四行(0 0 0 1) 
              (setq vX (mapcar 'car vv)) ;X 向量 
              (setq vY (mapcar 'cadr vv)) ;Y 向量 
              (setq vZ (mapcar 'caddr vv)) ;Z 向量 
              (setq lX (distance vX '(0 0 0))) ;X 比例因子 
              (setq lY (distance vY '(0 0 0))) ;Y 比例因子 
              (setq lZ (distance vZ '(0 0 0))) ;Z 比例因子                
              (vlax-for        obj (vla-item (vla-get-blocks 
                                        (vla-get-activedocument 
                                          (vlax-get-acad-object) 
                                        ) 
                                      ) 
                                      (vla-get-name obj) 
                            ) 
                (setq lst (cons obj lst)) 
              ) 
              (if lst 
                (foreach obj lst 
                  (if (and (equal lX lY 1e-17) (equal lY lZ 1e-17)) 
                                        ;如果是均匀缩放 
                    (progn 
                      (setq 
                        OwnrObj        (vla-get-Modelspace 
                                  (vla-get-activedocument 
                                    (vlax-get-acad-object) 
                                  ) 
                                ) 
                      ) 
                      (vl-catch-all-apply 
                        'vlax-invoke 
                        (list 
                          (vla-get-activedocument 
                            (vlax-get-acad-object) 
                          ) 
                          'copyobjects 
                          (list obj) 
                          OwnrObj 
                        ) 
                      ) 
                      (setq new (vlax-ename->vla-object (entlast))) 
                      (vla-transformby new mat) 
                    ) 
                    (progn 
                      (and (setq blk (make-anonymous-block obj)) 
                                        ;先做一个匿名图块 
                           (setq ref (vlax-ename->vla-object (entlast))) 
                                        ;插入块参照 
                      ) 
                      (setq sX (/ 1 lx)) 
                                        ;非均匀缩放则要取得各个比例值 
                      (setq sY (/ 1 lY)) 
                      (setq sZ (/ 1 lZ)) 
                      (setq sclMat (list (list sX 0 0 1) 
                                        ;乘以一个比例缩放矩阵使得比例均匀 
                                         (list 0 sY 0 1) 
                                         (list 0 0 sZ 1) 
                                         (list 0 0 0 1) 
                                   ) 
                      ) 
                      (setq 
                        trsmat (MAT:mxm (varArray->List mat) sclMat) 
                      )                        ;得到一个均匀缩放的变换矩阵 
                      (vla-transformby ref (vlax-tmatrix trsmat)) 
                                        ;变换参照 
                      ;;最后需要变换回去 
                      (vla-put-xscalefactor 
                        ref 
                        (* (vla-get-xscalefactor ref) lX) 
                      ) 
                      (vla-put-yscalefactor 
                        ref 
                        (* (vla-get-yscalefactor ref) lY) 
                      ) 
                      (vla-put-zscalefactor 
                        ref 
                        (* (vla-get-zscalefactor ref) lZ) 
                      ) 
                      (vlax-put ref 'insertionpoint (mapcar 'last vv)) 
                                        ;(vla-Explode ref) 
                      (vl-cmdf "explode" (vlax-vla-object->ename ref)) 
                                        ;炸开匿名块参照 
                      (vla-delete blk)        ;删除匿名块定义                  
                    ) 
                  ) 
                ) 
              ) 
            ) 
          ) 
        ) 
      ) 
      (progn 
        (setq NEWS nil) 
        (setq en mark) 
        (while (setq en (entnext en)) 
          (setq NEWS (cons en NEWS)) 
        ) 
        (SETQ NEWS (VL-REMOVE NIL NEWS)) 
        (setq parent nil) 
        (setq NEWS 
               (mapcar 
                 (function (lambda (a) 
                             (cond 
                               ((and 
                                  (= (cdr (assoc 0 (entget a))) "SEQEND") 
                                  (cdr (assoc -2 (entget a))) 
                                ) 
                                (set 'parent (cdr (assoc -2 (entget a)))) 
                                nil 
                               ) 
                               ((and 
                                  parent 
                                  (= (cdr (assoc 5 (entget a))) 
                                     (cdr (assoc 5 (entget parent))) 
                                  ) 
                                ) 
                                (set 'parent nil) 
                                a 
                               ) 
                               ((AND parent) 
                                nil 
                               ) 
                               (t a) 
                             ) 
                           ) 
                 ) 
                 NEWS 
               ) 
        ) 
        (ENTDEL mark) 
        (setq NEWS (reverse (vl-remove nil NEWS))) 
        (setq 
          NEWS (vl-remove-if-not 
                 (function (lambda (a) (entget a))) 
                 NEWS 
               ) 
        ) 
      ) 
    ) 
  ) 
  NEWS 
) 
(setq dd (ncopym (car (entsel))))

Lisphk · 发表于 2020-5-19 23:43:10

能不能原位在INSERT上复制出来？

tzfcn · 发表于 2020-5-20 00:03:55

好代码。使用起来更方便了。

tanjurun · 发表于 2020-5-20 08:53:38

这个怎样用呢？请问楼主

dcl1214 · 发表于 2020-5-25 16:14:06

tanjurun 发表于 2020-5-20 08:53
这个怎样用呢？请问楼主

这个只是复制一个图元，你需要循环找到你的块中块，找到后调用我这个代码就能复制到外面了

原地踏步 · 发表于 2020-5-27 22:10:10

最好能举个调用的例子，更能明白些。

dcl1214 · 发表于 2020-9-4 22:43:52

Lisphk 发表于 2020-5-19 23:43
能不能原位在INSERT上复制出来？

支持原位复制了，请看上面的代码

xvjiex · 发表于 2021-1-9 00:26:41

块内图元复制到块外，感谢分享！

huxu823 · 发表于 2021-1-16 12:55:30

命令是什么？

xxchemkin · 发表于 2021-1-16 20:24:09

和Express扩展工具“NCOPY”命令有什么区别联系。

nochao · 发表于 2021-10-19 17:38:46

块内复制，支持多选吗

账号		自动登录	找回密码
密码			立即注册

[每日一码] 块内图元复制到块外

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

点评

点评