大家讨论下图纸空间视口到模型空间的转换问题

Lispboy · 发表于 2013-6-1 15:25:59

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

上图是图纸空间截图

下图是模型空间截图

问题是怎么能从图纸空间的视口边界得到模型空间对应大小的红色的矩形？

Gdlprfcu · 发表于 2013-6-1 15:38:04

找找视口对象的属性，应该能得到。

Lispboy · 发表于 2013-6-1 15:42:11

Gdlprfcu 发表于 2013-6-1 15:38
找找视口对象的属性，应该能得到。

谢谢参与我的帖子，有资料吗，试试写下代码看怎么得到。

仲文玉 · 发表于 2013-6-1 15:51:17

高版本本身就有这个功能，不过导出布局的尺寸不对的！
视口对象的属性没研究过，源泉有视口工具，不喜欢在布局中作图，木有研究

Love-Lisp · 发表于 2013-6-1 16:24:20

本帖最后由 Love-Lisp 于 2013-6-1 18:28 编辑

(defun c:tt (/ ll ur coords pl)
(vl-load-com)
(if (= 0 (getvar 'TILEMODE))
(progn
(setq ps (vla-get-PaperSpace
(vla-get-ActiveDocument (vlax-get-acad-object))
)
i 0
)
(vlax-for pv ps
(vla-GetBoundingBox pv 'll 'ur)
(setq ll (trans (vlax-safearray->list ll) 3 2)
ur
(trans (vlax-safearray->list ur) 3 2)
coords
(vlax-safearray-fill
(vlax-make-safearray vlax-vbDouble (cons 0 7))
(list (car ll)
(cadr ll)
(car ur)
(cadr ll)
(car ur)
(cadr ur)
(car ll)
(cadr ur)
)
)
)
(vla-put-closed
(setq pl (vla-AddLightWeightPolyline
(vla-get-ModelSpace (vla-get-Document pv))
coords
)
)
:vlax-true
)
(vla-put-color pl (setq i (1+ i)))
(vlax-vla-object->ename pl)
)
)
)
)

(defun c:tt (/ ll ur coords pl) 
  (vl-load-com) 
  (if (= 0 (getvar 'TILEMODE)) 
    (progn 
      (setq ps (vla-get-PaperSpace 
                 (vla-get-ActiveDocument (vlax-get-acad-object)) 
               ) 
            i  0 
      ) 
      (vlax-for        pv ps 
        (vla-GetBoundingBox pv 'll 'ur) 
        (setq ll     (trans (vlax-safearray->list ll) 3 2) 
              ur 
                     (trans (vlax-safearray->list ur) 3 2) 
              coords 
                     (vlax-safearray-fill 
                       (vlax-make-safearray vlax-vbDouble (cons 0 7)) 
                       (list (car ll) 
                             (cadr ll) 
                             (car ur) 
                             (cadr ll) 
                             (car ur) 
                             (cadr ur) 
                             (car ll) 
                             (cadr ur) 
                       ) 
                     ) 
        ) 
        (vla-put-closed 
          (setq        pl (vla-AddLightWeightPolyline 
                     (vla-get-ModelSpace (vla-get-Document  pv)) 
                     coords 
                   ) 
          ) 
          :vlax-true 
        ) 
        (vla-put-color pl (setq i (1+ i))) 
        (vlax-vla-object->ename pl) 
      ) 
    ) 
  ) 
)

Lispboy · 发表于 2013-6-1 17:26:53

Love-Lisp 发表于 2013-6-1 16:24

在图纸空间运行，提示错误

命令: tt
错误: 参数类型错误: VLA-OBJECT nil

帮看看。

QiaoCheng · 发表于 2013-6-1 18:00:28

本帖最后由 QiaoCheng 于 2013-6-1 18:11 编辑

我测试了下，倒是可以运行{:soso_e113:}
以前看到不死猫有个多线程的对比两张图纸，楼主弄弄？

(setq pl (vla-AddLightWeightPolyline (vla-get-ModelSpace (vla-get-Document vp)) coords))
==>
(setq pl (vla-AddLightWeightPolyline (vla-get-ModelSpace (vla-get-Document pv)) coords))

Lispboy · 发表于 2013-6-1 18:10:01

QiaoCheng 发表于 2013-6-1 18:00
我测试了下，倒是可以运行，但看代码像是画了条线，没见到也没细看
以前看到不死猫有个多线 ...

谢谢，我在试试。

对了，你说的什么多线程对比，你去开个帖子，详细介绍下啊。论坛这么多高手呢。

Gdlprfcu · 发表于 2013-6-1 21:07:03

Lispboy 发表于 2013-6-1 18:10
谢谢，我在试试。

对了，你说的什么多线程对比，你去开个帖子，详细介绍下啊。论坛这么多高手呢。

lisp多线程！就别折腾了，花无谓的时间不如ARX得了，不死猫那个什么多线程只不过是一BUG，根本就算不上多线程，不一会CAD就会崩溃，lisp是不能并发的，很多时候你应该也试过出现“不能重复进入LISP”这样的提示吧。

auva · 发表于 2013-6-1 21:08:17

;;; vp-outline.lsp (VPO)
;;;
;;; Creates a polyline in modelspace that
;;; has the outline of the selected viewport.
;;; Supports clipped viewports.
;;; If vp-outline is called when in mspace it detects
;;; the active viewport.
;;;
;;; c:vp-outline (C:VPO)
;;;
;;; By Jimmy Bergmark
;;; Website: www.jtbworld.com (http://www.jtbworld.com)
;;; E-mail: info@jtbworld.com
;;;
;;; 2000-04-10
;;; 2003-11-19 Added support for drawing the outline in other ucs/view than world/current
;;;
;;; 2006-04-06 Added support for twisted views Tom Beauford
;;;
;;; Tested on AutoCAD 2000, 2000i, 2002, 2004, 2006, 2007
(vl-load-com)
(defun dxf (n ed) (cdr (assoc n ed)))
(defun ax:List->VariantArray (lst)
(vlax-Make-Variant
(vlax-SafeArray-Fill
(vlax-Make-SafeArray
vlax-vbDouble
(cons 0 (- (length lst) 1))
)
lst
)
)
)
(defun c:VPO
(/ ad ss ent pl plist xy n vpbl vpur msbl msur ven vpno ok)
(setq ad (vla-get-activedocument (vlax-get-acad-object)))
(if (= (getvar "tilemode") 0)
(progn
(if (= (getvar "cvport") 1)
(progn
(if (setq ss (ssget ":E:S" '((0 . "VIEWPORT"))))
(progn
(setq ent (ssname ss 0))
(setq vpno (dxf 69 (entget ent)))
(vla-Display (vlax-ename->vla-object ent) :vlax-true)
(vla-put-mspace ad :vlax-true)
; equal (command "._mspace")
; this to ensure trans later is working on correct viewport
(setvar "cvport" vpno)
; (vla-put-mspace ad :vlax-false) ; equal (command "._pspace")
(setq ok T)
)
)
)
(setq ent (vlax-vla-object->ename (vla-get-activepviewport ad))
ok T
)
)
(if ok
(progn
(setq ven (vlax-ename->vla-object ent))
(if (/= 1 (logand 1 (dxf 90 (entget ent))))
; detect perspective
(if (= (vla-get-clipped ven) :vlax-false)
(progn ; not clipped
(vla-getboundingbox ven 'vpbl 'vpur)
(setq vpbl (trans (vlax-safearray->list vpbl) 3 2)
msbl (trans vpbl 2 1)
msbl (trans msbl 1 0)
vpur (trans (vlax-safearray->list vpur) 3 2)
msur (trans vpur 2 1)
msur (trans msur 1 0)
vpbr (list (car vpur) (cadr vpbl) 0)
msbr (trans vpbr 2 1)
msbr (trans msbr 1 0)
vpul (list (car vpbl) (cadr vpur) 0)
msul (trans vpul 2 1)
msul (trans msul 1 0)
plist (list (car msbl)
(cadr msbl)
(car msbr)
(cadr msbr)
(car msur)
(cadr msur)
(car msul)
(cadr msul)
)
)
)
(progn ; clipped
(setq pl (entget (dxf 340 (entget ent)))
plist (vla-get-coordinates
(vlax-ename->vla-object (dxf -1 pl))
)
plist (vlax-safearray->list
(vlax-variant-value plist)
)
n 0
pl nil
)
(repeat (/ (length plist) 2)
(setq xy (trans (list (nth n plist) (nth (1+ n) plist))
3
2
)
xy (trans xy 2 1)
xy (trans xy 1 0)
pl (cons (car xy) pl)
pl (cons (cadr xy) pl)
n (+ n 2)
)
)
(setq plist (reverse pl))
)
)
)
(setq plist (ax:List->VariantArray plist))
(vla-Put-Closed
(vla-AddLightWeightPolyline
(vla-get-ModelSpace ad)
plist
)
:vlax-True
)
)
)
)
)
(if ss
(vla-put-mspace ad :vlax-false)
) ; equal (command "._pspace"))
(princ)
)

;;; vp-outline.lsp (VPO) 
;;; 
;;; Creates a polyline in modelspace that 
;;; has the outline of the selected viewport. 
;;; Supports clipped viewports. 
;;; If vp-outline is called when in mspace it detects 
;;; the active viewport. 
;;; 
;;; c:vp-outline (C:VPO) 
;;; 
;;; By Jimmy Bergmark 
;;; Copyright (C) 1997-2006 JTB World, All Rights Reserved 
;;; Website: www.jtbworld.com (http://www.jtbworld.com) 
;;; E-mail: info@jtbworld.com 
;;; 
;;; 2000-04-10 
;;; 2003-11-19 Added support for drawing the outline in other ucs/view than world/current 
;;; 
;;; 2006-04-06 Added support for twisted views Tom Beauford 
;;; 
;;; Tested on AutoCAD 2000, 2000i, 2002, 2004, 2006, 2007 
(vl-load-com) 
(defun dxf (n ed) (cdr (assoc n ed))) 
(defun ax:List->VariantArray (lst) 
  (vlax-Make-Variant 
    (vlax-SafeArray-Fill 
      (vlax-Make-SafeArray 
        vlax-vbDouble 
        (cons 0 (- (length lst) 1)) 
      ) 
      lst 
    ) 
  ) 
) 
(defun c:VPO 
       (/ ad ss ent pl plist xy n vpbl vpur msbl msur ven vpno ok) 
  (setq ad (vla-get-activedocument (vlax-get-acad-object))) 
  (if (= (getvar "tilemode") 0) 
    (progn 
      (if (= (getvar "cvport") 1) 
        (progn 
          (if (setq ss (ssget ":E:S" '((0 . "VIEWPORT")))) 
            (progn 
              (setq ent (ssname ss 0)) 
              (setq vpno (dxf 69 (entget ent))) 
              (vla-Display (vlax-ename->vla-object ent) :vlax-true) 
              (vla-put-mspace ad :vlax-true) 
                                        ; equal (command "._mspace") 
                                        ; this to ensure trans later is working on correct viewport 
              (setvar "cvport" vpno) 
                                        ; (vla-put-mspace ad :vlax-false) ; equal (command "._pspace") 
              (setq ok T) 
            ) 
          ) 
        ) 
        (setq ent (vlax-vla-object->ename (vla-get-activepviewport ad)) 
              ok  T 
        ) 
      ) 
      (if ok 
        (progn 
          (setq ven (vlax-ename->vla-object ent)) 
          (if (/= 1 (logand 1 (dxf 90 (entget ent)))) 
                                        ; detect perspective 
            (if        (= (vla-get-clipped ven) :vlax-false) 
              (progn                        ; not clipped 
                (vla-getboundingbox ven 'vpbl 'vpur) 
                (setq vpbl  (trans (vlax-safearray->list vpbl) 3 2) 
                      msbl  (trans vpbl 2 1) 
                      msbl  (trans msbl 1 0) 
                      vpur  (trans (vlax-safearray->list vpur) 3 2) 
                      msur  (trans vpur 2 1) 
                      msur  (trans msur 1 0) 
                      vpbr  (list (car vpur) (cadr vpbl) 0) 
                      msbr  (trans vpbr 2 1) 
                      msbr  (trans msbr 1 0) 
                      vpul  (list (car vpbl) (cadr vpur) 0) 
                      msul  (trans vpul 2 1) 
                      msul  (trans msul 1 0) 
                      plist (list (car msbl) 
                                  (cadr msbl) 
                                  (car msbr) 
                                  (cadr msbr) 
                                  (car msur) 
                                  (cadr msur) 
                                  (car msul) 
                                  (cadr msul) 
                            ) 
                ) 
              ) 
              (progn                        ; clipped 
                (setq pl    (entget (dxf 340 (entget ent))) 
                      plist (vla-get-coordinates 
                              (vlax-ename->vla-object (dxf -1 pl)) 
                            ) 
                      plist (vlax-safearray->list 
                              (vlax-variant-value plist) 
                            ) 
                      n            0 
                      pl    nil 
                ) 
                (repeat        (/ (length plist) 2) 
                  (setq        xy (trans (list (nth n plist) (nth (1+ n) plist)) 
                                  3 
                                  2 
                           ) 
                        xy (trans xy 2 1) 
                        xy (trans xy 1 0) 
                        pl (cons (car xy) pl) 
                        pl (cons (cadr xy) pl) 
                        n  (+ n 2) 
                  ) 
                ) 
                (setq plist (reverse pl)) 
              ) 
            ) 
          ) 
          (setq plist (ax:List->VariantArray plist)) 
          (vla-Put-Closed 
            (vla-AddLightWeightPolyline 
              (vla-get-ModelSpace ad) 
              plist 
            ) 
            :vlax-True 
          ) 
        ) 
      ) 
    ) 
  ) 
  (if ss 
    (vla-put-mspace ad :vlax-false) 
  )                                        ; equal (command "._pspace")) 
  (princ) 
)

zteykmgscqh · 发表于 2021-6-30 15:00:52

刚才有些需求，路过学习一下！

zteykmgscqh · 发表于 2021-7-9 14:20:08

Love-Lisp方法可批量生成视口矩形框，但坐标不对。auva方法生成多段线框完成对应多边形视口，完美！

jevil · 发表于 2022-12-15 18:56:11

这个太好了，实在是太实用，找了很久，找到了组织了，感谢auva方法，真的nice啊，多谢分享，赞一个

jevil · 发表于 2022-12-15 19:02:02

现在就是能否把整个布局空间的内容导出到模型空间，比如外部参考的图框，还有布局中的图例和说明等内容，就是把一个图框中的所有布局信息内容导入到模型中间，类似于CAD的布局输出模型，但是要能批量实现，用cad的这个功能有时会报错了，有没有插件直接导出的，一键生成

账号		自动登录	找回密码
密码			立即注册

[研讨] 大家讨论下图纸空间视口到模型空间的转换问题

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

评分

相关帖子

点评

点评

评分

点评

点评

评分

点评

评分