[编程申请]：超级scale命令

lain · 发表于 2003-4-20 13:28:04

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

cad中的scale命令只能沿xy轴等比缩放，我想能否实现一个超级scale命令，
可以选择沿x轴、沿y轴、沿xy轴缩放。

自己想了个命令格式如下：
Command: xSCALE
Select objects: 1 found

Select objects:
缩放方向（1、沿X轴；2、沿Y轴；3、沿XY轴）:1
Specify base point:
Specify scale factor or [Reference]: r

Specify reference length <1>: Specify second point:
Specify new length:
请各位同仁指教。

eachy · 发表于 2003-4-20 22:36:53

等Autodesk提供解决命令吧，或者用Ctrl+X后Ctrl+V（or Ctrl+Shift+V）然后调整特性。

zhynt · 发表于 2003-4-23 16:21:14

是不是可以这样呢，正如上面说的，编程，选择对象，做成块，根据提供的参数插入该块，最后再炸开。也就是把上面说的程序化。

LUCAS · 发表于 2003-4-26 16:33:36

你是說這個嗎???
http://www.xdcad.net/forum/showt ... ostid=6406#post6406

nmsssb · 发表于 2003-4-26 17:09:59

其实该构思不够全面，我收集了一个lisp程序。
命令名：XSCALE
对选择图元得X,Y,Z三个方向进行不等比例得缩放，解决了scale命令的局限问题。

