帮忙看一下command命令自动生成图块的程序出问题

八块腹肌笑出来

帮忙看一下程序，该程序将command命令自动生成的图元转换成图块，程序在-BLOCK和-INSERT参数好像都有问题，不知道如何修改？


源码如下：


(defun c:tkcreate ()
    ;; 生成图块函数

      (setvar "cmdecho" 0)
     ;; 保存生成前的最后一个实体   
      (setq old_ent (entlast))
      
   
    ;; 使用command生成图元（示例：直线和圆）
    (command "line" "0,0" "1000,5000" "") ; 示例图元1
    (command "circle" "5,0" "3000")       ; 示例图元2
    (command "line" "1000,2000" "5000,0" "")  ; 示例图元3
      
    ;; 收集新生成的实体
    (setq new_ents '())
      
    (if old_ent
        (progn
            (setq ent (entnext old_ent))
            (while ent
                (setq new_ents (cons ent new_ents))
                (setq ent (entnext ent))
            )
        )
        ;; 如果old_ent为nil，则所有实体都是新的
        (progn
            (setq ent (entnext))
            (while ent
                (setq new_ents (cons ent new_ents))
                (setq ent (entnext ent))
            )
        )
    )
    (setq new_ents (reverse new_ents))
   
    ;; 创建选择集
    (setq ss (ssadd))
      (setq tempent (car new_ents))
    (while tempent
          (ssadd tempent ss)
          (setq new_ents (cdr new_ents))
          (setq tempent (car new_ents))
    )

    ;; 设置块名和基点
    (setq blockname "MyBlock1")
  

    ;; 检查块是否存在
    (if (tblsearch "BLOCK" blockname)
        (princ (strcat "\n块 " blockname " 已存在。"))
        (progn
            (sssetfirst nil ss)
              ;; 创建块定义
            (command "-BLOCK" blockname '(0 0))
            ;; 插入块实例
            (command "-INSERT" blockname '(0 0) "" "" "")   ; 此处出问题
           (princ (strcat "\n块 " blockname " 创建成功。"))
        )
    )   
    (princ)
)

dnbc

(defun c:tkcreate ()
    ;; 生成图块函数
    (setvar "cmdecho" 0)
    ;; 设置块名
    (setq blockname "MyBlock1")
    ;; 检查块是否存在，如果不存在则新建
    (if (not (tblsearch "BLOCK" blockname))
        (progn
            ;; 创建选择集
           (setq ssa (ssadd))
           ;; 使用command生成图元（示例：直线和圆）
           (command "line" "0,0" "1000,5000" "") ; 示例图元1
           (setq ssa (ssadd (entlast) ssa))
           (command "circle" "5,0" "3000")       ; 示例图元2
           (setq ssa (ssadd (entlast) ssa))
           (command "line" "1000,2000" "5000,0" "")  ; 示例图元3
           (setq ssa (ssadd (entlast) ssa))
  
           (sssetfirst nil ssa)

           (if (not (setq pt0 (getpoint "\n 请指基准点:")))
               (setq pt0 '(1000.0 5000.0 0.0))
           )
          
           ;; 创建块定义
           (command "_BLOCK" blockname pt0 ssa "")
           (princ (strcat "\n块 " blockname " 创建成功。"))
        )
    )

    (while (setq pt (getpoint "\n 请指定插入点:"))
        ;; 插入块实例
        (command "_INSERT" blockname pt "" "" "")   ; 此处出问题
    )

    (princ)
)

八块腹肌笑出来

dnbc 发表于 2025-4-30 20:50
(defun c:tkcreate ()
    ;; 生成图块函数
    (setvar "cmdecho" 0)

非常感谢，确实解决了问题，但是原先的程序为啥出问题也没搞清楚