[LISP函数]：SET 函数有什么用？

doubao · 发表于 2005-8-18 12:34:51

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

大家都很熟悉 SETQ 函数。
SET 函数却很少用。它最适合于哪些应用？能否给个实例？

狂刀 · 发表于 2005-8-18 14:03:47

搜索一下　“set”

zxq0220 · 发表于 2005-8-18 14:59:15

例：统计图中每种图块的数量。

(DEFUN C:SUMBLK ()
(IF (SETQ SS (SSGET "X" '((0 . "INSERT")))) (PROGN
(SETQ SL (SSLENGTH SS) I 0 BL (LIST))
(REPEAT SL
(SETQ ENT (ENTGET (SSNAME SS I)) I (1+ I)
BNM (CDR (ASSOC 2 ENT)))
(IF (EVAL (READ BNM))
(SET (READ BNM) (1+ (EVAL (READ BNM))))
(PROGN
(SETQ BL (CONS (LIST BNM 0) BL))
(SET (READ BNM) 0)
))
)
(SETQ SL (LENGTH BL) I 0 BL (REVERSE BL))
(PRINC "图块名:数量\n")
(REPEAT SL
(SETQ B (NTH I BL) BNM (CAR B)
BL (SUBST (LIST BNM (EVAL (READ BNM))) B BL))
(PRINC BNM) (PRINC " : ")
(PRINC (EVAL (READ BNM))) (PRINC "\n")
(SETQ I (1+ I))
(SET (READ BNM) nil)
)
))
(PRINC)
)

doubao · 发表于 2005-8-18 18:24:35

非常感谢3楼的程序，不仅是一个set 函数的很好的应用，也是一个非常实用的程序，可以用来统计材料表。

该程序的核心语句应该是
(SET (READ BNM) (1+ (EVAL (READ BNM)))

主要思路我看懂了，就是以每个块的块名作为变量名，并作为该块数量的累加器，程序简洁，妙哉！

如果不用 set 函数，恐怕难做到这么简洁。

yehuli · 发表于 2005-8-18 19:23:30

setq=set+quote

zxq0220 · 发表于 2005-8-19 08:31:23

三楼程序有BUG，下面是更改过的程序。
[php]
(DEFUN C:SUMBLK ()
(IF (SETQ SS (SSGET "X" (LIST (CONS 0 "INSERT")))) (PROGN
  (SETQ SL (SSLENGTH SS) I 0 BL (LIST))
  (REPEAT SL
(SETQ ENT (ENTGET (SSNAME SS I)) I (1+ I)
      BNM (CDR (ASSOC 2 ENT)))
(IF (EVAL (READ BNM))
(SET (READ BNM) (1+ (EVAL (READ BNM))))
(PROGN
(SETQ BL (CONS (LIST BNM 1) BL))
(SET (READ BNM) 1)
))
  )
  (SETQ SL (LENGTH BL) I 0 BL (REVERSE BL))
  (PRINC "图块名:数量\n")
  (REPEAT SL
(SETQ B (NTH I BL) BNM (CAR B)
      BL (SUBST (LIST BNM (EVAL (READ BNM))) B BL))
(PRINC BNM) (PRINC " : ")
(PRINC (EVAL (READ BNM))) (PRINC "\n")
(SETQ I (1+ I))
(SET (READ BNM) nil)
  )
))
(PRINC)
)
[/php]

doubao · 发表于 2005-8-19 12:04:50

zxq0220 的程序很好用。

可以举一反三地运用 set 函数对图层、颜色等进行统计操作

狂刀 · 发表于 2005-9-3 19:58:28

用set统计存在的问题（看最下方的评论）:
[iframe h=600 w=100%]http://www.mjtd.com/blog/user1/46/archives/2005/57.asp[/iframe]

doubao · 发表于 2005-9-3 20:32:23

关于8楼所贴评论中提到的问题
“不能重复使用（数量会累加）”应该是由于该程序未设清零。
“用纯数字做块名，会出错。”是因为程序中用块名作为变量名，而变量名不能为全数字。可以通过用一个字符加上块名作为变量名的方法来解决。

狂刀 · 发表于 2005-9-3 21:51:32

这样一来，程序就臃肿了。光是清除程序中的变量名就有的写了，如果变量名（块名）保存为表，那么用ｓｅｔ就显得多此一举（就本例而言）
ｓｅｔ除了不能以数字为变量名，还不能用函数名和保留字，如 'ｌｉｓｔ　'PI 'T。

eachy · 发表于 2005-9-4 01:33:10

这样写，以前我发过一个关于属性修改的，用属性名保存属性值，还有以前写的一个合并直线也是用 set 和 eval ，这就是Lisp特有的一种表处理方法。

(defun c:sumblk (/ ss sl i ent bnm bl)
;;
(if (setq ss (ssget '((0 . "insert"))))
(progn
(setq sl (sslength ss)
i 0
)
(repeat sl
(setq ent (entget (ssname ss i))
i (1+ i)
bnm (strcat "EA_" (cdr (assoc 2 ent)))
)
(if (eval (read bnm))
(set (read bnm) (1+ (eval (read bnm))))
(set (read bnm) 1)
)
(setq bl (if (not (vl-position bnm bl))
(cons bnm bl)
bl
)
)
)
(if bl
(progn (mapcar '(lambda (x)
(princ (strcat "\n图块" (substr x 4) "数量: "))
(princ (eval (read x)))
)
bl
)
(mapcar '(lambda (x) (set (read x) nil)) bl);_这个要定义到 *error* 中释放变量
(setq bl nil);_也要加入到 *error* 中
)
)
)
)
(princ)
)

(defun c:sumblk        (/ ss sl i ent  bnm bl) 
  ;; 
  (if (setq ss (ssget '((0 . "insert")))) 
    (progn 
      (setq sl (sslength ss) 
            i  0 
      ) 
      (repeat sl 
        (setq ent (entget (ssname ss i)) 
              i          (1+ i) 
              bnm (strcat "EA_" (cdr (assoc 2 ent))) 
        ) 
        (if (eval (read bnm)) 
          (set (read bnm) (1+ (eval (read bnm)))) 
          (set (read bnm) 1) 
        ) 
        (setq bl (if (not (vl-position bnm bl)) 
                   (cons bnm bl) 
                   bl 
                 ) 
        ) 
      ) 
      (if bl 
        (progn (mapcar '(lambda        (x) 
                          (princ (strcat "\n图块" (substr x 4) "数量: ")) 
                          (princ (eval (read x))) 
                        ) 
                       bl 
               ) 
               (mapcar '(lambda (x) (set (read x) nil)) bl);_这个要定义到 *error* 中释放变量 
               (setq bl nil);_也要加入到 *error* 中 
        ) 
      ) 
    ) 
  ) 
  (princ) 
)

doubao · 发表于 2005-9-4 01:34:02

能否再介绍一个不用set函数统计图块数量的lisp程序？以便比较一下哪一种方法效率高？

eachy · 发表于 2005-9-4 01:48:16

;| Written By Eachy 2004.1.12
功能: 图块数量统计;;
说明: 根据点取的典型图块统计, 可以多选 ;;
|;
(defun c:Ea:BlkNum (/ ss ssl i bn bl pos)
(princ "\n拾取统计范围[All - 全选].....")
(if (setq ss (ssget '((0 . "insert"))))
(progn
(setq ssl (sslength ss)
i -1
)
(repeat ssl
(setq bn (cdr (assoc 2 (entget (ssname ss (setq i (1+ i)))))))
(if bl
(if (setq pos (assoc bn bl))
(setq bl (subst (cons bn pos) pos bl))
(setq bl (append (list (list bn)) bl))
)
(setq bl (list (list bn)))
)
)
(mapcar '(lambda (x)
(princ (strcat "\n图块" (car x) "数量: "))
(princ (length x))
)
bl
)
)
)
(princ)
)

doubao · 发表于 2005-9-4 20:35:34

eachy 在13楼贴出的程序也很精炼，对表的操作技巧很高，值得学习。

和用set函数的程序（见11楼）相比， 13楼的程序运行时所需要的存储空间可能要大，因为它是建立一个表bl，这个表把每个块的块名按该块的数量罗列起来，构成一个子表，这个子表的长度即该块的数量。如果图中块的数量越大，这个表 bl 就会越大，所需要的存储空间就越大。另外块名的长短也直接影响所需要的存储空间的大小。

而用set函数的程序是给每个块设一个累加器，累加器的数量即选择集中不同块名的数量。所以所需存储空间不会随块的数量而增加。

另外从计算机算法上，实现累加器应该比实现表的添加扩充简单得多。

综上所述，我认为还是用set函数的程序（11楼）比用创建表来统计块的程序（13楼）效率要高。

正确与否，欢迎指正。

狂刀 · 发表于 2005-9-4 20:45:41

说到效率，我也很感兴趣，不知道哪位大侠可以拿一个大图测试一下？
期待结论ｉｎｇ

账号		自动登录	找回密码
密码			立即注册

[LISP函数]：SET 函数有什么用？

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子