图中这样的文字的包围盒怎么得到？

Lisphk

对于文字有倾角的，我想获得实际形状的包围盒，有办法吗？

Free-Lancer

根据文字的倾角用三角函数重新计算角点

Faster

[pcode=lisp,true](defun getTextminBox (EN / ENX L B R N W H J O ob tan)
(defun tan (a)
  (/ (sin a) (cos a))
)
  (if (= 'VLA-OBJECT (type en))
    (setq en (vlax-vla-object->ename en))
  )
  (setq enx (entget en))
  (setq        l
         (cond
           ((= "TEXT" (cdr (assoc 0 enx)))
            (setq b (cdr (assoc 10 enx))
                  r (cdr (assoc 50 enx))
                  l (textbox enx)
                  n (cdr (assoc 210 enx))
                  ob (cdr (assoc 51 enx))
            )
            (setq l
                   (list
                     (list (caar l) (cadar l))
                     (list (caadr l) (cadar l))
                     (list (caadr l) (cadadr l))
                     (list (caar l) (cadadr l))
                     )
                  h (distance (car l) (last l))
                  )
            (list
              (car l)
              (polar (cadr l) 0 (- (* h (tan ob))))
              (caddr l)
              (polar (cadddr l) 0 (* h (tan ob)))
              )
           )
           ((= "MTEXT" (cdr (assoc 0 enx)))
            (setq n (cdr (assoc 210 enx))
                  b (trans (cdr (assoc 10 enx)) 0 n)
                  r (angle '(0.0 0.0 0.0) (trans (cdr (assoc 11 enx)) 0 n))
                  w (cdr (assoc 42 enx))
                  h (cdr (assoc 43 enx))
                  j (cdr (assoc 71 enx))
                  o (list
                      (cond
                        ((member j '(2 5 8)) (/ w -2.0))
                        ((member j '(3 6 9)) (- w))
                        (0.0)
                      )
                      (cond
                        ((member j '(1 2 3)) (- h))
                        ((member j '(4 5 6)) (/ h -2.0))
                        (0.0)
                      )
                    )
            )
            (list
              (list (car o) (cadr o))
              (list (+ (car o) w) (cadr o))
              (list (+ (car o) w) (+ (cadr o) h))
              (list (car o) (+ (cadr o) h))
            )
           )
         )
  )
  (setq        l
         ((lambda (m)
            (mapcar
              '(lambda (p)
                 (mapcar '+
                         (mapcar '(lambda (r) (apply '+ (mapcar '* r p))) m)
                         b
                 )
               )
              l
            )
          )
           (list
             (list (cos r) (sin (- r)) 0.0)
             (list (sin r) (cos r) 0.0)
             '(0.0 0.0 1.0)
           )
         )
  )
  (mapcar '(lambda (x) (trans x n 0)) l)
)[/pcode]

Lisphk

Faster 发表于 2013-5-2 13:30

                               
登录/注册后可看大图

(defun getTextminBox (EN / ENX L B R N W H J O ob tan)
(defun tan (a)
  (/ (sin a) (cos a))

谢谢！ 借用你的图测试下，为什么结果是这样？ 我运行你提供的代码，提示tan函数没有，猜是求正切的，就自己写了个，但是结果却不是我想要的。

淫约黄昏

学习学习！

Free-Lancer

得到一个正放的TextBox，如匹配到实体或者有旋转的可以用矩阵再次转换[pcode=lisp,true](defun GetTextBox (el / box p1 p3 c71 tf c51 an v l p2 p4 tb)
  (setq        box (textbox (list (assoc 1 el)
                           (assoc 40 el)
                           (assoc 50 el)
                           (assoc 41 el)
                           (setq c51 (assoc 51 el))
                           (assoc 7 el)
                     )
            )
        p1  (car box)
        p3  (cadr box)
        c71 (cdr (assoc 71 el))
        an  (cdr c51)
        tf  (zerop an)
        v   (mapcar '- p3 p1)
  )
  (if (not tf)
    (setq l (* (/ (cadr v) (sin an)) (cos an)))
    (setq l 0.)
  )
  (setq        vl (- (car v) l)
        p2 (polar p1 0. vl)
        p4 (polar p3 pi vl)
        tb (list p1 p2 p3 p4)
  )
  (cond
    ((= c71 2)
     (mapcar (function (lambda (x) (mapcar '* '(-1 1 0) x))) tb)
    )
    ((= c71 4)
     (mapcar (function (lambda (x) (mapcar '* '(1 -1 0) x))) tb)
    )
    ((= c71 6)
     (mapcar (function (lambda (x) (mapcar '* '(-1 -1 0) x))) tb)
    )
    (t tb)
  )
)
(defun c:tt (/ e box)
  (if (setq e (car (entsel)))
    (progn
      (setq box (GetTextBox (entget e)))
      (apply 'vl-cmdf (cons ".pline" box))
      (vl-cmdf "c")
      (vl-cmdf "_move"
               "l"
               ""
               "_None"
               '(0. 0. 0.)
               (cdr (assoc 10 (entget e)))
      )
    )
  )
  (princ)
)[/pcode]

tsxy

谢谢楼主分享！学习学习，:(:(