[求助]：超快速 直角连接线

idchris

可否各位高手如下图所示
两个快
图1.首先点第一个快.
图2.在点另一个快之后.
图3.再点在第四象限(或第二象限).
图4.完成直角连接.

补充:能否在圆角处设半径输入值.
各位高手恳请相助

                               
登录/注册后可看大图

zxq0220

[php]
(DEFUN C:RightAngle ()
(SETVAR "CMDECHO" 0)
(SETQ OLDOS (GETVAR "OSMODE"))
(SETQ R (IF R R 0))
(SETQ R1 (GETDIST (STRCAT "\nEnter Radius <" (RTOS R 2 3) "> :"))
       R (IF R1 R1 R))
(IF (SETQ S1 (ENTSEL "\nSelect First Circle :"))
  (IF (SETQ S2 (ENTSEL "\nSelect Second Circle :")) (PROGN
   (SETQ ENT1 (ENTGET (CAR S1)) ENT2 (ENTGET (CAR S2))
         EN1 (CDR (ASSOC 0 ENT1)) EN2 (CDR (ASSOC 0 ENT2)))
   (IF (= EN1 EN2 "CIRCLE") (PROGN
    (SETQ PC1 (CDR (ASSOC 10 ENT1)) PC2 (CDR (ASSOC 10 ENT2))
          R1 (CDR (ASSOC 40 ENT1)) R2 (CDR (ASSOC 40 ENT2)))
    (IF (SETQ PT1 (INTERS PC1 (OSNAP (CADR S1) "QUA") PC2 (OSNAP (CADR S2) "QUA") nil))
    (PROGN
     (SETQ PT2 (POLAR PT1 (ANGLE PT1 PC1) R)
           PT3 (POLAR PT1 (ANGLE PT1 PC2) R)
           PT4 (POLAR PC1 (ANGLE PC1 PT1) R1)
           PT5 (POLAR PC2 (ANGLE PC2 PT1) R2))
     (SETVAR "OSMODE" 0)
     (COMMAND "PLINE" PT4 PT2 "A" PT3 "L" PT5 "")
     (SETVAR "OSMODE" OLDOS)
    ))
   ))
  ))
)
(SETVAR "OSMODE" OLDOS)
(SETVAR "CMDECHO" 1)
(PRINC)
)
[/php]

idchris

很感谢大大的帮助

但我希望选的并不是圆或是图块
而是点的位置(图1,图2)
而(图3)是帮我确定直角的方向

希望大大能再帮我更改

zxq0220

[php]
(DEFUN C:RightAngle ()
(SETVAR "CMDECHO" 0)
(SETQ OLDOS (GETVAR "OSMODE") OLDBI (GETVAR "BLIPMODE"))
(SETQ R (IF R R 0))
(SETQ R1 (GETDIST (STRCAT "\nEnter Radius <" (RTOS R 2 3) "> :"))
       R (IF R1 R1 R))
(IF (SETQ PT1 (GETPOINT "\nSelect First Point :"))
  (IF (SETQ PT2 (GETPOINT "\nSelect Second Point :"))
   (IF (SETQ PT3 (GETPOINT "\nThe Orientation ")) (PROGN
    (SETQ PT4 (LIST (CAR PT1) (CADR PT2))
          PT5 (LIST (CAR PT2) (CADR PT1)))
    (SETQ PT4 (IF (> (DISTANCE PT4 PT3) (DISTANCE PT5 PT3)) PT5 PT4))
    (SETQ PT5 (POLAR PT4 (ANGLE PT4 PT1) R)
          PT6 (POLAR PT4 (ANGLE PT4 PT2) R))
    (SETVAR "OSMODE" 0)
    (SETVAR "BLIPMODE" 0)
    (COMMAND "PLINE" PT1 PT5 "A" PT6 "L" PT2 "")
    (SETVAR "BLIPMODE" OLDBI)
    (SETVAR "OSMODE" OLDOS)
   ))
  )
)
(SETVAR "CMDECHO" 1)
(PRINC)
)
[/php]

idchris

真的,真的…很感谢你的帮忙.
本人还有很多快速做图的方法,
想写些指令来加快速度,
只是还在摸索程序,
希望还有机会能得到你的鼎力帮助
谢谢…