[求助]：尺寸中DIMSCALE的组码是多少

lzy9788 · 发表于 2004-7-30 15:24:59

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

请教各位，尺寸中变量DIMSCALE的组码是多少？

aidraft · 发表于 2004-7-30 15:27:38

vla-get-scalefactor

lzy9788 · 发表于 2004-7-30 15:44:09

我不会VLISP,现在我想将图中的尺寸修改全局比例(dimscale)，但不改变标注比例，
可以用lisp编程实现吗？
用VLISP是不是很简单

aidraft · 发表于 2004-7-30 16:01:05

(cdr (assoc 1040 (cdadr (assoc -3 (entget EN '("ACAD"))))))

lzy9788 · 发表于 2004-7-30 16:25:11

这种怎么用新项换旧项(用subst)

aidraft · 发表于 2004-7-31 09:20:18

[php]
(defun c:tt  (/ el oldDimscale newDimscale xdata)
  (setq el (entget (car (entsel "\n选择尺寸：")) '("ACAD")))
  (setq oldDimscale
   (cdr (assoc 1040 (setq xdata (cdadr (assoc -3 el))))))
  (princ "\n新的Dimscale <")
  (princ oldDimscale)
  (setq newDimscale (getreal ">: "))
  (if (and (/= nil newDimscale) (/= oldDimscale newDimscale))
(progn
   (setq
el
   (subst (cons -3
      (list
(cons "ACAD"
      (subst (cons 1040 newDimscale)
      (assoc 1040 xdata)
      xdata))))
(assoc -3 el)
el))
   (entmod el)
   )
)
  (princ)
  )
;;;ActiveX 方法直接多了
(defun c:ttax  (/ dimobj oldDimscale newDimscale)
  (vl-load-com)
  (setq dimobj       (vlax-ename->vla-object (car (entsel "\n选择尺寸：")))
oldDimscale (vla-get-ScaleFactor dimobj))
  (princ "\n新的Dimscale <")
  (princ oldDimscale)
  (setq newDimscale (getreal ">: "))
  (if (and (/= nil newDimscale) (/= oldDimscale newDimscale))
(vla-put-ScaleFactor dimobj newDimscale))
  (princ)
  )
;;直接用AutoCAD命令, 有点啰嗦
(defun c:ttcad (/          el       en
   oldDimscale newDimscale DimstyleHold
   DimscaleHold  cmdEchoHold dimstyle)
  (setq el (entget (setq en (car (entsel "\n选择尺寸："))) '("ACAD")))
  (setq dimstyle (cdr (assoc 3 el)))
  (setq oldDimscale
   (cdr (assoc 1040 (setq xdata (cdadr (assoc -3 el))))))
  (princ "\n新的Dimscale <")
  (princ oldDimscale)
  (setq newDimscale (getreal ">: "))
  (if (and (/= nil newDimscale) (/= oldDimscale newDimscale))
(progn
   (setq DimstyleHold (getvar "DIMSTYLE"))
   (setq DimscaleHold (getvar "DIMSCALE"))
   (setq cmdEchoHold (getvar "CMDECHO"))
   (setvar "CMDECHO" 0)
   (command "-dimstyle" "r" dimstyle)
   (setvar "DIMSCALE" newDimscale)
   (command "-dimstyle" "a" en "")
   (command "-dimstyle" "r" DimstyleHold)
   (setvar "DIMSCALE" DimscaleHold)
   (setvar "CMDECHO" cmdEchoHold)
   )
)
  (princ)
  )
[/php]

lzy9788 · 发表于 2004-8-1 22:40:43

多谢aidraft的诚心指教。

梦断江南 · 发表于 2004-8-1 23:06:05

最初由 aidraft 发布
[B]
(defun c:tt  (/ el oldDimscale newDimscale xdata)
  (setq el (entget (car (entsel "\n选择尺寸：")) '("ACAD")))
  (setq oldDimscale
   (cdr (assoc 1040 (setq xdata (cdadr (assoc -3 el))))))
... [/B]

第一个程序tt。
应该用(1070 . 40)判断.否则如果无标注替代，会改到别的替代数据.
第二个程序，ok。
第三个程序。
用cad命令怎么会罗嗦呢？另，你的cad命令方法会屏蔽掉原来已经有的标注样式替代。
用cad命令：
[php]
(defun c:dimsc ()
(setvar "cmdecho" 1)
(vl-cmdf ".dimoverride" "dimscale" pause "");;pause可用(getreal)代替
)
[/php]

aidraft · 发表于 2004-8-2 10:14:16

Thx LISP monster:)

橄榄滋味 · 发表于 2004-9-7 14:22:37

下面编码是某个尺寸部分信息(100 . "AcDbRotatedDimension") (-3 ("ACAD" (1000 . "DSTYLE") (1002 . "{") (1070 . 144) (1040 . 8.0) (1070 . 40) (1040 . 7.0) (1070 . 176) (1070 . 1) (1070 . 177) (1070 . 1) (1070 . 178) (1070 . 3) (1002 . "}"))))
请高手解释一下(1070 . 144) (1040 . 8.0) (1070 . 40) (1040 . 7.0) (1070 . 176) (1070 . 1) (1070 . 177) (1070 . 1) (1070 . 178) (1070 . 3) 每个括号中含义，以及如何提取和更改。我发现里面的8.0是线性比例因子，7.0是全局比例因子，那么其余的呢，还有就是怎样提取和更改呢

账号		自动登录	找回密码
密码			立即注册

[求助] [求助]：尺寸中DIMSCALE的组码是多少

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子

浏览过的版块