[求助]：求文字的四个点的点表

158466939

怎么求文字的四个点的点表，支持多行文字最好，而且要是文字在任何角度的，感觉晓东原来的有点不准，谁能写个好点的

zxq0220

哪四个点？是外包围框的四个角点吗？

158466939

对

zxq0220

试试看:
[php]
;文本外框，只对单行文字有效。晓东 zxq0220
(DEFUN C:TXTBLK ()
(SETVAR "CMDECHO" 0)
(SETQ OLDOS (GETVAR "OSMODE"))
(SETQ TXTSZ (GETVAR "TEXTSIZE"))
(SETVAR "OSMODE" 0)
(PRINC "\nSelect Text : ")
(IF (SETQ SS (SSGET '((0 . "TEXT")))) (PROGN
  (COMMAND ".UNDO" "BE")
  (SETQ SL (SSLENGTH SS) I 0)
  (REPEAT SL
   (SETQ ENT (ENTGET (SSNAME SS I)) I (1+ I))
   (SETVAR "TEXTSIZE" (CDR(ASSOC 40 ENT)))
   (SETQ TEMP    (TEXTBOX (LIST (ASSOC 1 ENT)))
         PT_BASE (CDR (ASSOC 10 ENT))
         ANG     (CDR (ASSOC 50 ENT)) ;文字转角
         TEXTW   (CDR (ASSOC 41 ENT)) ;文字高宽比
         TEMP_W  (* (- (CAADR TEMP) (CAAR TEMP)) TEXTW) ;实际字宽
         TEMP_H  (- (CADADR TEMP) (CADAR TEMP))
         PT      (LIST (+ (CAR PT_BASE) (CAAR TEMP)) (+ (CADR PT_BASE) (CADAR TEMP))))
   (COMMAND "PLINE" PT
            (SETQ PT1 (POLAR PT (+ (/ PI 2) ANG) TEMP_H))
            (POLAR PT1 ANG TEMP_W)
            (POLAR PT ANG TEMP_W)
            "C")
  )
  (COMMAND ".UNDO" "E")
))
(SETVAR "TEXTSIZE" TXTSZ)
(SETVAR "OSMODE" OLDOS)
(SETVAR "CMDECHO" 1)
(PRINC)
)
[/php]

liu_lang

对末尾有空格的文字，用TEXTBOX取点不准

158466939

刚测试了下，也不准，不过改下应该可以，支持多行就好了，在此还是谢谢zxq0220的帮忙  ~！楼上的，我要的就是比较通用准确的，你不要只说不准，能否也给个准确的？

zml84

http://zml84.blog.sohu.com/79282269.html

;;;=======================================================
;;;    通用函数
;;;功能：获取TEXT对象包围盒四个角点
;;;参数：ENT ----text组码表
;;;参数：SC  ----缩放比例
(defun TEXTBOX2    (ENT SC    / PT0 ANG LST PTA PTB PTC PTD LST_NEW PT_ANG PT_DIST)
    ;;插入点 角度
    (setq PT0 (cdr (assoc 10 ENT))
      ANG (cdr (assoc 50 ENT))
    )
    ;;计算局部坐标系四点
    (setq LST (textbox ENT))
    (setq PTA (car LST)
      PTB (cadr LST)
    )
    (setq PTC (list (car PTA) (cadr PTB))
      PTD (list (car PTB) (cadr PTA))
    )
    (setq LST      (list PTA PTC PTB PTD)
      LST_NEW ()
    )
    ;;旋转坐标系
    (foreach PT    LST
    (setq PT_DIST (distance '(0 0 0) PT)
          PT_ANG  (angle '(0 0 0) PT)
          PT      (polar '(0 0 0) (+ PT_ANG ANG) (* SC PT_DIST))
          LST_NEW (cons PT LST_NEW)
    )
    )
    ;;平移
    (setq LST '())
    (foreach PT    LST_NEW
    (setq PT  (mapcar '+ PT0 PT)
          LST (cons PT LST)
    )
    )
    ;;返回
    LST
)