[求助]：有什么办法和并程序？

nuance · 发表于 2007-5-22 09:18:48

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

(defun c:15()
(command "text" pt .... "DN15")
)
(defun c:20()
(command "text" pt .... "DN20")
)

同样类似的程序很多，十几二十几个，有什么办法整合到一个程序里？

Underway · 发表于 2007-5-22 11:55:12

您有什么样的想法
或者说您想怎样执行 .....

adisonmaster · 发表于 2007-5-22 13:05:44

可以在程序中输入钢管的管径，使用GETINT函数就可以了。

zml84 · 发表于 2007-5-22 16:17:21

试一试下面这个如何：

(defun C:DN (/ INT)
(if (setq INT (getint "\n请输入钢管直径:"))
(while (setq PT0 (getpoint "\n插入位置:"))
(command "_.text" pt0 20 0 (strcat "DN" (itoa INT)))
)
)
(princ)
)

nuance · 发表于 2007-5-23 08:49:53

楼上的做法编程序简单，用起来不方便，先输入DN回车，再输管径，大量标注时效率不高

zml84 · 发表于 2007-5-23 15:44:49

最初由 nuance 发布
[B]楼上的做法编程序简单，用起来不方便，先输入DN回车，再输管径，大量标注时效率不高 [/B]

那谈谈你的需求？！

nuance · 发表于 2007-5-23 17:15:50

如果要编15，20，25，32，40，50，70，80，100，125，150，200，250，300等程序，每个都要编一个程序，程序是基本相同的，对维护程序不利，能不能把所有程序整合到一个里，例如
(defun c:15()
(sub-defun)
)
defun c:20()
(sub-defun)
)
....
defun c:300()
(sub-defun)
)

(defun sub-defun
(.....grread 读取命令行，例如15，然后command "text" ......"15")
)

我只是这样想，不要被误导

highflybird · 发表于 2007-5-23 17:37:44

(defun C:DN (/ INT)
(while (setq INT (getint "\n请输入钢管直径:"))
(if (setq PT0 (getpoint "\n插入位置:"))
(command "_.text" pt0 20 0 (strcat "DN" (itoa INT)))
)
)
(princ)
)

zml84的确思路本来是正确的，只要改一下就可以了啊，象上面这样就可以了
如果有一千个管径，难道你要编写一千个程序不成？

zml84 · 发表于 2007-5-23 23:15:29

一、代码不断优化的目的之一就是使其符合用户的需求，应该在简化输入和合理组织响应次序等方面做努力。
以添加选项的方式解决问题，代码见：

