[原创]：提取单个块的所有属性值 ！超级精简代码！

陌生人

[php]
;(getatt ) = 提取单个块的所有属性值--------vl方法-----by 陌生人.2004.4
;返回：所有属性值的列表。
;测试: (getatt (car(entsel "\n选择含属性的块:")))

(defun getatt (blk / attlst lst)
  (setq attlst (vlax-invoke (vlax-ename->vla-object blk) 'GetAttributes ))
  (mapcar '(lambda (x) (vlax-get x 'TextString)) attlst)
)
[/php]

------
编程要点分析：
用vlax返回值的特性，避免了过多的变体转换。
其中：vlax－invoke 得到的是 vla方法的列表 ，如果用vla－getattributes，将返回变体数组。
vlax－get，直接得到textsting的值，当然，一般vla能直接返回字符串，但是在这里，我把属性的属性单独拿出来，好处是什么？：）
换成‘TagString 试试，换成’Rotation 试试。如果是用vla－get－，你会怎么做呢？写很多个有重复代码的程序？还是将 函数名用字符串组合再转为完整的函数名？如：(eval (quote(read(strcat "vla-get-" (vl-symbol-name  attkey) ))))) ，都不如用vlax简单。
得了表之后处理用mapcar,foreach是常用方法。
------
不得不说的话：
这个程序仅仅提供一个框架，其实仅仅返回属性值列表往往不能满足需求，一般是和tag等其他一起组表才方便后面的提取。
但是你可以通过稍微一点的修改，而达到目的。能够发挥多少，就看你自己的本事了。呵呵：）

虽然程序不长，（比我见过的同样功能的程序要简洁），但是这体现了我编程经验的积淀，我相信（自信）这也不是一般爱好lsp编程的人能写出来的（当然，高手除外）。
完成一个功能，能用一句代码写出来，就不要用两句－－－这是我的编程原则之一。今天不才，拿出来与大家共勉。：）

5axing

陌生人,兄弟看来又想通了哈，更进了一步，佩服佩服。向你学习，瘦身运动一定要坚持：）

david96007

高手！
看来学无止境，我要继续努力才行呀！

aeo

不是原创吧:)

不过很奇怪，帮助里说，vlax-invoke 是2000以前的。那时候好像没variant吧,只好是表了.
现在是vlax-invoke-method了，但实际上还是支持的,但返回是不同的.

vlax-get和vlax-get-property 倒是一样。
不会哪天说不支持了吧!

陌生人

是原创

aeo

VxGetAtts - Reads all attribute values from a block

[php]
;
; -- Function VxGetAtts
; Reads all attribute values from a block
; Copyright:
;   ?000 MENZI ENGINEERING GmbH, Switzerland
; Arguments [Typ]:
;   Obj = Object [VLA-OBJECT]
; Return [Typ]:
;   > Dotted pair list '(("Tag1" . "Val1")...) [LIST]
; Notes:
;   None
;
(defun VxGetAtts (Obj)
(mapcar
'(lambda (Att)
   (cons (vla-get-TagString Att)
         (vla-get-TextString Att)
   )
  )
  (vlax-invoke Obj "GetAttributes")
)
)
[/php]

陌生人

我还真没见过上面这个程序，那也算英雄所见略同吧。
而且，对textstring的用法也不同

snsj

陌生人能写出这样的程序很正常，非常不错

LUCAS

;;查看http://www.mjtd.com/bbs/dispbbs. ... 7&replyID=10014
;;vlax-get & vlax-invoke是向下相容
;;但以後不一定支持,能不用就不用

;;換成『TagString 試試，換成』Rotation 試試。如果是用vla－get－，你會怎麼做呢？
;;--->把VLA-GET-TEXTSTRING放到輸入來做!!

;;下列用很久了!(最近在明經的TABLE R2005 提取圖面中所有帶屬性圖塊值並表列)
;;甚麼是才算精簡代碼！要處理的放到輸入來處理!!
;;提取單個塊的所有屬性值vl方法---By 龍龍仔.200?
;;返回：所有屬性值的列表。
;;(GETATT <VOBJ> <VLA-GET-物件性質>)
;;(GETATT (vlax-ename->vla-object (car (entsel "\n選擇含屬性的塊:"))) VLA-GET-TEXTSTRING)
(defun GETATT (OBJ TAG)
  (mapcar '(lambda (ATT) (TAG ATT))
          (vlax-invoke OBJ "GetAttributes")
  )
)