[求助]：请教大家一个关于标注引线的问题！

小李子

我们正常标注引线的时候，所标注的引线都是直线引线，请问各位，如何标注曲线引线？

coln2001

自己做一个块吧

lsjjm

最初由 小李子 发布
[B]我们正常标注引线的时候，所标注的引线都是直线引线，请问各位，如何标注曲线引线？ [/B]

请参考：
(defun c:test ()
   (setq ocmdec (getvar "cmdecho")  loop 'T)
   (setvar "cmdecho" 0)
   (while loop
      (if current_pnt
         (progn
            (initget "Undo")
            (setq loop (getpoint current_pnt "\nUndo/<pick point>: "))
         ); PROGN
         (progn
            (setq flag nil); INSURE REVERSE FLAG IS OFF
            (initget "Reverse")
            (setq loop (getpoint "\nReverse/<Pick arrowhead point>: "))
            (if (= loop "Reverse")
               (setq flag 'T  loop (getpoint "\nPick point nearest text: "))
            ); IF
            (command ".pline")
         ); PROGN
      ); IF
      (cond
         ( (= (type loop) 'LIST)
            (setq point_list (append point_list (list loop)))
            (setq current_pnt loop)
            (command loop)
         )
         ( (= loop "Undo")
            (setq point_list (reverse (cdr (reverse point_list)))
                  current_pnt (last point_list)
            )
            (if current_pnt
               (command "u")
               (command nil)
            ); IF
         )
      ); COND
   ); WHILE LOOP
   (if point_list
      (progn
         (command ""); FINISH PLINE COMMAND
         (command ".pedit" (entlast) "s" ""); SPLINE CURV IT
         (if flag (setq point_list (reverse point_list)))
         ; REVERSE FLAG WAS TRUE
;----- CALCULATE ROTATION OF ARROWHEAD
         (setq ang (angle (car point_list) (cadr point_list)) )
              ; THIS IS IN RADIANS
         (if (= (setq arrow_name (getvar "dimblk")) "")
            (progn; THEN DRAW STANDARD ACAD ARROW
;----- CALCULATE SIZE OF ARROWHEAD
               (setq dist1 (* 1.014 (getvar "dimasz") (getvar "dimscale"))
                     dist2 (/ dist1 3) )
               (command ".solid"
                  (car point_list)
                  (strcat "@" (rtos dist1 2 3) "<" (rtos (+ ang 0.1651) 2 3) "r")
                  (strcat "@" (rtos dist2 2 3) "<" (rtos (- ang 1.5708) 2 3) "r")
                  "" ""
               ); COMMAND
            ); PROGN
            (progn; THEN INSERT ARROW_NAME AT DIMASZ X DIMSCALE
                  ; WILL CRASH IF ARROW_NAME IS NOT IN BLOCK TABLE
                  ; OR IN ACAD SEARCH PATH.
               (command ".insert" arrow_name (car point_list)
                  (* (getvar "dimscale") (getvar "dimasz")); X SCALE FACTOR
                  ""; Y SCALE SAME AS X
                  (strcat (rtos (- ang pi) 2 3) "r"); ANG IS IN RADIANS!
               ); COMMAND
            ); PROGN
         ); IF
         (redraw)
      ); PROGN THEN POINT_LIST
      (command nil); NO POINT_LIST- FINISH PLINE COMMAND
   ); IF
   (setvar "cmdecho" ocmdec)
   (princ)
)

luck star

三楼发的是什么东西啊。。怎么看都看不懂。。。。。

27182818284

三楼lsjjm是编程高手，你把“请参考”后面的内容拷贝下来，另存为一个lsp文件，例如：test.lsp。在AutoCAD中用APPLOAD命令加载这个lsp文件，以后就可以用test命令画曲线引线了。

另外，AutoCAD本身也有曲线引线功能，演示如下：

lizc

佩服

小李子

三楼的楼主用的方法太高难度了，偶不会呀，还是5楼楼主的方法方便一点~谢谢大家了~呵呵

cooldream

TO lsjjm
这个程序加载后，出现的箭头和样条曲线是分开的，而27182818284 的不是~