[求助]：[0227]如何取出字串中"数值"与"非数值"资料方法?

tctabc

[求助]：[0227]如何取出字串中"数值"与"非数值"资料方法?
如一段属性为STR内容为 "面积:2153.512,(本基地)"
该怎取出其数值部份 "2153.512" 呢?
烦请各位高手解答一下
谢谢~

lazybug

取asciii码(and (>47) (< 58))
另外,还要考虑一下"."

marcoyuwen

稍带说一句，函数CLIP2输入字符串，返回表，见程序开始的注释，不知是否合tctabc的意？
;;;2.CLIP2 Ver 1.0 2005.9.25 16:06
;;;作者：保定电力设计研究院marcoyuwen
;;;以下程序将"."分不同情况进行处理，前或后有数字时将"."归为数字，否则归为字符串
;;;如strnr="5.5bbb1245.cc"，则结果为("5.5" "bbb" "1245." "cc")
;;;如strnr=".5bbb1245aaa"，则结果为(".5" "bbb" "1245" "aaa")

(defun CLIP2( strnr / strcd ltstrs chastr numstr posi charnr charas numor charash charsq)

    (setq strcd (strlen strnr))
    (setq ltstrs (list))
    (setq chastr "")
    (setq numstr "")
    (setq posi 1)
    (repeat strcd
        (setq charnr (substr strnr posi 1))
        (setq charas (ascii charnr))

        (cond ((and (>= charas 48) (<= charas 57)) (setq numor T))

              ((= charas 46) (cond ((= posi 1) (setq charash (ascii (substr strnr 2 1)))
                                               (if (and (>= charash 48) (<= charash 57)) (setq numor T)
                                                                                         (setq numor nil)
                                               );end if
                                   );end posi=1

                                   ((= posi strcd) (setq charasq (ascii (substr strnr (1- strcd) 1)))
                                                   (if (and (>= charasq 48) (<= charasq 57)) (setq numor T)
                                                                                             (setq numor nil)
                                                   );end if
                                   );end posi=strcd

                                   (T (setq charasq (ascii (substr strnr (1- posi) 1)))
                                      (setq charash (ascii (substr strnr (1+ posi) 1)))
                                      (if (or (and (>= charasq 48) (<= charasq 57))
                                              (and (>= charash 48) (<= charash 57))
                                          );end or
                                          (setq numor T)
                                          (setq numor nil)
                                      );end if

                                   );end 1<posi<strcd
                             );end cond
              );end charas=46,charnr=.

              (T (setq numor nil))
        );end cond

        (if numor
            (progn
                (if (/= chastr "") (progn
                                       (setq ltstrs (append ltstrs (list chastr)))
                                       (setq chastr "")
                                   );end progn
                );end if
                (setq numstr (strcat numstr charnr))
            );end progn

            (progn
                (if (/= numstr "") (progn
                                       (setq ltstrs (append ltstrs (list numstr)))
                                       (setq numstr "")
                                   );end progn
                );end if
                (setq chastr (strcat chastr charnr))
            );end progn
        );end if numor
        (setq posi (1+ posi))
    );end repeat

    (if (/= chastr "") (setq ltstrs (append ltstrs (list chastr))))
    (if (/= numstr "") (setq ltstrs (append ltstrs (list numstr))))

    (if ltstrs ltstrs nil)
);end defun CLIP2