[讨论]：讨论一下用户交互输入的问题

yjtdkj

各位大虾，不知道LISP里有没有这样一个函数，
例如我输入这样一串字：500X200X8X12
函数能自动根据乘号两边的变量画出图形，
请问想获得这样的效果怎么才能办到

zhanzujie

你的想法没有针对性,建议你先看看有关lisp编程方面的书
http://www.xdcad.net/forum/showt ... ighlight=lisp%CA%E9

hi71400

2楼说得对。
lisp没有直接的函数。
1楼说的其实就是将一个字串个分成几个子串，再转成数字，再画图的问题。
不难，但讲起来麻烦，1楼的：
先看看书吧。

zhang8755

可以自编一个字符串处理的函数，可以参考我下面的程序，我的程序是以逗号作为分隔符，你只要改成X就行了
;;将一行字符串转为表,逗号分隔
(defun str_to_list (str / i one l strl)
  (setq one "")
  (setq strl (strlen str))
  (setq i 1)
  (while (<= i strl)
        (if        (/= "," (substr str i 1))
          (setq one (strcat one (substr str i 1)))
          (progn
                (if        (= "." (substr one 1 1))
                  (setq one (strcat "0" one))
                )
                (setq l (append l (list (read one))))
                (setq one "")
          )
        )
        (setq i (1+ i))
  )
  (if (= "." (substr one 1 1))
        (setq one (strcat "0" one))
  )
  (setq l (append l (list (read one))))
  l
)

yjtdkj

谢谢4楼主的帮忙，但小弟只是个初学者，能否一一解释一下你的函数?跪谢！！！
(if (= "." (substr one 1 1))
(setq one (strcat "0" one))
)
上面这句似乎不要也行

lsjjm

4,5楼: 直接使用acet内部函数:
(acet-str-to-list "x" "500x200x8x12")
return:   ("500" "200" "8" "12")

yjtdkj

acet-str-to-list 好像不能在LISP中用应用呀

lsjjm

最初由 yjtdkj 发布
[B]acet-str-to-list 好像不能在LISP中用应用呀 [/B]

安装了ET工具就可以应用.

yjtdkj

最初由 lsjjm 发布
[B]
安装了ET工具就可以应用. [/B]

谢谢指点！！！
但是我应用在我的函数中不知道那里出错了？？？？
(defun
      c:dcl (/ pt1 pt2 pt3 pt4 pt5 pt6 pt7 pt8 pt9 pt10        pt11 h b1 tw
             B2        DCL T2 X t1 oldosm)
  (setq        dcl
         (getstring
           "请输入高度X上翼缘宽度X下翼缘宽度X腹板厚X上翼缘厚X下翼缘厚:"
         )
  )
  (setq x (acet-str-to-list "x" dcl))
  (setq h (atof (nth 1 x)))
  (setq b1 (atof (nth 2 x)))
  (setq b2 (atof (nth 3 x)))
  (setq tw (atof (nth 4 x)))
  (setq t1 (atof (nth 5 x)))
  (setq t2 (atof (nth 6 x)))
  (setq pt1 (getpoint "插入点:"))
  (setq pt2 (polar pt1 (/ pi 2.0) (- (/ h 2) t1)))
  (setq pt3 (polar pt2 pi (/ tw 2.0)))
  (setq pt4 (polar pt1 (* pi 1.5) (- (/ h 2) t2)))
  (setq pt5 (polar pt4 0.0 (/ tw 2.0)))
  (setq pt6 (polar pt1 (/ pi 2.0) (/ h 2)))
  (setq pt7 (polar pt6 pi (/ b1 2)))
  (setq pt8 (polar pt2 0.0 (/ b1 2)))
  (setq pt9 (polar pt1 (* pi 1.5) (/ h 2)))
  (setq pt10 (polar pt9 pi (/ b2 2)))
  (setq pt11 (polar pt4 0.0 (/ b2 2)))
  (setq oldosm (getvar "osmode"))
  (setvar "osmode" 0)
  (command "rectang" pt3 pt5)
  (command "rectang" pt7 pt8)
  (command "rectang" pt10 pt11)
  (setvar "osmode" oldosm)
  (PRINC)
)

lsjjm

nth 为0基函数.
表x 的第一个元素是(nth 0 x), 不是(nth 1 x).......

陌生人

[php]
(defun c:test ()
  (setq str "500x200x8x12");(setq str "500X200X8X12")
  (eval (read (strcat "(* " (vl-list->string (mapcar '(lambda(x)(if (member x '(88 120)) 32 x))(vl-string->list str))) ")")))
)
;|
命令: test
9600000
|;


(eval (read (strcat "(* " (vl-list->string (subst 32 88 (vl-string->list "500X200X8X12"))) ")")))
-> 9600000
[/php]

yjtdkj

最初由 lsjjm 发布
[B]nth 为0基函数.
表x 的第一个元素是(nth 0 x), 不是(nth 1 x)....... [/B]

非常感谢您的指点，现在可以用了！！！！

cy956

去明经通道看看内部函数,看看字串->表和表->字串的函数怎么写,
或者拿来了怎么用.