[求助]：一个关于块的问题请教

ntchjie

这个问题很简单，甚至很幼稚，但是不知道为什么要发生错误在
Set aline = blockObj.AddLine(p1, p2)
这一句，总的代码如下，我是想生成一个块的。
Dim blockObj As AcadBlock
Dim insertionPnt(0 To 2) As Double

Set acadObj = GetObject(, "AutoCAD.Application.15")
Set AcadDoc = acadObj.ActiveDocument
Set MSpace = AcadDoc.ModelSpace

'生成块名称
insertionPnt(0) = 0#: insertionPnt(1) = 0#: insertionPnt(2) = 0#
Set blockObj = AcadDoc.Blocks.Add(insertionPnt, "CircleBlock")

'外边框线
Dim pl As Object
Dim p(0 To 14) As Double
p(0) = 25: p(1) = 5: p(2) = 0
p(3) = 404: p(4) = 5: p(5) = 0
p(6) = 404: p(7) = 280: p(8) = 0
p(9) = 25: p(10) = 280: p(11) = 0
p(12) = 25: p(13) = 5: p(14) = 0
Set pl = blockObj.AddPolyline(p)
pl.color = 6
For i = 0 To 4
    Call pl.SetWidth(i, 0.8, 0.8)
Next i

'上线
Dim p1(0 To 2), p2(0 To 2) As Double
Dim aline As Object
p1(0) = 25: p1(1) = 21: p1(2) = 0
p2(0) = 404: p2(1) = 21: p2(2) = 0
Set aline = blockObj.AddLine(p1, p2)                           **********这里错误
aline.color = 6


' Insert the block
Dim blockRefObj As AcadBlockReference
insertionPnt(0) = 2#: insertionPnt(1) = 2#: insertionPnt(2) = 0
Set blockRefObj = AcadDoc.ModelSpace.InsertBlock(insertionPnt, "CircleBlock", 1#, 1#, 1#, 0)
我自己都觉得很不可思议，查遍了很多书，好像语法都没有错。

lijiao

Dim p1(0 To 2), p2(0 To 2) As Double改为
Dim p1(0 To 2) As Double
Dim p2(0 To 2) As Double
变量类型不对。

雪山飞狐(lzh)

同意，这种错误很常见，又不容易检查出
建议对一个变量的声明写一行，像楼上的写法就不错

ntchjie

多谢，我还真的没有看出来这个问题。
严重的万分感谢！！

wyj7485

Dim p1(0 To 2) As Double,p2(0 To 2)  As Double亦可