<HR SIZE=5><PRE>;;;全局变量使用示例-------记忆前次运行所输入的数据
;;;在用户响应中添加选项示例
;;;=================================================
;;功能：以文字的形式标注管径
;;全局变量说明：D-OLD 整数前次所采用的管径
(defun C:DN (/ LST PT TMP)
;;管径有效值（白名单）
(setq LST '(15 20 25 32 40 50 70 80 100 125 150 200 250 300))
;;检查全局变量若无则赋初值
(if (= D-OLD NIL)
(setq D-OLD (car LST))
)
;;显示当前设置
(princ (strcat "\n>>>当前设置:管径=" (itoa D-OLD)))
;;循环问询
(while
(progn (initget 4 "D")
(setq PT (getpoint "\n请指定插入位置，或 [管径(D)]:"))
)
(cond
;;分支一：管径设置
((= PT "D")
(if (setq TMP
(getint
(strcat "\n请输入钢管直径 <" (itoa D-OLD) ">:")
)
)
;;对用户输入进行有效性检查
(if (member TMP LST)
(setq D-OLD TMP)
(progn
(princ
"\n>>>注意：数据有误。\n输入的数据必须为以下其中之一："
)
(princ LST)
)
)
)
)
;;分支二：点取了点位
((listp PT)
(command "_.text" PT 20 0 (strcat "DN" (itoa D-OLD)))
)
) ;_结束 COND
) ;_结束 while
(princ)
) ;_结束 defun
;;;=================================================
;;;后话：通过在响应中添加选项，可以简化操作，方便使用。
</PRE>

<HR SIZE=5><PRE>;;;全局变量使用示例-------记忆前次运行所输入的数据 
;;;在用户响应中添加选项示例 
;;;================================================= 
;;功能：以文字的形式标注管径 
;;全局变量说明：D-OLD  整数  前次所采用的管径 
(defun C:DN (/ LST PT TMP) 
    ;;管径有效值（白名单） 
    (setq LST '(15 20 25 32 40 50 70 80 100 125 150 200 250 300)) 
    ;;检查全局变量 若无则赋初值 
    (if        (= D-OLD NIL) 
        (setq D-OLD (car LST)) 
    ) 
    ;;显示当前设置 
    (princ (strcat "\n&gt;&gt;&gt;当前设置:管径=" (itoa D-OLD))) 
    ;;循环问询 
    (while 
        (progn (initget 4 "D") 
               (setq PT (getpoint "\n请指定插入位置，或 [管径(D)]:")) 
        ) 
           (cond 
               ;;分支一：管径设置 
               ((= PT "D") 
                (if (setq TMP 
                             (getint 
                                 (strcat "\n请输入钢管直径 &lt;" (itoa D-OLD) "&gt;:") 
                             ) 
                    ) 
                    ;;对用户输入进行有效性检查 
                    (if        (member TMP LST) 
                        (setq D-OLD TMP) 
                        (progn 
                            (princ 
                                "\n&gt;&gt;&gt;注意：数据有误。\n输入的数据必须为以下其中之一：" 
                            ) 
                            (princ LST) 
                        ) 
                    ) 
                ) 
               ) 
               ;;分支二：点取了点位 
               ((listp PT) 
                (command "_.text" PT 20 0 (strcat "DN" (itoa D-OLD))) 
               ) 
           ) ;_结束 COND 
    ) ;_结束 while 
    (princ) 
) ;_结束 defun 
;;;================================================= 
;;;后话：通过在响应中添加选项，可以简化操作，方便使用。 
</PRE>

参见：http://zml84.blog.sohu.com/47343318.html
 
二、按照1楼的要求，将多个命令整合到一段代码中定义，代码如下：

<HR SIZE=5><PRE>;;; eval函数示例------定义以表中元素为名称的命令
;;;日期：zml84 于 2007-05-24
;;;============================================================
;;;功能：定义系列命令，用于标注管径
(defun C:TT (/ LST I A B)
(setvar "CMDECHO" 0)
(setq LST '(15 20 25 32 40 50 70 80 100 125 150 200 250 300))
(princ "\n定义命令")
(foreach I LST
(setq A (itoa I)
B (list
'defun
(read (strcat "C:" A))
(list '/)
(list 'if
(list 'setq 'PT (list 'getpoint "\n插入点:"))
(list 'command "_.text" 'PT 20 0 (strcat "DN" A))
)
(list 'princ)
)
)
(eval B)
(princ (strcat " " A))
) ;_结束 foreach
(princ " 完成！")
(princ)
) ;_结束 defun
;;;============================================================
;|;;后话：看eval的功能说明是：返回一个AutoLISP表达式的求值结果。
但每个表达式均返回结果，从这方面去想，这个函数似乎无多大用处；
而事实上，通过灵活的组织其参数就可以达到意想不到的完美效果。
上面的代码就是一个经典的应用。
;;|;
</PRE>

<HR SIZE=5><PRE>;;;      eval函数示例------定义以表中元素为名称的命令 
;;;日期：zml84 于 2007-05-24 
;;;============================================================ 
;;;功能：定义系列命令，用于标注管径 
(defun C:TT (/ LST I A B) 
    (setvar "CMDECHO" 0) 
    (setq LST '(15 20 25 32 40 50 70 80 100 125 150 200 250 300)) 
    (princ "\n定义命令") 
    (foreach I LST 
        (setq A        (itoa I) 
              B        (list 
                    'defun 
                    (read (strcat "C:" A)) 
                    (list '/) 
                    (list 'if 
                          (list 'setq 'PT (list 'getpoint "\n插入点:")) 
                          (list 'command "_.text" 'PT 20 0 (strcat "DN" A)) 
                    ) 
                    (list 'princ) 
                ) 
        ) 
        (eval B) 
        (princ (strcat "  " A)) 
    ) ;_结束 foreach 
    (princ "  完成！") 
    (princ) 
) ;_结束 defun 
;;;============================================================ 
;|;;后话：看eval的功能说明是：返回一个AutoLISP表达式的求值结果。 
        但每个表达式均返回结果，从这方面去想，这个函数似乎无多大用处； 
        而事实上，通过灵活的组织其参数就可以达到意想不到的完美效果。 
        上面的代码就是一个经典的应用。 
;;|; 
</PRE>

参见：http://zml84.blog.sohu.com/47331560.html
 
三、虽然，通过EVAL函数可以达到1楼的要求，但还是不建议采用此法。

adisonmaster · 发表于 2007-5-24 12:36:36

最初由 nuance 发布
[B]如果要编15，20，25，32，40，50，70，80，100，125，150，200，250，300等程序，每个都要编一个程序，程序是基本相同的，对维护程序不利，能不能把所有程序整合到一个里，例如
(defun c:15()
(sub-defun)
)
... [/B]

按照楼主的要求，需要实现的功能是可以在循环中定义函数，也就是说如果函数名如果可以使用变量来就能实现了。zml84的程序很好，完美解决了问题！

账号		自动登录	找回密码
密码			立即注册

[求助] [求助]：有什么办法和并程序？

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子

Re: [求助]：有什么办法和并程序？