（完成）[编程申请]：如何关闭图块所有属性值？

yangzj · 发表于 2003-1-18 12:12:25

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

请高人帮忙！
不论图块有多少属性值，如何用编程方式将其所有属性值关闭或清空？:

LUCAS · 发表于 2003-1-28 13:54:26

;;By LUCAS
;;所有属性值关闭或清空
(defun C:CLEANATTRIBUTES (/ TMP M2)
(setq TMP (entsel "\n选取带属性图块: "))
(if (and (/= TMP NIL)
(setq TMP (vlax-ename->vla-object (car TMP)))
(= (vla-get-objectname TMP) "AcDbBlockReference")
(= (vla-get-hasattributes TMP) :vlax-true)
)
(foreach M2 (vlax-safearray->list
(vlax-variant-value
(vla-getattributes TMP)
)
)
(if (= :vlax-true (vla-get-visible M2))
(vla-put-visible M2 :vlax-false)
(vla-put-visible M2 :vlax-true)
)
;;(vla-put-textstring M2 "") ;;清空
)
(prompt "\n所选对象不带属性")
)
(princ)
)

zhuqi75 · 发表于 2003-1-29 15:11:07

你好棒阿

海豚 · 发表于 2004-9-21 13:35:04

版主还请帮忙，程序很好，但是必须一个一个去点，如果图中块的数量很多，就无法这样去找了。
能不能作些改进，最好点击后，该块名的所有块都如此处理。或者是否能改为多选，我可以用选择易选择后再运行该程序。不用一个一个去找。谢谢。

Free-Lancer · 发表于 2004-9-21 18:41:16

最初由海豚发布
[B]版主还请帮忙，程序很好，但是必须一个一个去点，如果图中块的数量很多，就无法这样去找了。
能不能作些改进，最好点击后，该块名的所有块都如此处理。或者是否能改为多选，我可以用选择易选择后再运行该程序。不用... [/B]

(defun attonf (ss mode / n obj sl)
(if ss
(progn (setq sl (sslength ss))
(while (< (if (not n)
(setq n 0)
(setq n (1+ n))
)
sl
)
(setq obj (vlax-ename->vla-object (ssname ss n)))
(if (= (vla-get-hasattributes obj) :vlax-true)
(mapcar '(lambda (x) (vla-put-visible x mode))
(safearray-value
(variant-value (vla-getattributes obj))
)
)
)
)
)
)
)
(defun c:atton (/ ss)
(princ "\n选择图块....")
(attonf (ssget '((0 . "insert"))) :vlax-true)
(princ)
)
(defun c:attoff ()
(princ "\n选择图块....")
(attonf (ssget '((0 . "insert"))) :vlax-false)
(princ)
)

(defun attonf (ss mode / n obj sl) 
  (if ss 
    (progn (setq sl (sslength ss)) 
           (while (< (if (not n) 
                       (setq n 0) 
                       (setq n (1+ n)) 
                     ) 
                     sl 
                  ) 
             (setq obj (vlax-ename->vla-object (ssname ss n))) 
             (if (= (vla-get-hasattributes obj) :vlax-true) 
               (mapcar '(lambda (x) (vla-put-visible x mode)) 
                       (safearray-value 
                         (variant-value (vla-getattributes obj)) 
                       ) 
               ) 
             ) 
           ) 
    ) 
  ) 
) 
(defun c:atton (/ ss) 
  (princ "\n选择图块....") 
  (attonf (ssget '((0 . "insert"))) :vlax-true) 
  (princ) 
) 
(defun c:attoff        () 
  (princ "\n选择图块....") 
  (attonf (ssget '((0 . "insert"))) :vlax-false) 
  (princ) 
)

海豚 · 发表于 2004-9-22 07:32:15

谢谢Free-Lancer 以及LUCAS版主的热情帮忙，问题解决的，现在可以多选了，我现在可以用选择易选择后，再用Free-Lancer 的程序关闭属性显示，方便了很多。
希望各位大哥能继续改进本程序，令程序可以直接结合选择易，点击图块就可以把所有该名字图块的属性显示关闭，是程序运行更快捷。
不过这样已经帮了我很大的忙，实在太谢谢各位。

wkai · 发表于 2004-9-22 10:28:00

将所有程序集成到选择易的后继操作中显然是不合适的。
你可以以后几操作为"无"的方式用选择易得到夹选的物体，之后调用 Free-Lancer 的程序完成任务。

LUCAS · 发表于 2004-9-23 08:29:51

;;點擊後，該塊名的所有塊都如此處理。
;;指令:ATTON_OFF
;;BY LUCAS
;;切換屬性值顯示或關閉
;;--------------------------------------------------------------
(defun C:ATTON_OFF (/ SS TMP)
(vl-load-com)
(while (and (setq TMP (entsel "\n選取帶屬性圖塊: "))
(equal "INSERT" (cdr (assoc 0 (entget (car TMP)))))
(setq SS (ssget "x"
(list '(0 . "insert")
'(66 . 1)
(assoc 2 (entget (car TMP)))
)
)
)
)
(if (= :vlax-true
(vla-get-visible
(nth 0
(safearray-value
(variant-value
(vla-getattributes
(vlax-ename->vla-object (ssname SS 0))
)
)
)
)
)
)
(ATTONF SS :vlax-false)
(ATTONF SS :vlax-true)
)
)
(princ)
)
;;---------------------------------------------------------------
(defun ATTONF (SS MODE / ENT M2)
(while (setq ENT (ssname SS 0))
(foreach M2 (safearray-value
(variant-value
(vla-getattributes (vlax-ename->vla-object ENT))
)
)
(vla-put-visible M2 MODE)
)
(ssdel ENT SS)
)
)

;;點擊後，該塊名的所有塊都如此處理。 
;;指令:ATTON_OFF 
;;BY LUCAS 
;;切換屬性值顯示或關閉 
;;-------------------------------------------------------------- 
(defun C:ATTON_OFF (/ SS TMP) 
  (vl-load-com) 
  (while (and (setq TMP (entsel "\n選取帶屬性圖塊: ")) 
              (equal "INSERT" (cdr (assoc 0 (entget (car TMP))))) 
              (setq SS (ssget "x" 
                              (list '(0 . "insert") 
                                    '(66 . 1) 
                                    (assoc 2 (entget (car TMP))) 
                              ) 
                       ) 
              ) 
         ) 
    (if        (= :vlax-true 
           (vla-get-visible 
             (nth 0 
                  (safearray-value 
                    (variant-value 
                      (vla-getattributes 
                        (vlax-ename->vla-object (ssname SS 0)) 
                      ) 
                    ) 
                  ) 
             ) 
           ) 
        ) 
      (ATTONF SS :vlax-false) 
      (ATTONF SS :vlax-true) 
    ) 
  ) 
  (princ) 
) 
;;--------------------------------------------------------------- 
(defun ATTONF (SS MODE / ENT M2) 
  (while (setq ENT (ssname SS 0)) 
    (foreach M2        (safearray-value 
                  (variant-value 
                    (vla-getattributes (vlax-ename->vla-object ENT)) 
                  ) 
                ) 
      (vla-put-visible M2 MODE) 
    ) 
    (ssdel ENT SS) 
  ) 
)

海豚 · 发表于 2004-9-23 13:03:49

太谢谢版主了，非常符合我的要求，而且一个命令就可以控制开关。经测试所有的图纸都能通过。谢谢。

账号		自动登录	找回密码
密码			立即注册

（完成）[编程申请]：如何关闭图块所有属性值？

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子

浏览过的版块