已知：弧线求面AO-AC的nor

cable2004 · 发表于 2017-4-24 12:22:08

谢谢！我试试。
cad版本低
没有错误: no function definition: ALIGN

csharp · 发表于 2017-4-24 12:49:24

cable2004 发表于 2017-4-24 12:22

运行一次 align 命令

newer · 发表于 2017-4-24 22:58:47

cable2004 发表于 2017-4-24 12:22

ARC的法线向量是V1
那么垂平面的法线向量V = V1 和向量AO（单位）的叉积

AO的向量你可以用 (mapcar '- po pa)得到

单位向量和叉积的函数论坛有，搜索下。

newer · 发表于 2017-4-24 23:27:01

本帖最后由 newer 于 2017-4-24 23:40 编辑

csharp 发表于 2017-4-24 12:49

通用的向量计算函数

;;;-----------------------------------------------------------;;
;;; 两向量的叉积 ;;
;;; Vector Cross Product ;;
;;; Args: u,v - vectors in R^3 ;;
;;;-----------------------------------------------------------;;
(defun XD::Vec:vxv (u v)
(list
(- (* (cadr u) (caddr v)) (* (cadr v) (caddr u)))
(- (* (car v) (caddr u)) (* (car u) (caddr v)))
(- (* (car u) (cadr v)) (* (car v) (cadr u)))
)
)
;;;-----------------------------------------------------------;;
;;; 单位向量 ;;
;;; Unit Vector - Lee Mac ;;
;;; Args: v - vector in R^n ;;
;;;-----------------------------------------------------------;;
(defun XD::VEC:Normalize (v)
((lambda (n)
(if (equal 0.0 n 1e-14)
nil
(XD::VEC:v*s v (/ 1.0 n))
)
)
(XD::VEC:length v)
)
)
;;;-----------------------------------------------------------;;
;;; 向量的模(长度) ;;
;;; Vector Norm - Lee Mac ;;
;;; Args: v - vector in R^n ;;
;;;-----------------------------------------------------------;;
(defun XD::Vec:length (v)
(sqrt (apply '+ (mapcar '* v v)))
)
;;;-----------------------------------------------------------;;
;;; 向量乘标量(系数) ;;
;;; Vector x Scalar - Lee Mac ;;
;;; Args: v - vector in R^n, s - real scalar ;;
;;;-----------------------------------------------------------;;
(defun XD::Vec:v*s (v s)
(mapcar (function (lambda (n) (* n s))) v)
)

;;;-----------------------------------------------------------;; 
;;; 两向量的叉积                                              ;; 
;;; Vector Cross Product                                       ;; 
;;; Args: u,v - vectors in R^3                                      ;; 
;;;-----------------------------------------------------------;; 
(defun XD::Vec:vxv (u v) 
  (list 
    (- (* (cadr u) (caddr v)) (* (cadr v) (caddr u))) 
    (- (* (car v) (caddr u)) (* (car u) (caddr v))) 
    (- (* (car u) (cadr v)) (* (car v) (cadr u))) 
  ) 
) 
;;;-----------------------------------------------------------;; 
;;; 单位向量                                                      ;; 
;;; Unit Vector - Lee Mac                                     ;; 
;;; Args: v - vector in R^n                                      ;; 
;;;-----------------------------------------------------------;; 
(defun XD::VEC:Normalize (v) 
  ((lambda (n) 
     (if (equal 0.0 n 1e-14) 
       nil 
       (XD::VEC:v*s v (/ 1.0 n)) 
     ) 
   ) 
    (XD::VEC:length v) 
  ) 
) 
;;;-----------------------------------------------------------;; 
;;; 向量的模(长度)                                              ;; 
;;; Vector Norm - Lee Mac                                             ;; 
;;; Args: v - vector in R^n                                      ;; 
;;;-----------------------------------------------------------;; 
(defun XD::Vec:length (v) 
  (sqrt (apply '+ (mapcar '* v v))) 
) 
;;;-----------------------------------------------------------;; 
;;; 向量乘标量(系数)                                              ;; 
;;; Vector x Scalar - Lee Mac                                      ;; 
;;; Args: v - vector in R^n, s - real scalar                      ;; 
;;;-----------------------------------------------------------;; 
(defun XD::Vec:v*s (v s) 
  (mapcar (function (lambda (n) (* n s))) v) 
)

下面是测试命令，红色线画出弧线垂平面的Y轴，黄色线画出弧线垂平面的法线。

