[求助]：通过VBA编程可以调用Visual lisp程序吗？如何调用？

kfygl

通过VBA编程可以调用Visual lisp程序吗？如何调用？

efan2000

需要通过VLAX来调用VL的功能。感觉没有这个必要。

fylinwater

其实这个是lisp 和vba的通讯问题  觉得很重要，这样lisp和vba就可以混合编程了
主要是要调用了lisp函数后能获得返回值
efan2000
能不能介绍介绍

自由的鱼

我只听说用LISP来调用VB，还没有听说用VB来调用LISP，有必要吗？AUTOCAD引用LISP是最方便的，VB还麻烦点，简直是走弯路！

darkblue

用sendcommand方法应该可以

wei186

能说的详细点吗？？
救急！！！

星星

自由的鱼 我只听说用LISP来调用VB，还没有听说用VB来调用LISP，有必要吗？AUTOCAD引用LISP是最方便的，VB还麻烦点，简直是走弯路！ [QUOTE]
我也是比较爱用vlisp,但是lisp有些功能使用很特别,好像不够系统,不太全面,好像能有vb的补充就好了.
请教如何编写带参数的vb函数?
如何在vlisp中引用自己编写的这些vb函数?

lijiao

VL和VBA的相互调用是有用的，因为他们各自都有不足，如果通过相互调用，取长补短，就最好了。
VL和VBA的相互调用并不难，难的是相互间的数据传递，我的做法是在调用之前，将要传递的数据写入字典数据中，被调用的启动后，读取即可。

星星

虽然我还不了解"字典数据"是什么,但看到希望了.谢谢lijiao.

wei186

请问“字典数据”是什么？

lijiao

看看这里http://www.xdcad.net/forum/showt ... d=251409#post251409

wei186

多谢！！！

CComputer

VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
END
Attribute VB_Name = "VLAX"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = False
' VLAX.CLS v2.0 (Last updated 8/1/2003)
' Copyright 1999-2001 by Frank Oquendo
'
' 该程序由明经通道修改支持2004版本
' http://www.mjtd.com
'
' Permission to use, copy, modify, and distribute this software
' for any purpose and without fee is hereby granted, provided
' that the above copyright notice appears in all copies and
' that both that copyright notice and the limited warranty and
' restricted rights notice below appear in all supporting
' documentation.
'
' FRANK OQUENDO (THE AUTHOR) PROVIDES THIS PROGRAM "AS IS" AND WITH
' ALL FAULTS. THE AUTHOR SPECIFICALLY DISCLAIMS ANY IMPLIED WARRANTY
' OF MERCHANTABILITY OR FITNESS FOR A PARTICULAR USE.  THE AUTHOR
' DOES NOT WARRANT THAT THE OPERATION OF THE PROGRAM WILL BE
' UNINTERRUPTED OR ERROR FREE.
'
' Use, duplication, or disclosure by the U.S. Government is subject to
' restrictions set forth in FAR 52.227-19 (Commercial Computer
' Software - Restricted Rights) and DFAR 252.227-7013(c)(1)(ii)
' (Rights in Technical Data and Computer Software), as applicable.
'
' VLAX.cls allows developers to evaluate AutoLISP expressions from
' Visual Basic or VBA
'
' Notes:
' All code for this class module is publicly available througout various posts
' at news://discussion.autodesk.com/a ... .customization.vba. I do not
' claim copyright or authorship on code presented in these posts, only on this
' compilation of that code. In addition, a great big "Thank you!" to Cyrille Fauvel
' demonstrating the use of the VisualLISP ActiveX Module.
'
' Dependencies:
' Use of this class module requires the following application:
' 1. VisualLISP

Private VL As Object
Private VLF As Object

Private Sub Class_Initialize()

    If Left(ThisDrawing.Application.Version, 2) = "15" Then
     Set VL = ThisDrawing.Application.GetInterfaceObject("VL.Application.1")
    ElseIf Left(ThisDrawing.Application.Version, 2) = "16" Then
     Set VL = ThisDrawing.Application.GetInterfaceObject("VL.Application.16")
    End If
    Set VLF = VL.ActiveDocument.Functions

End Sub

Private Sub Class_Terminate()

    Set VLF = Nothing
    Set VL = Nothing

End Sub

Public Function EvalLispExpression(lispStatement As String)

    Dim sym As Object, ret As Object, retval
   
    Set sym = VLF.Item("read").funcall(lispStatement)
    On Error Resume Next
    retval = VLF.Item("eval").funcall(sym)
    If Err Then
        EvalLispExpression = ""
    Else
        EvalLispExpression = retval
    End If

End Function

Public Sub SetLispSymbol(symbolName As String, value)

    Dim sym As Object, ret, symvalue
   
    symvalue = value
    Set sym = VLF.Item("read").funcall(symbolName)
    ret = VLF.Item("set").funcall(sym, symvalue)
    EvalLispExpression "(defun translate-variant (data) (cond ((= (type data) 'list) (mapcar 'translate-variant data)) ((= (type data) 'variant) (translate-variant (vlax-variant-value data))) ((= (type data) 'safearray) (mapcar 'translate-variant (vlax-safearray->list data))) (t data)))"
    EvalLispExpression "(setq " & symbolName & "(translate-variant " & symbolName & "))"
    EvalLispExpression "(setq translate-variant nil)"

End Sub

Public Function GetLispSymbol(symbolName As String)

    Dim sym As Object, ret, symvalue
   
    symvalue = value
    Set sym = VLF.Item("read").funcall(symbolName)
    GetLispSymbol = VLF.Item("eval").funcall(sym)

End Function

Public Function GetLispList(symbolName As String) As Variant

   Dim sym As Object, list As Object
   Dim Count, elements(), i As Long
   
   Set sym = VLF.Item("read").funcall(symbolName)
   Set list = VLF.Item("eval").funcall(sym)
   
   Count = VLF.Item("length").funcall(list)
   
   ReDim elements(0 To Count - 1) As Variant
   
   For i = 0 To Count - 1
        elements(i) = VLF.Item("nth").funcall(i, list)
   Next
   
   GetLispList = elements
   
End Function

Public Sub NullifySymbol(ParamArray symbolName())

    Dim i As Integer
   
    For i = LBound(symbolName) To UBound(symbolName)
        EvalLispExpression "(setq " & CStr(symbolName(i)) & " nil)"
    Next

End Sub

以上代码就是2楼所指的内容，我也不希望对他太过依赖，因为他不是很稳定，而且，不是所有的命令都可以使用。

kfygl

我不会VL，但手上有现成的别人编写的VL程序，若可用VBA调用，则可收到事半功倍的效果。

wpizi

我用了一个原始的方法，将你的lisp程序文件写入vba的一个文本框，并将其保存为.lsp文件，再用sendcommand命令将新生成的lsp文件加载就可以拉：
Sub Example_SendCommand()
ThisDrawing.SendCommand "(load " & Chr(34) & "aa.lsp" & Chr(34) & " )" & VbCr  ,加载文件
ThisDrawing.SendCommand "aaa" & vbCr  ,执行lsp文件的命令
ThisDrawing.SendCommand "_zoom" & vbCr & "a" & vbCr
ThisDrawing.Regen acAllViewports
End Sub
这方法比较麻烦，但还是可以用！！