弱弱的问一下，有没有这样的数据“2(35+3x34)”计算函数??

挚友01

以下都是字符型的格式
2x36  ; 2x(36+10x50)  ; 2*(36+10*50) 等等，格式都为正常手写的输入格式，有没有求这种类型式计算的函数及程序，给个提示...

huangpc27

阿甘计算器就可以，只是x要转换为*符号。

tzfcn

可以参考：
http://bbs.xdcad.net/forum.php?m ... F%CA%BD%BC%C6%CB%E3

(prompt "\n >>>欢迎使用表达式计算器，命令: wwcalc <<<")
(defun c:wwcal ( / oldch1)
    (vl-load-com)
    (if (member "geomcal.arx" (arx)) nil
        (arxload "geomcal.arx" nil)
    )
    ;;; 灰显控件
    (defun gps->dcl-disablectrls (keylist / key)
        (foreach key keylist (mode_tile key 1))
    )
    ;;;激活控件
    (defun gps->dcl-enablectrls (keylist / key)
        (foreach key keylist (mode_tile key 0))
    )
    ;;;设置剪切板
    (defun gxl-copytoclipboard(text / clip_board)
        (setq clip_board (vlax-get-property (vlax-get (vlax-create-object "htmlfile") 'parentwindow) 'clipboarddata))
        (vlax-invoke clip_board 'setdata "text" text)
        (vlax-release-object clip_board)
        text
    )
    ;;;关于
    (defun note_about ()
        (alert
            (strcat
                "────────────────────────────\n"
                "表达式计算器 V1.0 for AutoCAD2004\n"
                "wowan1314 ,2014年5月13日\n"
                "────────────────────────────\n"
                "程序简介<表达式写法参考cal命令>:\n"
                "1.表达式计算器,并将计算过程存在图形文件中.方便查看.\n"
                "2.作者尽力将本程序做得完善,但不会因本软件的错失\n"
                "  而造成的损失承担任何责任。\n"
                "3.程序还无法增加自定义函数，等待您的参与"
            )
        )
    )
    ;;;计算
    (defun note_add( / note time mmm)
        (if (/= (setq note (get_tile "edit")) "")
            (progn
                (setq mmm (vl-catch-all-apply 'c:cal (list note)))
                (if
                    (null mmm)
                    (progn (mode_tile "edit" 2)(alert "表达式错误!请检查!"))
                    (progn
                        (setq time (menucmd "M=(edtime,(getvar,date),YYYY_MODD_HHMMSS)"))
                        (setq mmm (vl-princ-to-string mmm))
                        (vlax-ldata-put "#wwcalc#" time (strcat note "=" mmm))
                        (gxl-copytoclipboard mmm)
                        (setq oldch1 mmm)
                        (note_fill_lst)
                    )
                )
            )
            (progn
                (mode_tile "edit" 2)
                (alert "输入计算表达式!")
            )
        )
    )
    ;;;dcl赋值
    (defun note_fill_lst( / n)
        (setq #notedataall(vlax-ldata-list "#wwcalc#") #notedata (mapcar 'cdr #notedataall))
        (if oldch1 (set_tile "edit" oldch1))
        (start_list "list")
        (if #notedataall
            (progn
                (foreach n #notedataall
                    (add_list (cdr n))
                )
                (gps->dcl-enablectrls '("sdel" "alldel"))
            )
            (gps->dcl-disablectrls '("sdel" "alldel"))
        )
        (end_list)
        (set_tile "list" "0")
        (mode_tile "edit" 2)
    )
    ;;;单删
    (defun note_lst_sdel( / get n)
        (if (and #notedataall (/= "" (setq get (get_tile "list"))))
            (progn
                (setq n (nth (atoi get) #notedataall))
                (vlax-ldata-delete "#wwcalc#" (car n))
                (note_fill_lst)
            )
        )
    )
    ;;;全删
    (defun note_lst_alldel( / n)
        (foreach n #notedataall (vlax-ldata-delete "#wwcalc#" (car n)))
        (note_fill_lst)
    )
    ;;;双击list.
    (defun note_ok( / get n)
        (if (/= "" (setq get (get_tile "list")))
            (progn
                (setq n (nth (atoi get) #notedataall))
                (gxl-copytoclipboard (cdr n))
                (set_tile "edit" (cdr n))(mode_tile "edit" 2)
            )
        )
    )
    ;;拾取内容
    (defun shiqua (/ ent1 ent2 entdata tmlist entlist textzs)
        (while (null (setq ent1 (nentsel ))))
        (if ent1
            (progn(setq oldch1 (cdr(assoc 1(entget(car ent1)))))
                (caldhk))
        )
    )
    ;end shiqu1
    ;;;
    (defun caldhk ( / #notedata #notedataall dclid dclname filen fn get n note stream tempname time re)
        (setq dclname
            (cond
                ((setq tempname (vl-filename-mktemp "gps-dcl-tmp.dcl") filen (open tempname "w"))
                    (foreach stream
                        '(
                            "ibutton:button{width=12;fixed_width=true;}\n"
                            "wwcalc:dialog{label=\"表达式计算器 v1.0----by wowan1314 \";\n"
                            "  :boxed_row{label=\"输入计算表达式\";\n"
                            "     :edit_box{key=\"edit\"; allow_accept=true;}\n"
                            "  :ibutton{label=\"计算\";key=\"add\";is_default = true;}\n"
                            "  }\n"
                            "  :boxed_column{label=\"历史记录\";\n"
                            "     :list_box{key=\"list\";}\n"
                            "  }\n"
                            ":image {color = 194 ;height = 0.1 ;}\n"
                            "  :row{\n"
                            "  :ibutton{label=\"拾取\";key=\"txtin\";}\n"
                            "  :ibutton{label=\"单删\";key=\"sdel\";}\n"
                            "  :ibutton{label=\"全删\";key=\"alldel\";}\n"
                            "  :ibutton{is_cancel=true;label=\"取消\";}\n"
                            "  :ibutton{label=\"预留扩展\";key=\"about\";}\n"
                            "  }\n"
                            "}\n"
                        )
                        (princ stream filen)
                    )
                    (close filen)
                    tempname
                )
            )
        )
        (setq dclid (load_dialog dclname))
        (if (not(new_dialog "wwcalc" dclid))
            (progn (alert "dcl对话框加载失败.")(exit))
        )
        (note_fill_lst)
        (action_tile "add" "(note_add)")
        (action_tile "list" "(if(= $reason 4)(note_ok))")
        (action_tile "cancel" "(done_dialog 0)")
        (action_tile "sdel" "(note_lst_sdel)")
        (action_tile "alldel" "(note_lst_alldel)")
        (action_tile "about" "(note_about)")
        (action_tile "txtin" "(done_dialog 1)")
        (action_tile "txtout" "(note_out)")
        (setq re (start_dialog))
        (if (= re 1) (shiqua))
        (unload_dialog dclid)
        (vl-file-delete dclname)
        (prin1)
    )
    (caldhk)
)

挚友01

输入2*(2*45+2*34) 就死机了，估计括号的嵌套没去做，要是更复杂计算估计就...

tzfcn

不知道这个代码是否能够派上用场。

qqqincccken

谢谢提供分享试试看了

aisong220

aisong220

aisong220

aisong220