获得选择集的包围框

marting · 发表于 2021-1-20 04:51:24

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

(defun SSBoundingBox ( ss / _GetBoundingBox _SStoObjects _Main )
(defun _GetBoundingBox ( object / p1 p2 )
(vl-catch-all-apply
'(lambda ()
(vlax-invoke-method
object
'GetBoundingBox
'p1
'p2
)
)
)
(if p1
( (lambda (data)
(mapcar
'(lambda (funcs)
(mapcar
'(lambda (func)
(apply func data)
)
funcs
)
)
'( (caar cadar)
(caadr cadar)
(caadr cadadr)
(caar cadadr)
)
)
)
(list
(mapcar
'vlax-safearray->list
(list p1 p2)
)
)
)
)
)
(defun _SStoObjects ( ss / i objects )
(if (eq 'pickset (type ss))
(repeat (setq i (sslength ss))
(setq objects
(cons
(vlax-ename->vla-object
(ssname ss
(setq i (1- i))
)
)
objects
)
)
)
)
objects
)
(defun _Main ( ss / boundingboxes )
(cond
( (setq boundingboxes
(vl-remove-if 'null
(mapcar '_GetBoundingBox
(_SStoObjects ss)
)
)
)
(mapcar
'(lambda ( func pair / lst )
(list
(apply (car pair)
(mapcar 'car
(setq lst
(mapcar
func
boundingboxes
)
)
)
)
(apply (cadr pair)
(mapcar 'cadr lst)
)
)
)
'(car cadr caddr cadddr)
'((min min)(max min)(max max)(min max))
)
)
)
)
(_Main ss)
)

(defun SSBoundingBox ( ss / _GetBoundingBox _SStoObjects _Main ) 
 
    (defun _GetBoundingBox ( object / p1 p2 ) 
        (vl-catch-all-apply 
           '(lambda () 
                (vlax-invoke-method 
                    object 
                   'GetBoundingBox 
                   'p1 
                   'p2 
                ) 
            ) 
        ) 
        (if p1 
            (   (lambda (data) 
                    (mapcar 
                       '(lambda (funcs) 
                            (mapcar 
                               '(lambda (func) 
                                    (apply func data) 
                                ) 
                                funcs 
                            ) 
                        )    
                       '(   (caar cadar) 
                            (caadr cadar) 
                            (caadr cadadr) 
                            (caar cadadr) 
                        ) 
                    ) 
                )    
                (list 
                    (mapcar 
                        'vlax-safearray->list 
                        (list p1 p2) 
                    ) 
                ) 
            ) 
        )    
    ) 
    
    (defun _SStoObjects ( ss / i objects ) 
        (if (eq 'pickset (type ss)) 
            (repeat (setq i (sslength ss)) 
                (setq objects 
                    (cons 
                        (vlax-ename->vla-object 
                            (ssname ss 
                                (setq i (1- i)) 
                            ) 
                        ) 
                        objects 
                    ) 
                ) 
            ) 
        ) 
        objects 
    ) 
    
    (defun _Main ( ss / boundingboxes )   
        (cond 
            (   (setq boundingboxes 
                    (vl-remove-if 'null 
                        (mapcar '_GetBoundingBox 
                            (_SStoObjects ss) 
                        ) 
                    ) 
                )    
                (mapcar 
                   '(lambda ( func pair / lst ) 
                        (list 
                            (apply (car pair) 
                                (mapcar 'car 
                                    (setq lst 
                                        (mapcar 
                                            func 
                                            boundingboxes 
                                        ) 
                                    ) 
                                )    
                            ) 
                            (apply (cadr pair) 
                                (mapcar 'cadr lst) 
                            ) 
                        )    
                    ) 
                   '(car cadr caddr cadddr) 
                   '((min min)(max min)(max max)(min max))    
                )    
            )    
        ) 
    ) 
    
    (_Main ss) 
    
)

newer · 发表于 2021-1-20 07:44:46

本帖最后由 newer 于 2021-1-20 07:45 编辑

express tools 提供的函数：

(ACET-GEOM-SS-EXTENTS (ssget) 0.01)

(ACET-GEOM-SS-EXTENTS-ACCURATE(ssget))

(ACET-GEOM-SS-EXTENTS-FAST(ssget))

XDRX API：

(xdrx-entity-box ss)

hh_lj007 · 发表于 2021-1-20 09:36:25

两位牛人。
我理解是获取x,y最小值和最大值，这样就获得了包围选择集的框

yuren008 · 发表于 2021-1-20 10:50:15

做个对论坛有益的人。

/db_自贡黄明儒_ · 发表于 2021-1-20 11:56:28

本帖最后由 /db_自贡黄明儒_ 于 2021-1-20 11:59 编辑

综合一下，有ET就用ET的，没有就用M的

(defun _MyBoxs (ss)
(if ACET-GEOM-SS-EXTENTS-ACCURATE
(ACET-GEOM-SS-EXTENTS-ACCURATE SS)
(SSBoundingBox ss)
)
)

zero423 · 发表于 2021-1-21 10:45:42

跟大神学习学习!

一张单程票 · 发表于 2022-6-9 09:33:30

看到好贴必点赞，感谢分享！

账号		自动登录	找回密码
密码			立即注册

[每日一码] 获得选择集的包围框

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。