[求助]：如何用lisp删除。创建图层过滤器?

libo2000

如何用lisp删除。创建图层过滤器?
N千多个图层过滤器，每次打开图层管理器都要半天时间，烦死了！

Underway

http://discussion.autodesk.com/thread.jspa?messageID=1194782

(defun C:fildel        ()
  (vl-Load-Com)
  (vl-Catch-All-Apply
    '(lambda ()
       (vla-Remove
         (vla-GetExtensionDictionary
           (vla-Get-Layers
             (vla-Get-ActiveDocument
               (vlax-Get-Acad-Object)
             )
           )
         )
         "ACAD_LAYERFILTERS"
       )
     )
  )
  (princ "\nAll layer filters have been deleted.")
  (princ)
)



(defun c:filtrdel (/ names)
  (vl-Load-Com)
  (textscr)
  (princ
    (strcat  
      "\nRoutine to delete all but the specified Layer filters. "
      "When entering filter names to retain, wildcards are allowed. "
      "i.e., entering \"zz*,xx*\" will delete all filters "
      "except those beginning with zz and xx."
  ) )
  (setq names (getstring  "\nEnter filter names to retain, press Enter for none: "))
  
  (vl-Catch-All-Apply
    '(lambda ()
       (setq dicts (vla-GetExtensionDictionary
                     (vla-Get-Layers
                       (vla-Get-ActiveDocument
                         (vlax-Get-Acad-Object)
                       )
                     )
                   )
       )
       (vlax-for dict dicts
         (if (and (= (vla-get-name dict) "ACAD_LAYERFILTERS")
                  (> (vla-get-count dict) 0)
             )
           (progn
             (vlax-for filtr dict
               (if (not (wcmatch (vla-get-name filtr) names))
                 (vla-delete filtr)
               )
             )
           )
         )
       )
     )
  )
  (graphscr)
  (princ "\nSpecified layer filters have been deleted.")
  (princ)
)

snoopychen

http://www.theswamp.org/index.php?topic=7560.msg113739#msg113739
有个专门讨论这个的帖子和几个源码