[求助]：怎样用CAD 画塔形弹簧的实体

弦外有音

各位高手，小弟近日碰到 一个难题，就要要用CAD画实体的锥形弹簧，小弟水平有限，实在没有办法，请各位高手不吝赐教，拔刀相助，在下先谢恩了*-*3

贱人

命令a1、a2
每圈点数可以调节精度

(defun myerror (s)  
  (if (/= s "Function cancelled")
    (princ (strcat "\n错误： " s))
  )
  (setvar "cmdecho" ocmd)             ; 恢复已保存的模式
  (setvar "blipmode" oblp)
  (setq *error* olderr)               ; 恢复旧的*error* 句柄
  (princ)
)

(defun cspiral (ntimes bpoint hfac lppass strad vfac
                / ang dist tp ainc dhinc dvinc circle dv)
  (setvar "blipmode" 0)               ; 关闭blipmode
  (setvar "cmdecho" 0)                ; 关闭cmdecho
  (setq circle (* 3.141596235 2))
  (setq ainc (/ circle lppass))
  (setq dhinc (/ hfac lppass))
  (if vfac (setq dvinc (/ vfac lppass)))
  (setq ang 0.0)
  (if vfac
    (setq dist strad dv 0.0)
    (setq dist 0.0)
  )
  (if vfac
    (command "3dpoly")                ; 开始绘制螺旋线 ...
    (command "pline" bpoint)          ; 开始从基点绘制螺旋线并...
  )
  (repeat ntimes
    (repeat lppass
      (setq tp (polar bpoint (setq ang (+ ang ainc))
                      (setq dist (+ dist dhinc))
               )
      )
      (if vfac
          (setq tp (list (car tp) (cadr tp) (+ dv (caddr tp)))
                dv (+ dv dvinc)
          )
      )
      (command tp)                    ; 继续到下一点...
    )
  )
  (command "")                        ; 直到完成。
  (princ)
)

;Interactive spiral generation

(defun C:a1 (/ olderr ocmd oblp nt bp cf lp)
  ;(setq olderr  *error*
  ;      *error* myerror)
  (setq ocmd (getvar "cmdecho"))
  (setq oblp (getvar "blipmode"))
  (setvar "cmdecho" 0)
  (initget 1)                         ; bp不必为空
  (setq bp (getpoint "\n中心点： "))
  (initget 7)                         ; nt不必为零、负或空
  (setq nt (getint "\n圈数： "))
  (initget 3)                         ; cf不必为零或空
  (setq cf (getdist "\n步长： "))
  (initget 6)                         ; lp不必为零或负
  (setq lp (getint "\n每圈点数 <30>： "))
  (cond ((null lp) (setq lp 30)))
  (cspiral nt bp cf lp nil nil)
  (setvar "cmdecho" ocmd)
  (setvar "blipmode" oblp)
  (setq *error* olderr)               ; 恢复旧的*error* 句柄
  (princ)

)

;Interactive spiral generation

(defun C:a2 (/ olderr ocmd oblp nt bp hg vg sr lp)
  ;(setq olderr  *error*
  ;      *error* myerror)
  (setq ocmd (getvar "cmdecho"))
  (setq oblp (getvar "blipmode"))
  (setvar "cmdecho" 0)
  (initget 1)                         ; bp不必为null
  (setq bp (getpoint "\n中心点： "))
  (initget 7)                         ; nt不必为零、负或空
  (setq nt (getint "\n圈数： "))
  (initget 7)                         ; sr不必为零、负或空
  (setq sr (getdist bp "\n起始半径： "))
  (initget 1)                         ; cf不必为零或空
  (setq hg (getdist "\n水平步长： "))
  (initget 3)                         ; cf不必为零或空
  (setq vg (getdist "\n垂直步长： "))
  (initget 6)                         ; lp不必为零或负
  (setq lp (getint "\n每圈点数 <30>： "))
  (cond ((null lp) (setq lp 30)))
  (cspiral nt bp hg lp sr vg)
  (setvar "cmdecho" ocmd)
  (setvar "blipmode" oblp)
  (setq *error* olderr)               ; 恢复旧的*error* 句柄
  (princ)
)
(princ)

弦外有音

在此感谢贱人的帮忙，只可惜我用的是AUTOCAD2004中文版，有点看不明白

贱人

a1可以画平面螺旋线，a2可以画塔形螺旋线，画完在段点画个圆，沿路径拉伸就好了
和cad版本没什么关系吧，我也是2004

ailing109

我还是看不明白啊

弦外有音

我用的是AUTODESK公司的AUTOCAD2004呀，不是什么天正和什么中旺呀

liuxg2005

感谢贱人的程序