[已解决]■怎么属性查找 做成表？■

zhuquanmao

图中有若干属性块a 它有两个属性b c， 遍历所以属性块 查到属性c的值为“0”的图块后，将其属性b的值加到表1st中  这个该怎么做？

zhuquanmao

G版给的代码 如下 问题解决！{:soso_e113:}
[pcode=lisp,true]
(defun c:tt (/ ss n blkref atts a)
  (setq ss (ssget "x" '((0 . "insert") (2 . "a")
                   (66 . 1)
                  )
           )
  )
  (if ss
    (progn
      (repeat (setq n (sslength ss))
        (setq blkref (vlax-ename->vla-object (ssname ss (setq n (1- n)))))
        (setq atts (mapcar
                     '(lambda (x)
                        (cons (vla-get-tagstring x)
                              (vla-get-textstring x)
                        )
                      )
                     (vlax-invoke blkref 'getattributes)
                   )
        )
        (if (and
              (setq a (assoc "c" atts))
              (= (cdr a) "0")
            )
          (if (setq a (cdr (assoc "b" atts)))
            (setq lst (cons a lst))
          )
        )
      )
      (princ lst)
    )
  )
  (princ)
)
[/pcode]