随机数生成函数

Lisphk · 发表于 2018-2-5 00:07:20

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

[JavaScript] 纯文本查看 复制代码

(defun rand ()
  (setq	seed (if seed
	       (rem (+ (* seed 15625.7) 0.21137152) 1)
	       0.3171943
	     )
  )
)

令: (repeat 10 (princ "\n")(princ(rand)))

0.0126488
0.858366
0.778777
0.152224
0.814014
0.756342
0.587726
0.849062
0.392444
0.421463

sicky111 · 发表于 2018-2-5 08:25:29

沙发。支持楼主！

ll_j · 发表于 2018-2-5 08:33:05

这段代码表达的是有序数列，不是随机数

Lisphk · 发表于 2018-2-5 08:42:25

ll_j 发表于 2018-2-5 08:33

大师，如何不是随机了，愿闻其详。

ll_j · 发表于 2018-2-5 10:17:04

Lisphk 发表于 2018-2-5 08:42

当seed为空时，取seed为0.3171943，这是全序列第一个数，为定值；
此时seed存在，那么序列的第二个数为(rem (+ (* 0.3171943 15625.7） 0.21137152）1)，也为定值（除非违反rem的规则出错）；
此时seed存在，那么序列的第三个数和第二个数一样算法，也应该为定值；
以后同样。
这里要说一下，rem函数在某些特定条件下是会出错的（比如某数超出数据位数），但出错后也一定是按照某种规则返回，同样是定数，只是我们不知道其中规则。

对于随机数，严格地说，Lisp是没有此类函数的，目前所使用的方法一般是两种，一是调用VBA的随机函数，二是使用时间模拟，准确地说，使用时间模拟也是有序数列，但如果位数取的足够多，考虑系统运行流畅度对程序的影响，这种模拟也是可以被认可的。

Lisphk · 发表于 2018-2-5 12:12:41

本帖最后由 Lisphk 于 2018-2-5 12:29 编辑

下面是用这个函数生成的矩形的500个随机点，看着还行

搜狗截图20180205121052.png

(defun rand ()
(setq seed (if seed
(rem (+ (* seed 15625.7) 0.21137152) 1)
0.3171943
)
)
)
(defun c:tt ()
(if (and (setq e (car (entsel "\n拾取矩形<退出>:")))
(setq num (getint "\n随机点数<退出>:"))
)
(progn (vla-getboundingbox (vlax-ename->vla-object e) 'ld 'ru)
(setq ld (vlax-safearray->list ld)
ru (vlax-safearray->list ru)
xmin (car ld)
xmax (car ru)
ymin (cadr ld)
ymax (cadr ru)
)
(repeat num
(setq rnd (rand)
x (+ xmin (* rnd (- xmax xmin)))
rnd (rand)
y (+ ymin (* rnd (- ymax ymin)))
pt (list x y 0.0)
)
(command ".point" pt)
)
)
)
(princ)
)

(defun rand () 
  (setq seed (if seed 
               (rem (+ (* seed 15625.7) 0.21137152) 1) 
               0.3171943 
             ) 
  ) 
) 
(defun c:tt () 
  (if (and (setq e (car (entsel "\n拾取矩形<退出>:"))) 
           (setq num (getint "\n随机点数<退出>:")) 
      ) 
    (progn (vla-getboundingbox (vlax-ename->vla-object e) 'ld 'ru) 
           (setq ld   (vlax-safearray->list ld) 
                 ru   (vlax-safearray->list ru) 
                 xmin (car ld) 
                 xmax (car ru) 
                 ymin (cadr ld) 
                 ymax (cadr ru) 
           ) 
           (repeat num 
             (setq rnd (rand) 
                   x   (+ xmin (* rnd (- xmax xmin))) 
                   rnd (rand) 
                   y   (+ ymin (* rnd (- ymax ymin))) 
                   pt  (list x y 0.0) 
             ) 
             (command ".point" pt) 
           ) 
    ) 
  ) 
  (princ) 
)

Lisphk · 发表于 2018-2-5 12:25:22

ll_j 发表于 2018-2-5 10:17

都是“伪随机了”，主要是看种子的选取，尽可能的看起来随机，判断随机数是否好，好像有个正态函数方程。我理解的“有序序列”，就是每次执行得到的结果都是一样的，这样的肯定不是随机数了。但是这个函数执行起来，每次得到的结果很少一样的，特别是在循环里面，每次的间隔时间很短，相邻的数差别很大。

命令: (repeat 10 (princ "\n")(princ (rand))(princ))

0.176973
0.533045
0.40609
0.659055
0.401617
0.75492
0.363896
0.33797
0.230324
0.184701

命令: (repeat 10 (princ "\n")(princ (rand))(princ))

0.291961
0.310965
0.258529
0.911728
0.592928
0.134142
0.27574
0.842065
0.0665068
0.426792

命令: (repeat 10 (princ "\n")(princ (rand))(princ))

0.129601
0.319936
0.432847
0.75403
0.452668
0.470354
0.829671
0.397789
0.948167
0.987636

命令: (repeat 10 (princ "\n")(princ (rand))(princ))

0.722999
0.573534
0.0762111
0.0638111
0.303919
0.165273
0.718875
0.132657
0.0768326
0.775214

下面图片是执行了6次上面的程序，生成的随机点，看着分布挺好的，各个角落都有了，没重复的。

搜狗截图20180205122425.png

ll_j · 发表于 2018-2-5 12:35:58

Lisphk 发表于 2018-2-5 12:25

你把seed设置成局部变量看看。

Lisphk · 发表于 2018-2-5 13:59:03

本帖最后由 Lisphk 于 2018-2-5 14:01 编辑

ll_j 发表于 2018-2-5 12:35

就是不能设置成局部变量啊，要的是每次不同的“种子啊”。每次的种子一样，那当然生成的是一样了，不一样机器就不听话了:)

下面用LISP写了个任何曲线内部的随机点生成，多段线可以是“凹”的。看结果，挺“随机的”，每个“凹”的部分都给生成到了。

随机点-lisp.gif

(defun c:tt ()
(defun XD::List:GroupByNum (lst num / ls ret)
(if (= (rem (length lst) num) 0)
(progn (setq ls nil)
(repeat (/ (length lst) num)
(repeat num
(setq ls (cons (car lst) ls)
lst (cdr lst)
)
)
(setq ret (append ret (list (reverse ls)))
ls nil
)
)
)
)
ret
)
(if (and (setq e (car (entsel "\n拾取多边形<退出>:")))
(setq num (getint "\n随机点数<退出>:"))
)
(progn (vla-StartUndoMark
(setq doc (vla-get-activedocument (vlax-get-acad-object)))
)
(vla-getboundingbox
(setq o (vlax-ename->vla-object e))
'ld
'ru
)
(setq ld (vlax-safearray->list ld)
ru (vlax-safearray->list ru)
xmin (car ld)
xmax (car ru)
ymin (cadr ld)
ymax (cadr ru)
)
(repeat num
(setq rnd (rand)
y (+ ymin (* rnd (- ymax ymin)))
pt1 (list 0.0 y 0.0)
pt2 (polar pt1 0.0 1.0)
)
(entmake (list '(0 . "XLINE")
'(100 . "AcDbEntity")
'(67 . 0)
'(410 . "Model")
'(8 . "0")
'(100 . "AcDbXline")
(cons 10 pt1)
(list 11 1.0 0.0 0.0)
)
)
(setq e1 (entlast)
o1 (vlax-ename->vla-object e1)
ints (vla-IntersectWith o1 o acExtendThisEntity)
ints (vlax-safearray->list (vlax-variant-value ints))
ints (XD::List:GroupByNum ints 3)
ints (vl-sort ints '(lambda (x y) (< (car x) (car y))))
rnd (rand)
inx1 (fix (+ 0.5 (+ 0 (* rnd (- (length ints) 1)))))
inx (if (= (rem inx1 2) 1)
(1- inx1)
inx1
)
pt1 (nth inx ints)
pt2 (nth (1+ inx) ints)
xmin (car pt2)
xmax (car pt1)
rnd (rand)
)
(setq x (+ xmin (* rnd (- xmax xmin)))
pt (list x y 0.0)
)
(entdel e1)
(command "point" pt)
)
(vla-endundomark doc)
)
)
(princ)
)

(defun c:tt () 
  (defun XD::List:GroupByNum (lst num / ls ret) 
    (if (= (rem (length lst) num) 0) 
      (progn (setq ls nil) 
             (repeat (/ (length lst) num) 
               (repeat num 
                 (setq ls  (cons (car lst) ls) 
                       lst (cdr lst) 
                 ) 
               ) 
               (setq ret (append ret (list (reverse ls))) 
                     ls  nil 
               ) 
             ) 
      ) 
    ) 
    ret 
  ) 
  (if (and (setq e (car (entsel "\n拾取多边形<退出>:"))) 
           (setq num (getint "\n随机点数<退出>:")) 
      ) 
    (progn (vla-StartUndoMark 
             (setq doc (vla-get-activedocument (vlax-get-acad-object))) 
           ) 
           (vla-getboundingbox 
             (setq o (vlax-ename->vla-object e)) 
             'ld 
             'ru 
           ) 
           (setq ld   (vlax-safearray->list ld) 
                 ru   (vlax-safearray->list ru) 
                 xmin (car ld) 
                 xmax (car ru) 
                 ymin (cadr ld) 
                 ymax (cadr ru) 
           ) 
           (repeat num 
             (setq rnd (rand) 
                   y   (+ ymin (* rnd (- ymax ymin))) 
                   pt1 (list 0.0 y 0.0) 
                   pt2 (polar pt1 0.0 1.0) 
             ) 
             (entmake (list '(0 . "XLINE") 
                            '(100 . "AcDbEntity") 
                            '(67 . 0) 
                            '(410 . "Model") 
                            '(8 . "0") 
                            '(100 . "AcDbXline") 
                            (cons 10 pt1) 
                            (list 11 1.0 0.0 0.0) 
                      ) 
             ) 
             (setq e1   (entlast) 
                   o1   (vlax-ename->vla-object e1) 
                   ints (vla-IntersectWith o1 o acExtendThisEntity) 
                   ints (vlax-safearray->list (vlax-variant-value ints)) 
                   ints (XD::List:GroupByNum ints 3) 
                   ints (vl-sort ints '(lambda (x y) (< (car x) (car y)))) 
                   rnd  (rand) 
                   inx1 (fix (+ 0.5 (+ 0 (* rnd (- (length ints) 1))))) 
                   inx  (if (= (rem inx1 2) 1) 
                          (1- inx1) 
                          inx1 
                        ) 
                   pt1  (nth inx ints) 
                   pt2  (nth (1+ inx) ints) 
                   xmin (car pt2) 
                   xmax (car pt1) 
                   rnd  (rand) 
             ) 
             (setq x  (+ xmin (* rnd (- xmax xmin))) 
                   pt (list x y 0.0) 
             ) 
             (entdel e1) 
             (command "point" pt) 
           ) 
           (vla-endundomark doc) 
    ) 
  ) 
  (princ) 
)

线路板 · 发表于 2019-1-13 09:28:37

支持楼主！

zteykmgscqh · 发表于 2021-7-12 04:09:33

过来学习一下，支持大师源码

账号		自动登录	找回密码
密码			立即注册

[每日一码] 随机数生成函数

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。