[求助]：动态画线程序有时可用有时出错，高手帮忙！

wangwangnn

自编了一个动态画平行线的程序（选择被平行对象，随着鼠标移动出现它的平行线，点鼠标左键跳出对话框响应此时的偏移距离也可更改数值，点确定及刻画出），但有时用的挺好，有时却出错，比如，两次都选同一个对象作偏移的对象，就容易出问题，不知何因，还请高手帮忙看看！
;;;----------------------------------------------------------
;;;画动态平行线
(defun draw_dline (/ os en endata tmp a p dd)
  (defun dcl_dia1a (en / dcl_id ostr nstr oke) ;调用对话框子函数
    (setq dcl_id (load_dialog "pattendia.dcl"))
    (if        (not (new_dialog "length010" dcl_id))
      (exit)
    )
    (setq ostr (rtos (distance (cadr a) p)))
    (set_tile "l" ostr)
    (setq nstr ostr)
    (mode_tile "l" 2)
    (action_tile "l" "(setq nstr $value) ")
    (action_tile "accept" "(done_dialog 1)")
    (action_tile "cancel" "(entdel (entlast))(done_dialog 0)")
    (setq oke (start_dialog))
    (if        (= oke 1)
      (progn
        (entdel (entlast))
        (command "offset" (atof nstr) en (cadr a) "")
      )
    )
    (unload_dialog dcl_id)
  )
  ;;子函数结束
  (vl-load-com)
  (setvar "cmdecho" 0)
  (setq os (getvar "osmode"))
  (setvar "osmode" 0)
  (setq ent (car (entsel "\n 选取被平行线:")))
  (setq endata (entget ent))
  (command ".copy" ent "" "@" "@")

  (SETQ tmp t)
  (while tmp
    (setq a (grread t 4 0))
    (cond
      ((= (car a) 5)
       (entdel (entlast))
       (setq p (vlax-curve-getClosestPointTo
                 (vlax-ename->vla-object ent)
                 (cadr a)
               )
       )
       (setq dd (distance (cadr a) p))
       (command ".offset" dd ent (cadr a) "")

      )
      ((= (car a) 3)
       (entdel (entlast))
       (setq p (vlax-curve-getClosestPointTo
                 (vlax-ename->vla-object ent)
                 (cadr a)
               )
       )
       (setq dd (distance (cadr a) p))
       (command ".offset" dd ent (cadr a) "")

       (setq tmp nil)

      )
    )
  )
  (dcl_dia1a ent)
  (setvar "osmode" os)
  (princ)
)


//平行线对话框 pattendia.dcl
  length010: dialog{
        label="平行线";
        :concatenation{
                  :text_part {label="间隔=";}
                  :edit_box{edit_width=15;key="l";}
                  :text_part {label="cm";}
        }
        spacer_1;
        ok_cancel;
}

ljpnb

把DD改成(+ dd 0.001)即可，当DD是0的时候程序会出错，因为offset的偏移距离不能为0