;;; XSCALE.LSP / 04JUL95 / 03MAY96
;;;
;;; Copyright (C) 1995, 1996 by Thomas Berger
;;;
;;; FREEWARE:
;;; Permission to use, copy, modify, and distribute this software
;;; for any purpose and without fee is hereby granted, provided
;;; that the above copyright notice appears in all copies and
;;; that both that copyright notice and the limited warranty and
;;; restricted rights notice below appear in all supporting
;;; documentation.
;;;
;;; THOMAS BERGER PROVIDES THIS PROGRAM "AS IS" AND WITH ALL FAULTS.
;;; THOMAS BERGER SPECIFICALLY DISCLAIMS ANY IMPLIED WARRANTY OF
;;; MERCHANTABILITY OR FITNESS FOR A PARTICULAR USE. THOMAS BERGER
;;; DOES NOT WARRANT THAT THE OPERATION OF THE PROGRAM WILL BE
;;; UNINTERRUPTED OR ERROR FREE.
;;;
;;;
;;; ****************************************************************
;;; XSCALE: xyz scaling of selected entities
;;;
;;; AutoCAD version: R13 only, ACIS solids need R13 C2 or higher
;;;
;;; functions:
;;; C:XSCALE for use at the command prompt
;;; (XSCALE sset basepoint xscale yscale zscale) for API usage
;;; (MAKEBLOCK name basepoint sset xscale yscale zscale rotation)
;;; to entmake blocks (anonymous block if name="*")
;;; C:MAKEBLOCK for use at the command prompt
;;;
;;; known bugs:
;;; there is an AutoCAD bug still existent in R13c4 that
;;; does not allow to explode blocks correctly with equal scaling
;;; in X- and Y-direction and a different factor in Z-direction. In this
;;; special case the exploded block will fall back to the 1-1-1
;;; scaling.
;;; Workaround:
;;; Use slightly different scaling factors for the X- and the
;;; Y-direction (i.e 1.00001 and 0.999999)
(defun xscale (sset basp xscale yscale zscale / )
(if (makeblock "*" basp sset xscale yscale zscale 0)
(command "._explode" (entlast))
)
)
(defun c:xscale (/ oldecho olderr temp xs ys zs basp sset)
(setq oldecho (getvar "cmdecho") olderr *error*)
(command "._undo" "_group")
(defun *error* (msg)
(setq *error* olderr)
(princ (strcat "\nXSCALE: " msg "\n"))
(prin1)
)
(setvar "cmdecho" 0)
(setq basp (while (not temp) (setq temp (getpoint "\nbase point: ")))
sset (if (< 0 (sslength (setq temp (ssget)))) temp nil)
xs (if sset (if (not (setq temp (getdist basp "\nX-scale <1>: "))) 1 temp))
ys (if sset (if (not (setq temp (getdist basp "\nY-scale <1>: "))) 1 temp))
zs (if sset (if (not (setq temp (getdist basp "\nZ-scale <1>: "))) 1 temp))
)
(if (and basp sset xs ys zs)
(xscale sset basp xs ys zs)
)
(command "._undo" "_end")
(setq *error* olderr)
(setvar "cmdecho" oldecho)
(prin1)
)
(defun makeblock (name baspoint sset xs ys zs rot / i e en blocktype)
(if sset nil (setq sset (ssadd)))
(if (or (/= 'STR (type name)) (= "" name)) (setq name "*A"))
(if (= (substr name 1 1) "*")
(setq blocktype 1 name "*A")
(setq blocktype 0)
)
(entmake (append
'((0 . "BLOCK"))
(list (cons 2 name))
(list (cons 70 blocktype))
(list (cons 10 baspoint))
))
(setq i -1)
(while (setq e (ssname sset (setq i (1+ i))))
(cond
((/= 1 (cdr (assoc 66 (entget e))))
(if (entget e) (progn
(entmake (entget e '("*")))
(entdel e)
))
)
((= 1 (cdr (assoc 66 (entget e))))
(if (entget e) (progn
(entmake (entget e '("*")))
(setq en e)
(while (/= "SEQEND" (cdr (assoc 0 (entget en))))
(setq en (entnext en))
(entmake (entget en '("*")))
)
(entdel e)
))
)
)
)
(setq name (entmake '((0 . "ENDBLK"))))
(if name (progn
(entmake (append
'((0 . "INSERT"))
(list (cons 2 name))
(list (cons 10 baspoint))
(list (cons 41 xs))
(list (cons 42 ys))
(list (cons 43 zs))
(list (cons 50 (/ (* PI rot) 180.0)))
))
))
(if name (entlast) nil)
)
(defun c:makeblock ()
(makeblock (getstring "\nName: ") (getpoint "\nInsertionpoint: ") (ssget) 1 1 1 0 )
)
(princ "\nXSCALE: scales AutoCAD Entities non-uniformly in X-,Y- and Z-direction!")
(prin1)

;;;    XSCALE.LSP / 04JUL95 / 03MAY96 
;;;    
;;;    Copyright (C) 1995, 1996 by Thomas Berger 
;;; 
;;;    FREEWARE: 
;;;    Permission to use, copy, modify, and distribute this software 
;;;    for any purpose and without fee is hereby granted, provided 
;;;    that the above copyright notice appears in all copies and 
;;;    that both that copyright notice and the limited warranty and 
;;;    restricted rights notice below appear in all supporting 
;;;    documentation. 
;;; 
;;;    THOMAS BERGER PROVIDES THIS PROGRAM "AS IS" AND WITH ALL FAULTS. 
;;;    THOMAS BERGER SPECIFICALLY DISCLAIMS ANY IMPLIED WARRANTY OF 
;;;    MERCHANTABILITY OR FITNESS FOR A PARTICULAR USE.  THOMAS BERGER 
;;;    DOES NOT WARRANT THAT THE OPERATION OF THE PROGRAM WILL BE 
;;;    UNINTERRUPTED OR ERROR FREE. 
;;; 
;;; 
;;;    **************************************************************** 
;;;    XSCALE: xyz scaling of selected entities 
;;; 
;;;    AutoCAD version: R13 only, ACIS solids need R13 C2 or higher 
;;; 
;;;    functions: 
;;;       C:XSCALE     for use at the command prompt 
;;;       (XSCALE sset basepoint xscale yscale zscale)  for API usage 
;;;       (MAKEBLOCK name basepoint sset xscale yscale zscale rotation) 
;;;          to entmake blocks (anonymous block if name="*") 
;;;       C:MAKEBLOCK     for use at the command prompt 
;;; 
;;;    known bugs: 
;;;       there is an AutoCAD bug still existent in R13c4 that 
;;;       does not allow to explode blocks correctly with equal scaling 
;;;       in X- and Y-direction and a different factor in Z-direction. In this 
;;;       special case the exploded block will fall back to the 1-1-1 
;;;       scaling. 
;;;      Workaround: 
;;;       Use slightly different scaling factors for the X- and the 
;;;       Y-direction (i.e 1.00001 and 0.999999) 
 
 
(defun xscale (sset basp xscale yscale zscale / ) 
(if (makeblock "*" basp sset xscale yscale zscale 0) 
        (command "._explode" (entlast)) 
) 
) 
 
 
(defun c:xscale (/ oldecho olderr temp xs ys zs basp sset) 
        (setq oldecho (getvar "cmdecho") olderr *error*) 
        (command "._undo" "_group") 
        (defun *error* (msg) 
                (setq *error* olderr) 
                (princ (strcat "\nXSCALE: " msg "\n")) 
                (prin1) 
        ) 
        (setvar "cmdecho" 0) 
        (setq basp (while (not temp) (setq temp (getpoint "\nbase point: "))) 
                        sset (if (< 0 (sslength (setq temp (ssget)))) temp nil) 
                        xs (if sset (if (not (setq temp (getdist basp "\nX-scale <1>: "))) 1 temp)) 
                        ys (if sset (if (not (setq temp (getdist basp "\nY-scale <1>: "))) 1 temp)) 
                        zs (if sset (if (not (setq temp (getdist basp "\nZ-scale <1>: "))) 1 temp)) 
        ) 
        (if (and basp sset xs ys zs) 
                (xscale sset basp xs ys zs) 
        ) 
        (command "._undo" "_end") 
        (setq *error* olderr) 
        (setvar "cmdecho" oldecho) 
        (prin1) 
) 
 
 
(defun makeblock (name baspoint sset xs ys zs rot / i e en blocktype) 
(if sset nil (setq sset (ssadd))) 
(if (or (/= 'STR (type name)) (= "" name)) (setq name "*A")) 
(if (= (substr name 1 1) "*") 
        (setq blocktype 1 name "*A") 
        (setq blocktype 0) 
) 
(entmake (append 
        '((0 . "BLOCK")) 
        (list (cons 2  name)) 
        (list (cons 70 blocktype)) 
        (list (cons 10 baspoint)) 
)) 
(setq i -1) 
(while (setq e (ssname sset (setq i (1+ i)))) 
        (cond 
                ((/= 1 (cdr (assoc 66 (entget e)))) 
                        (if (entget e) (progn 
                                (entmake (entget e '("*"))) 
                                (entdel e) 
                        )) 
                ) 
                ((= 1 (cdr (assoc 66 (entget e)))) 
                        (if (entget e) (progn 
                                (entmake (entget e '("*"))) 
                                (setq en e) 
                                (while (/= "SEQEND" (cdr (assoc 0 (entget en)))) 
                                        (setq en (entnext en)) 
                                        (entmake (entget en '("*"))) 
                                ) 
                                (entdel e) 
                        )) 
                ) 
        ) 
) 
(setq name (entmake '((0 . "ENDBLK")))) 
(if name (progn 
        (entmake (append 
                '((0 . "INSERT")) 
                (list (cons 2 name)) 
                (list (cons 10 baspoint)) 
                (list (cons 41 xs)) 
                (list (cons 42 ys)) 
                (list (cons 43 zs)) 
                (list (cons 50 (/ (* PI rot) 180.0))) 
        )) 
 
)) 
(if name (entlast) nil) 
) 
 
 
(defun c:makeblock () 
(makeblock (getstring "\nName: ") (getpoint "\nInsertionpoint: ") (ssget) 1 1 1 0 ) 
) 
 
(princ "\nXSCALE: scales AutoCAD Entities non-uniformly in X-,Y- and Z-direction!") 
(prin1)

lain · 发表于 2003-4-26 18:54:08

可惜pline线变成line,宽度等还是不能保留
谢谢nmsssb 等楼上的各位高手！顺祝各位五一节休息的好！！？

madbull · 发表于 2003-6-5 23:00:17

最初由 lain 发布
[B]可惜pline线变成line,宽度等还是不能保留
谢谢nmsssb 等楼上的各位高手！顺祝各位五一节休息的好！！？ [/B]

那位大虾能把这个问题解决一下?

efan2000 · 发表于 2003-6-5 23:37:18

这种方法是先将实体生成一个块，而块则可以进行X、Y或者Z方向的比例缩放，最后再将块炸开，这样块中的多段线就自然变成直线了。

madbull · 发表于 2003-6-5 23:52:12

可以当时不炸开吗?当然,如果必要的话可以自己事后在炸开.

efan2000 · 发表于 2003-6-6 00:15:23

当然可以，将程序中的(command "._explode" (entlast))这一句去掉就不会炸开了。

madbull · 发表于 2003-6-6 11:28:43

不行.
将程序中的(command "._explode" (entlast))这一句去掉后,加载程序时提示:: (LOAD "C:/Documents and Settings/madbull1/桌面/xscale.lsp") ; 错误:
语法错误.如果去掉(defun xscale (sset basp xscale yscale zscale / )
(if (makeblock "*" basp sset xscale yscale zscale 0)
(command "._explode" (entlast))
)
)
加载时不提示有错误了,但是缩放后物体仍被炸开.
另外我还担心:即使物体不被砸开了,如果在同一张图中缩放两个以上的物体,块名称会不会又冲突?

song123 · 发表于 2005-3-23 06:48:54

你输入缩放比例命令后在输入X就可以了

jx2008 · 发表于 2008-3-20 09:23:55

还是涉及到块，并炸开后都变成了直线了，能不能不用块就可以实现xyz不同比例缩放呢？

账号		自动登录	找回密码
密码			立即注册

[编程申请]：超级scale命令

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子

XY可以不等比例缩放

浏览过的版块