(defun c:tt ()
(if (setq e (ssget ":E:N" '((0 . "arc"))))
(progn
(setq e (ssname e 0)
ed (entget e)
v210 (cdr (assoc 210 ed))
p1 (vlax-curve-getstartpoint e)
p2 (vlax-curve-getendpoint e)
v1 (mapcar '- p1 p2)
v1 (xd::vec:normalize v1)
v2 (xd::vec:vxv v210 v1)
p3 (mapcar '+ p2 (xd::vec:v*s v210 100.0))
)
(princ "\n弧线垂平面Y轴用红色线画出")
(command "line" p2 p3 "")
(vla-put-color (vlax-ename->vla-object (entlast)) 1)
(princ "\n弧线垂平面的法线向量是：")
(princ v2)
(command "line" p3 (mapcar '+ p3 (xd::vec:v*s v2 100)) "")
(vla-put-color (vlax-ename->vla-object (entlast)) 2)
(princ "\n用黄色线画出")
)
)
(princ)
)

XDRX API 写就是这样：

(defun c:tt ()
(if (setq e (car (xdrx_entsel "\n拾取弧线<退出>:" '((0 . "arc")))))
(progn
(xdrx_getpropertyvalue e "normal" "startpoint" "endpoint")
(setq
v1 (mapcar '- #startpoint #endpoint)
v1 (xdrx_vector_normalize v1)
v2 (xdrx_vector_crossproduct #normal v1)
p3 (mapcar '+ p2 (xdrx_vector_product #normal 100.0))
)
(xdrx_line_make #endpoint p3)
(xdrx_setpropertyvalue (entlast) "color" 1)
(xdrx_prompt "\n弧线垂平面Y轴用红色线画出.\n弧线垂平面的法线向量是：" v2)
(xdrx_line_make
p3
(mapcar '+ p3 (xdrx_vector_product v2 100))
)
(xdrx_setpropertyvalue (entlast) "color" 2)
(xdrx_prompt "\n用黄色线画出")
)
)
(princ)
)

csharp · 发表于 2017-4-25 07:41:42

本帖最后由 csharp 于 2017-4-25 07:46 编辑

使用 align 和 c:cal 函数，先运行以下语句

(mapcar (function (lambda (x / fn)
(if (setq fn (findfile x))
(arxload fn)
)
)
)
'("geom3d.crx" "geom3d.arx" "geomcal.crx" "geomcal.arx")
)

求 Normal 可以使用 c:cal 函数
nor 函数用于计算单位法向矢量（即与直线或平面垂直的矢量），而不是某个点。矢量定义法线的方向而不是空间中的位置。可将法向矢量加到一个点上以获得另一个点。

nor
确定选定的圆、圆弧或多段线弧段的三维单位法向矢量。此法向矢量是选定对象的对象坐标系 (OCS) 的 Z 轴。

nor(v)
确定矢量 v 的二维单位法向矢量。这两个矢量都被认为是二维的，且投影在当前 UCS 的 XY 平面上。得出的法向矢量的方向指向原矢量 v 的左边。

nor(p1,p2)
确定直线 p1,p2 的二维单位法向矢量。该直线的方向为从 p1 指向 p2。得出的法向矢量的方向为指向原直线 (p1、p2) 的左边。

nor(p1,p2,p3)
确定平面（由 p1、p2 和 p3 三点定义）的三维单位法向矢量。法向矢量的方向与给定三点的逆时针方向垂直。

下图示意了如何计算法向矢量：

下例设置的视图方向垂直于选定对象。程序在平面视图中显示对象，而不会因平行投影而使对象扭曲。

命令: vpoint

当前视图方向: VIEWDIR=当前

指定视点或 [旋转(R)] <显示坐标球和三轴架>: 'cal

>> 表达式: nor

>> 给函数 NOR 选择圆、圆弧或多段线:

AutoLisp 中使用方法：

命令: (setq p1 (getpoint))
(1977.26 1043.75 0.0)

命令: (setq p2 (getpoint))
(2525.64 1043.75 0.0)

命令: (setq p3 (getpoint))
(1977.26 1496.45 410.61)

命令: (c:cal "nor(p1,p2,p3)")
(0.0 -0.671832 0.740704)

阿阿锟 · 发表于 2019-10-19 13:36:05

请教一下楼主，要学习lisp语言要从何入手？买什么书或是有什么教学视频？

账号		自动登录	找回密码
密码			立即注册

[求助] 已知：弧线求面AO-AC的nor

浏览过的版块