[求助]：关于AUTOLISP程序的问题

阿禄 · 发表于 2004-4-3 12:49:23

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

本人有一个AUTOLISP程序,是用来做结构加固的.
由于不是很熟悉,所以函数什么都看不明白.
有没有人可以帮我画一张计算机框图,这样就一目了然了!
急用!谢谢!
QQ:188175368 [/COLOR]

alwaysbin · 发表于 2004-4-3 21:46:24

程序本身就不完整，我把程序贴上来，大家看看。
其实也不复杂。

[FONT=courier new]
;碳纤维加固修复混凝土结构计算程序
(defun c:cabon_fiber ()
(setq dcl_id (load_dialog "cabon_fiber.dcl"))
(if (< dcl_id 0) (exit))
(new_dialog "cabon_fiber" dcl_id)
(action_tile "s_i_info" "(i_info_check $reason $key $value)")
(action_tile "s_m_con" "(m_con_check $reason $key $value)")
(action_tile "s_m_mtot" "(m_check $reason $key $value 0 10000 "请输入一个不小于0的数" "20")")
(action_tile "s_m_mbeg" "(m_check $reason $key $value 0 10000 "请输入一个不小于0的数" "0")")
(action_tile "s_m_vtot" "(m_check $reason $key $value 0 10000 "请输入一个不小于0的数" "100")")
(action_tile "s_m_ntot" "(m_check $reason $key $value 0 10000 "请输入一个不小于0的数" "100")")
(action_tile "s_m_rssed" "(m_check $reason $key $value 1.0 3.0 "请输入一个介于1.0和3.0之间的数" "1.0")")
(action_tile "s_cf_auta" "(m_check $reason $key $value 0 1 "请输入一个不小于0的数" "0.021")")
(action_tile "s_cf_me" "(m_check $reason $key $value 210 10000 "请输入一个不小于210的数" "230")")
(action_tile "s_cf_t" "(m_check $reason $key $value 0 1 "请输入一个不小于0的数" "0.111")")
(action_tile "s_cf_n" "(m_check $reason $key $value 0 10 "请输入一个大于0的自然数" "1")")
(action_tile "s_cf_nv" "(m_check $reason $key $value 0 10 "请输入一个大于0的自然数" "1")")
(action_tile "s_cf_bv" "(m_check $reason $key $value 0 10000 "请输入一个大于0的自然数" "50")")
(action_tile "s_c_sc" "(m_check $reason $key $value 15 40 "请输入一个介于15和40之间的数" "15")")
(action_tile "s_c_b" "(m_check $reason $key $value 0 1000 "请输入一个不小于0的数" "250")")
(action_tile "s_c_h" "(m_check $reason $key $value 0 1000 "请输入一个不小于0的数" "300")")
(action_tile "s_c_btf" "(m_check $reason $key $value 0 1000 "请输入一个不小于0的数" "0")")
(action_tile "s_c_htf" "(m_check $reason $key $value 0 1000 "请输入一个不小于0的数" "0")")
(action_tile "s_c_bcf" "(m_check $reason $key $value 0 1000 "请输入一个不小于0的数" "0")")
(action_tile "s_c_hcf" "(m_check $reason $key $value 0 1000 "请输入一个不小于0的数" "0")")
(action_tile "s_s_f" "(m_check $reason $key $value 0 1000 "请输入一个不小于0的数" "300")")
(action_tile "s_s_fv" "(m_check $reason $key $value 0 1000 "请输入一个不小于0的数" "210")")
(action_tile "s_s_at" "(m_check $reason $key $value 0.00001 10000 "请输入一个不小于0的数" "226")")
(action_tile "s_s_ac" "(m_check $reason $key $value 0 10000 "请输入一个不小于0的数" "0")")
(action_tile "s_s_av" "(m_check $reason $key $value 0 10000 "请输入一个不小于0的数" "0")")
(action_tile "s_s_s" "(m_check $reason $key $value 50 300 "请输入一个介于50和300之间的数" "200")")
(action_tile "s_s_dstc" "(m_check $reason $key $value 0 100 "请输入一个不小于0的数" "35")")
(action_tile "s_cf_a" "(cfsa $value)")
(action_tile "s_cf_av" "(cfsav $value)")
(action_tile "s_cal" "(cal)")
(action_tile "s_ok" "(done_dialog 1)")
(setq dcl_s (start_dialog))
(unload_dialog dcl_id)
(princ)
)
;读取数值
(defun read_data()
(setq m_mtot (* (atof (get_tile "s_m_mtot")) 1000000)
m_mbeg (* (atof (get_tile "s_m_mbeg")) 1000000)
m_vtot (* (atof (get_tile "s_m_vtot")) 1000)
m_ntot (* (atof (get_tile "s_m_ntot")) 1000)
m_rssed (atof (get_tile "s_m_rssed"))
cf_b (atof (get_tile "s_cf_b"))
cf_bv (atof (get_tile "s_cf_bv"))
cf_s (atof (get_tile "s_cf_s"))
cf_auta (atof (get_tile "s_cf_auta"))
cf_me (* (atof (get_tile "s_cf_me")) 1000)
cf_t (atof (get_tile "s_cf_t"))
cf_n (atoi (get_tile "s_cf_n"))
cf_nv (atoi (get_tile "s_cf_nv"))
c_sc (atof (get_tile "s_c_sc"))
c_b (atof (get_tile "s_c_b"))
c_h (atof (get_tile "s_c_h"))
c_btf (atof (get_tile "s_c_btf"))
c_htf (atof (get_tile "s_c_htf"))
c_bcf (atof (get_tile "s_c_bcf"))
c_hcf (atof (get_tile "s_c_hcf"))
s_f (atof (get_tile "s_s_f"))
s_fv (atof (get_tile "s_s_fv"))
s_at (atof (get_tile "s_s_at"))
s_ac (atof (get_tile "s_s_ac"))
s_av (atof (get_tile "s_s_av"))
s_s (atof (get_tile "s_s_s"))
s_dstc (atof (get_tile "s_s_dstc"))
)
(cond ((= (get_tile "s_m_info") "s_m_beam") (setq m_info "beam"))
((= (get_tile "s_m_info") "s_m_colu") (setq m_info "colu"))
)
(cond ((= (get_tile "s_m_con") "s_m_force") (setq m_con "force"))
((= (get_tile "s_m_con") "s_m_area") (setq m_con "area"))
)
(cond ((= (get_tile "s_v_con") "s_v_close") (setq cf_vcon 1.0))
((= (get_tile "s_v_con") "s_v_u") (setq cf_vcon 0.85))
((= (get_tile "s_v_con") "s_v_side") (setq cf_vcon 0.7))
)
)
;检查输入数据
(defun m_check (why key s_val m_min m_max m_str m_start)
(setq f_var (distof s_val 2))
(if (or (< f_var m_min) (> f_var m_max) (= f_var nil))
(progn
(alert m_str)
(set_tile key m_start)
(mode_tile key 2)
)
)
)
;检查条件
(defun m_con_check (why key s_val)
(cond ((= s_val "s_m_force")
(mode_tile "s_m_mtot" 0)
(mode_tile "s_m_mtot" 2)
(mode_tile "s_m_mtot" 3)
(mode_tile "s_m_vtot" 0)
(mode_tile "s_cf_a" 0)
(mode_tile "s_cf_av" 0)
(mode_tile "s_cf_b" 1)
(mode_tile "s_cf_s" 1)
)
((= s_val "s_m_area")
(mode_tile "s_cf_b" 0)
(mode_tile "s_cf_b" 2)
(mode_tile "s_cf_b" 3)
(mode_tile "s_cf_s" 0)
(mode_tile "s_m_mtot" 1)
(mode_tile "s_m_vtot" 1)
(mode_tile "s_cf_a" 1)
(mode_tile "s_cf_av" 1)
)
)
)
;计算主程序
(defun cal ()
(read_data)
(setq c_eds (- c_h s_dstc);混凝土构件截面有效高度
c_hw (chw c_h c_htf c_hcf c_eds);腹板高度
cf_h (cfh c_h c_hcf c_htf);抗剪碳纤维片材高度
c_me (cme c_sc);混凝土的弹性模量
c_f (fc c_sc);混凝土抗压强度设计值
c_t (ft c_sc);混凝土抗拉强度标准值
m_racfacua (racfacua m_ntot c_f c_b c_h);轴压比
s_me (sme s_f);钢筋的弹性模量
c_cbdcz (ccbdcz s_f s_me);相对界限受压区高度
)
(setq m_qis (mqis c_f c_b c_eds c_hw m_vtot)
c_vcs (cvcs c_t c_b c_eds s_fv s_av s_s)
)
(cond ((= m_info "beam")
(setq cf_atav (atav1 m_rssed cf_auta))
)
((= m_info "colu")
(setq cf_atav (atav2 m_rssed m_racfacua cf_auta))
)
)
(cond ((= m_con "force")
(shear_to_cfs)
(cfs_to_shear)
)
((= m_con "area")
(cfs_to_shear)
)
)
(cond ((> m_mbeg 0)
(setq m_rsc (rsc s_me c_me);钢筋弹性模量与混凝土弹性模量的比值
s_pr (pr s_at c_b c_eds);受拉钢筋配筋率
c_eta (ceta c_b c_h c_btf c_btf);有效受拉混凝土截面面积
c_smt (csmt c_b c_eds c_bcf c_hcf);受压翼缘加强系数
s_prceta (prceta s_at c_eta);按有效受拉混凝土截面面积计算的受拉钢筋配筋率
s_tsbeg (stsbeg m_mbeg s_at c_eds);在初始弯矩作用下受拉钢筋拉应力
s_ndtsc (ndtsc c_t s_tsbeg s_prceta);受拉钢筋拉应变不均匀系数
c_cam (cam c_smt m_rsc s_pr);受压边缘混凝土压应变综合系数
c_cabeg (ccabeg m_mbeg c_cam c_me c_b c_eds);混凝土初始压应变
s_tabeg (stabeg s_ndtsc m_mbeg c_eds s_at s_me);在初始弯矩作用下受拉钢筋拉应变
c_tabeg (ctabeg c_h c_eds c_cabeg s_tabeg);混凝土初始拉应变
)
)
(t (setq c_tabeg 0.0))
)
(setq cf_km (km cf_n cf_me cf_t);碳纤维片材厚度折减系数
cf_ata (ata cf_km cf_auta);碳纤维片材的允许拉应变
c_bdcz (bdcz cf_ata c_tabeg c_h);界限受压区高度
)
(cond ((= m_con "force")
(setq c_x (cx1 m_mtot c_f c_b c_h c_eds c_t s_f s_at s_ac s_dstc));受压区高度
(cx_to_area)
(if (<= cf_a 0)
(progn
(setq cf_a 0)
(setq c_x (cx2 cf_a cf_me c_f c_b c_h c_tabeg s_f s_at s_ac))
(cx_to_mon)
)
)
)
((= m_con "area")
(setq cf_a (* cf_b (* cf_t cf_n)))
(setq c_x (cx2 cf_a cf_me c_f c_b c_h c_tabeg s_f s_at s_ac))
(cx_to_mon)
)
)
(wcdcz c_x c_eds);写相对受压区高度
(wmmmax m_mmax);写构件允许弯矩设计值
(wmvmax m_vmax);写构件允许剪力设计值
)
;写抗弯碳纤维片材截面面积
(defun wcfa (cf_a cf_n cf_t)
(setq l_cf_a '())
(start_list "s_cf_a")
(cond ((= cf_a nil)
(add_list "**********")
(setq l_cf_a (cons nil l_cf_a))
)
((> cf_a 0)
(setq cf_bb (* (1+ (fix (/ (/ (/ cf_a cf_n) cf_t) 10))) 10))
(repeat 5
(add_list
(strcat (itoa cf_n) "×" (rtos cf_t) "×" (rtos cf_bb) " = "
(rtos (* (* cf_n cf_t) cf_bb)))
)
(setq l_cf_a (cons (* cf_bb (* cf_n cf_t)) l_cf_a)
cf_bb (+ cf_bb 10)
)
)
)
(t (add_list "0"))
)
(end_list)
)
;写抗剪碳纤维片材截面面积
(defun wcfav (cf_av cf_nv cf_t)
(setq l_cf_s '())
(start_list "s_cf_av")
(cond ((= cf_s nil)
(add_list "**********")
(setq l_cf_s (cons nil l_cf_s))
)
((> cf_s 0)
(setq cf_ss (* (1- (fix (/ cf_s 10))) 10))
(repeat 5
(add_list
(strcat (itoa cf_nv) "×" (rtos cf_t) "×" (rtos cf_bv) " @ " (rtos cf_ss))
)
(setq l_cf_s (cons cf_ss l_cf_s)
cf_ss (- cf_ss 10)
)
)
)
(t (add_list "0"))
)
(end_list)
)
;写相对受压区高度
(defun wcdcz(c_x c_eds)
(cond ((/= c_x nil)
(set_tile "s_c_dcz" (strcat "相对受压区高度 = " (rtos (/ c_x c_eds) 2 4)))
)
(t (set_tile "s_c_dcz" "相对受压区高度 ="))
)
)
;写构件允许弯矩设计值
(defun wmmmax(m_mmax)
(cond ((/= m_mmax nil)
(set_tile "s_m_mmax" (strcat "构件允许弯矩设计值 = " (rtos (/ m_mmax 1000000.0) 2 2) " (kN·m)"))
)
(t (set_tile "s_m_mmax" "构件允许弯矩设计值 ="))
)
)
;写构件允许剪力设计值
(defun wmvmax(m_vmax)
(cond ((/= m_vmax nil)
(set_tile "s_m_vmax" (strcat "构件允许剪力设计值 = " (rtos (/ m_vmax 1000.0) 2 2) " (kN)"))
)
(t (set_tile "s_m_vmax" "构件允许剪力设计值 ="))
)
)
;选择抗弯碳纤维面积
(defun cfsa (s_val)
(cond ((/= (last l_cf_a) "**********")
(setq cf_a (nth (- 4 (atoi s_val)) l_cf_a)
c_x (cx2 cf_a cf_me c_f c_b c_h c_tabeg s_f s_at s_ac)
)
(cx_to_mon)
)
(t
(setq c_x nil)
(setq m_mmax nil)
)
)
(wcdcz c_x c_h);写相对受压区高度
(wmmmax m_mmax);写构件允许弯矩设计值
)
;选择抗剪碳纤维面积
(defun cfsav (s_val)
(cond ((/= (last l_cf_s) "**********")
(setq cf_s (nth (- 4 (atoi s_val)) l_cf_s))
(cfs_to_shear);构件允许剪力设计值
)
(t
(setq cf_s nil)
(setq m_vmax nil)
)
)
(wmvmax m_vmax);写构件允许弯矩设计值
)
;混凝土初始拉应变
(defun ctabeg (c_h c_eds c_cabeg s_tabeg)
(- (/ (* c_h (+ c_cabeg s_tabeg)) c_eds) c_cabeg)
)
;在初始弯矩作用下受拉钢筋拉应力
(defun stsbeg (m_mbeg s_at c_eds)
(/ m_mbeg (* (* s_at 0.87) c_eds))
)
;受拉钢筋拉应变不均匀系数
(defun ndtsc (c_t s_tsbeg s_pr)
(- 1.1 (/ (* 0.65 c_t) (* s_tsbeg s_pr)))
)
;受拉钢筋配筋率
(defun pr (s_at c_b c_eds) (/ s_at (* c_b c_eds)))
;有效受拉混凝土截面面积
(defun ceta (c_b c_h c_btf c_htf)
(+ (* (* 0.5 c_b) c_h) (* (- c_btf c_b) c_htf))
)
;按有效受拉混凝土截面面积计算的受拉钢筋配筋率
(defun prceta (s_at c_eta) (/ s_at c_eta))
;受压翼缘加强系数
(defun csmt (c_b c_eds c_bcf c_hcf)
(/ (* (- c_bcf c_b) c_hcf) (* c_b c_eds))
)
;受压边缘混凝土压应变综合系数
(defun cam (c_smt m_rsc s_pr)
(/ (* (* (+ 1 (* 3.5 c_smt)) m_rsc) s_pr)
(+ (* 0.2 (+ 1 (* 3.5 c_smt))) (* (* 6 m_rsc) s_pr))
)
)
;在初始弯矩作用下受拉钢筋拉应变
(defun stabeg (s_ndtsc m_mbeg c_eds s_at s_me)
(/ (* s_ndtsc m_mbeg) (* 0.87 (* s_me (* s_at c_eds))))
)
;混凝土初始压应变
(defun ccabeg (m_mbeg c_cam c_me c_b c_eds)
(/ m_mbeg (* c_cam (* c_me (* c_b (* c_eds c_eds)))))
)
;混凝土初始拉应变
(defun ctabeg (c_h c_eds c_cabeg s_tabeg)
(- (/ (* c_h (+ c_cabeg s_tabeg)) c_eds) c_cabeg)
)
;已知弯矩求受压区度度
(defun cx1 (m_mtot c_f c_b c_h c_eds c_t s_f s_at s_ac s_dstc / a b c1 c2 c d)
(setq a (/ (* c_f c_b) 2.0)
b (* c_f (* c_b c_h))
c1 (* s_f (* s_at s_dstc))
c2 (* s_f (* s_ac (- c_h s_dstc)))
c (+ m_mtot (- c1 c2))
d (- (* b b) (* 4 (* a c)))
)
(cond ((>= d 0) (/ (- b (sqrt d)) (* 2 a)))
(t nil)
)
)
;已知受压区度度求碳纤维片材截面面积
(defun cx_to_area()
(setq m_mmax m_mtot)
(cond ((> c_x (* c_cbdcz c_eds));如果混凝土受压区高度大于界限受压区度度
(setq cf_a nil)
(setq m_mmax nil)
(alert "!受压区大于界限受压区高度")
)
((> c_x (* 2 s_dstc))
(cond ((> c_x c_bdcz)
(setq cf_ta (ta c_x c_h c_tabeg);碳纤维片材的拉应变
cf_a (area1 c_x c_f c_b s_f s_at s_ac cf_me cf_ta);碳纤维片材截面面积
)
)
(t (setq cf_a (area2 m_mtot c_h c_eds c_bdcz s_f s_at cf_me cf_ata)))
)
)
((< c_x (* 2 s_dstc)) (setq cf_a (area3 m_mtot c_h c_eds s_f s_at s_dstc cf_me cf_ata)))
((= c_x nil)
(setq cf_a nil)
(setq m_mmax nil)
(alert "!方程无解")
)
)
(wcfa cf_a cf_n cf_t);写抗弯碳纤维片材截面面积
)
;已知纤维片材截面面积求受压区度度
(defun cx2 (cf_a cf_me c_f c_b c_h c_tabeg s_f s_at s_ac / a b1 b2 b c d)
(setq a (* c_f c_b)
b1 (- (* s_f s_at) (* s_f s_ac))
b2 (* (* cf_me cf_a) (+ 0.0033 c_tabeg))
b (- b1 b2)
c (* -0.8 (* (* cf_me cf_a) (* 0.0033 c_h)))
d (- (* b b) (* 4.0 (* a c)))
)
(cond ((>= d 0.0) (/ (+ b (sqrt d)) (* 2 a)))
(t nil)
)
)
;已知受压区度度求构件允许弯矩设计值
(defun cx_to_mon()
(cond ((> c_x (* c_cbdcz c_eds));如果混凝土受压区高度大于界限受压区度度
(alert "!受压区大于界限受压区高度")
(setq m_mmax nil)
)
((>= c_x (* 2 s_dstc))
(cond ((> c_x c_bdcz)
(setq cf_ta (ta c_x c_h c_tabeg);碳纤维片材的拉应变
m_mmax (mmax1 c_f c_b c_h c_eds s_f s_at s_ac s_dstc cf_me cf_ta cf_a);碳纤维片材截面面积
)
)
(t (setq m_mmax (mmax2 c_h c_eds c_bdcz s_f s_at cf_me cf_ata cf_a)))
)
)
((< c_x (* 2 s_dstc)) (setq m_mmax (mmax3 c_eds s_f s_at s_dstc cf_me cf_ata cf_a)))
((= c_x nil) (alert "!方程无解") (setq m_mmax nil))
)
)
;构件允许弯矩
(defun mmax1 (c_f c_b c_h c_eds s_f s_at s_ac s_dstc cf_me cf_ta cf_a / m1 m2 m3)
(setq m1 (* c_f (* c_b (* c_x (- c_h (/ c_x 2)))))
m2 (* s_f (* s_ac (- c_eds s_dstc)))
m3 (* cf_me (* cf_ta (* cf_a s_dstc)))
)
(+ m1 (+ m2 m3))
)
(defun mmax2 (c_h c_eds c_bdcz s_f s_at cf_me cf_ata cf_a / m1 m2)
(setq m1 (* s_f (* s_at (- c_eds (* 0.5 c_bdcz))))
m2 (* cf_me (* cf_ata (* cf_a (- c_h (* 0.5 c_bdcz)))))
)
(+ m1 m2)
)
(defun mmax3 (c_eds s_f s_at s_dstc cf_me cf_ata cf_a / m1 m2)
(setq m1 (* s_f (* s_at (- c_eds s_dstc)))
m2 (* cf_me (* cf_ata (* cf_a (- c_h s_dstc))))
)
(+ m1 m2)
)
;碳纤维片材的拉应变
(defun ta (c_x c_h c_tabeg)
(- (/ (* 0.8 (* 0.0033 c_h)) c_x) (+ 0.0033 c_tabeg))
)
;碳纤维片材截面积
(defun area1 (c_x c_f c_b s_f s_at s_ac cf_me cf_ta / a1 a2)
(setq a1 (- (* c_f (* c_b c_x)) (- (* s_f s_at) (* s_f s_ac)))
a2 (* cf_me cf_ta)
)
(/ a1 a2)
);受拉钢筋先屈服,然后受压区混凝土压坏,此时碳纤维片材未达到其允许拉变
(defun area2 (m_mtot c_h c_eds c_bdcz s_f s_at cf_me cf_ata / a1 a2)
(setq a1 (- m_mtot (* (* s_f s_at) (- c_eds (* 0.5 c_bdcz))))
a2 (* (* cf_me cf_ata) (- c_h (* 0.5 c_bdcz)))
)
(/ a1 a2)
);受拉钢筋先屈服,碳纤维片材达到其允许拉变,此时受压区混凝土尚未被压坏坏
(defun area3 (m_mtot c_h c_eds s_f s_at s_dstc cf_me cf_ata / a1 a2)
(setq a1 (- m_mtot (* (* s_f s_at) (- c_eds s_dstc)))
a2 (* (* cf_me cf_ata) (- c_h s_dstc))
)
(/ a1 a2)
);受拉钢筋先屈服,碳纤维片材达到其允许拉变,此时受压区混凝土尚未被压坏坏
;碳纤维片材厚度折减系数
(defun km (cf_n cf_me cf_t) (- 1 (/ (* (* cf_n cf_me) cf_t) 420000)))
;界限受压区度度
(defun bdcz (cf_ata c_tabeg c_h)
(* (/ (* 0.8 0.0033) (+ (+ 0.0033 cf_ata) c_tabeg)) c_h)
)
;抗弯碳纤维片材的允许拉应变
(defun ata (cf_km cf_auta / k1 k2)
(setq k1 (/ (* 2.0 cf_auta) 3.0)
k2 (* cf_km cf_auta)
)
(min k1 k2 0.01)
)
;混凝土抗压强度设计值
(defun fc (c_sc)
(cond
((>= c_sc 40) 19.1)
((>= c_sc 35) (+ 16.7 (* 0.58 (- c_sc 35))))
((>= c_sc 30) (+ 14.3 (* 0.48 (- c_sc 30))))
((>= c_sc 25) (+ 11.9 (* 0.48 (- c_sc 25))))
((>= c_sc 20) (+ 9.6 (* 0.46 (- c_sc 20))))
((>= c_sc 15) (+ 7.2 (* 0.48 (- c_sc 15))))
((< c_sc 15) 7.2)
)
)
;混凝土抗拉强度标准值
(defun ft (c_sc)
(cond
((>= c_sc 40) 2.39)
((>= c_sc 35) (+ 2.20 (* 0.038 (- c_sc 35))))
((>= c_sc 30) (+ 2.01 (* 0.038 (- c_sc 30))))
((>= c_sc 25) (+ 1.78 (* 0.046 (- c_sc 25))))
((>= c_sc 20) (+ 1.54 (* 0.048 (- c_sc 20))))
((>= c_sc 15) (+ 1.27 (* 0.054 (- c_sc 15))))
((< c_sc 15) 1.27)
)
)
;混凝土弹性模量
(defun cme (c_sc)
(cond
((>= c_sc 40) 3.25)
((>= c_sc 35) (* (+ 3.15 (* 0.02 (- c_sc 35))) 10000))
((>= c_sc 30) (* (+ 3.00 (* 0.03 (- c_sc 30))) 10000))
((>= c_sc 25) (* (+ 2.80 (* 0.04 (- c_sc 25))) 10000))
((>= c_sc 20) (* (+ 2.55 (* 0.05 (- c_sc 20))) 10000))
((>= c_sc 15) (* (+ 2.20 (* 0.07 (- c_sc 15))) 10000))
((< c_sc 15) 2.20)
)
)
;钢筋弹性模量
(defun sme (s_f)
(cond
((= s_f 210) 210000.0)
(t 200000.0)
)
)
;钢筋弹性模量与混凝土弹性模量的比值
(defun rsc (s_me c_me) (/ s_me c_me))
;相对界限受压区高度
(defun ccbdcz(s_f s_me)
(/ 1 (+ 1 (/ s_f (* s_me 0.0033))))
)
;轴压比
(defun racfacua(m_ntot c_f c_b c_h)
(/ m_ntot (* c_f c_b c_h))
)
;抗剪碳纤维片材的允许拉应变
(defun atav1 (m_rssed cf_auta)
(/ (* 2 (+ 0.2 (* 0.12 m_rssed)) cf_auta) 3.0)
)
(defun atav2 (m_rssed m_racfacua cf_auta)
(/ (* 2 (+ 0.2 (* -0.3 m_racfacua) (* 0.12 m_rssed)) cf_auta) 3.0)
)
;构件斜截面条件
(defun mqis (c_f c_b c_eds c_hw m_vtot)
(setq rhwb (/ c_hw c_b))
(cond ((<= rhwb 4)
(cond ((<= m_vtot (* 0.25 c_f c_b c_eds))
(setq m_qis 1)
)
(t (setq m_qis 0))
)
)
((>= rhwb 6)
(cond ((<= m_vtot (* 0.2 c_f c_b c_eds))
(setq m_qis 1)
)
(t (setq m_qis 0))
)
)
(t ((<= m_vtot (* c_f c_b c_eds (- 0.25 (* 0.025 (- rhwb 4)))))
(setq m_qis 1)
)
(t (setq m_qis 0))
)
)
(eval m_qis)
)
;腹板高度
(defun chw (c_h c_htf c_hcf c_eds)
(cond ((and (/= c_htf 0) (/= c_hct 0))
(setq c_hw (- c_h c_htf c_hcf))
)
((/= c_htf 0)
(setq c_hw (- c_eds c_hcf))
)
((/= c_hcf 0)
(setq c_hw (- c_eds c_htf))
)
(t (setq c_hw c_eds))
)
)
;抗剪碳纤维片材高度
(defun cfh (c_h c_hcf c_htf)
(- c_h c_htf c_hcf)
)
;混凝土受剪承载力
(defun cvcs (c_t c_b c_eds s_fv s_av s_s)
(+ (* 0.7 c_t c_b c_eds) (/ (* 1.25 s_fv s_av c_eds) s_s))
)
;抗剪碳纤维片材净间距
(defun cfs (m_vtot c_vcs cf_vcon cf_nv cf_t cf_bv cf_atav cf_me cf_h)
(- (/ (* cf_vcon 2 cf_nv cf_bv cf_t cf_atav cf_me cf_h) (- m_vtot c_vcs)) cf_bv)
)
;已知抗剪碳纤维片材净间距求构件允许剪力设计值
(defun cfs_to_shear (/ v1 v2)
(cond ((= m_qis 0)
(setq m_vmax nil)
(alert "!截面抗剪能力不足")
)
((= m_qis 1)
(cond
((/= cf_s 0) (setq v1 (* cf_vcon 2 cf_nv cf_bv cf_t cf_atav cf_me cf_h)
v2 (+ cf_s cf_bv)
cf_v (/ v1 v2)
)
)
(t (setq cf_v 0))
)
(setq m_vmax (+ c_vcs cf_v))
)
(t (setq m_vmax nil))
)
)
;已知构件剪力求抗剪碳纤维片材净间距
(defun shear_to_cfs ()
(setq m_vmax m_vtot)
(cond ((= m_qis 0)
(setq cf_s nil)
(setq m_vmax nil)
(alert "!截面抗剪能力不足")
)
((= m_qis 1)
(cond ((< m_vtot c_vcs) (setq cf_s 0))
(t (setq cf_s (cfs m_vtot c_vcs cf_vcon cf_nv cf_t cf_bv cf_atav cf_me cf_h)))
)
)
)
(wcfav cf_av cf_nv cf_t);写抗剪碳纤维片材截面面积
)
[/FONT]

[FONT=courier new] 
;碳纤维加固修复混凝土结构计算程序 
(defun c:cabon_fiber () 
  (setq dcl_id (load_dialog "cabon_fiber.dcl")) 
  (if (< dcl_id 0) (exit)) 
  (new_dialog "cabon_fiber" dcl_id) 
  (action_tile "s_i_info" "(i_info_check $reason $key $value)") 
  (action_tile "s_m_con" "(m_con_check $reason $key $value)") 
  (action_tile "s_m_mtot" "(m_check $reason $key $value 0 10000 "请输入一个不小于0的数" "20")") 
  (action_tile "s_m_mbeg" "(m_check $reason $key $value 0 10000 "请输入一个不小于0的数" "0")") 
  (action_tile "s_m_vtot" "(m_check $reason $key $value 0 10000 "请输入一个不小于0的数" "100")") 
  (action_tile "s_m_ntot" "(m_check $reason $key $value 0 10000 "请输入一个不小于0的数" "100")") 
  (action_tile "s_m_rssed" "(m_check $reason $key $value 1.0 3.0 "请输入一个介于1.0和3.0之间的数" "1.0")") 
  (action_tile "s_cf_auta" "(m_check $reason $key $value 0 1 "请输入一个不小于0的数" "0.021")") 
  (action_tile "s_cf_me" "(m_check $reason $key $value 210 10000 "请输入一个不小于210的数" "230")") 
  (action_tile "s_cf_t" "(m_check $reason $key $value 0 1 "请输入一个不小于0的数" "0.111")") 
  (action_tile "s_cf_n" "(m_check $reason $key $value 0 10 "请输入一个大于0的自然数" "1")") 
  (action_tile "s_cf_nv" "(m_check $reason $key $value 0 10 "请输入一个大于0的自然数" "1")") 
  (action_tile "s_cf_bv" "(m_check $reason $key $value 0 10000 "请输入一个大于0的自然数" "50")") 
  (action_tile "s_c_sc" "(m_check $reason $key $value 15 40 "请输入一个介于15和40之间的数" "15")") 
  (action_tile "s_c_b" "(m_check $reason $key $value 0 1000 "请输入一个不小于0的数" "250")") 
  (action_tile "s_c_h" "(m_check $reason $key $value 0 1000 "请输入一个不小于0的数" "300")") 
  (action_tile "s_c_btf" "(m_check $reason $key $value 0 1000 "请输入一个不小于0的数" "0")") 
  (action_tile "s_c_htf" "(m_check $reason $key $value 0 1000 "请输入一个不小于0的数" "0")") 
  (action_tile "s_c_bcf" "(m_check $reason $key $value 0 1000 "请输入一个不小于0的数" "0")") 
  (action_tile "s_c_hcf" "(m_check $reason $key $value 0 1000 "请输入一个不小于0的数" "0")") 
  (action_tile "s_s_f" "(m_check $reason $key $value 0 1000 "请输入一个不小于0的数" "300")") 
  (action_tile "s_s_fv" "(m_check $reason $key $value 0 1000 "请输入一个不小于0的数" "210")") 
  (action_tile "s_s_at" "(m_check $reason $key $value 0.00001 10000 "请输入一个不小于0的数" "226")") 
  (action_tile "s_s_ac" "(m_check $reason $key $value 0 10000 "请输入一个不小于0的数" "0")") 
  (action_tile "s_s_av" "(m_check $reason $key $value 0 10000 "请输入一个不小于0的数" "0")") 
  (action_tile "s_s_s" "(m_check $reason $key $value 50 300 "请输入一个介于50和300之间的数" "200")") 
  (action_tile "s_s_dstc" "(m_check $reason $key $value 0 100 "请输入一个不小于0的数" "35")") 
  (action_tile "s_cf_a" "(cfsa $value)") 
  (action_tile "s_cf_av" "(cfsav $value)") 
  (action_tile "s_cal" "(cal)")   
  (action_tile "s_ok" "(done_dialog 1)") 
  (setq dcl_s (start_dialog)) 
  (unload_dialog dcl_id) 
  (princ) 
) 
 
;读取数值 
(defun read_data() 
  (setq m_mtot (* (atof (get_tile "s_m_mtot")) 1000000) 
        m_mbeg (* (atof (get_tile "s_m_mbeg")) 1000000) 
        m_vtot (* (atof (get_tile "s_m_vtot")) 1000) 
        m_ntot (* (atof (get_tile "s_m_ntot")) 1000) 
        m_rssed (atof (get_tile "s_m_rssed")) 
        cf_b (atof (get_tile "s_cf_b")) 
        cf_bv (atof (get_tile "s_cf_bv")) 
        cf_s (atof (get_tile "s_cf_s")) 
        cf_auta (atof (get_tile "s_cf_auta")) 
        cf_me (* (atof (get_tile "s_cf_me")) 1000) 
        cf_t (atof (get_tile "s_cf_t")) 
        cf_n (atoi (get_tile "s_cf_n")) 
        cf_nv (atoi (get_tile "s_cf_nv")) 
        c_sc (atof (get_tile "s_c_sc")) 
        c_b (atof (get_tile "s_c_b")) 
        c_h (atof (get_tile "s_c_h")) 
        c_btf (atof (get_tile "s_c_btf")) 
        c_htf (atof (get_tile "s_c_htf")) 
        c_bcf (atof (get_tile "s_c_bcf")) 
        c_hcf (atof (get_tile "s_c_hcf")) 
        s_f (atof (get_tile "s_s_f")) 
        s_fv (atof (get_tile "s_s_fv")) 
        s_at (atof (get_tile "s_s_at")) 
        s_ac (atof (get_tile "s_s_ac")) 
        s_av (atof (get_tile "s_s_av")) 
        s_s (atof (get_tile "s_s_s")) 
        s_dstc (atof (get_tile "s_s_dstc")) 
  ) 
  (cond ((= (get_tile "s_m_info") "s_m_beam") (setq m_info "beam")) 
        ((= (get_tile "s_m_info") "s_m_colu") (setq m_info "colu")) 
  ) 
  (cond ((= (get_tile "s_m_con") "s_m_force") (setq m_con "force")) 
        ((= (get_tile "s_m_con") "s_m_area") (setq m_con "area")) 
  ) 
  (cond ((= (get_tile "s_v_con") "s_v_close") (setq cf_vcon 1.0)) 
        ((= (get_tile "s_v_con") "s_v_u") (setq cf_vcon 0.85)) 
        ((= (get_tile "s_v_con") "s_v_side") (setq cf_vcon 0.7)) 
  ) 
) 
 
;检查输入数据 
(defun m_check (why key s_val m_min m_max m_str m_start) 
  (setq f_var (distof s_val 2)) 
  (if (or (< f_var m_min)  (> f_var m_max) (= f_var nil)) 
    (progn 
      (alert m_str) 
      (set_tile key m_start) 
      (mode_tile key 2) 
    ) 
  ) 
) 
 
 
;检查条件 
(defun m_con_check (why key s_val) 
  (cond ((= s_val "s_m_force") 
         (mode_tile "s_m_mtot" 0) 
         (mode_tile "s_m_mtot" 2) 
         (mode_tile "s_m_mtot" 3) 
         (mode_tile "s_m_vtot" 0) 
         (mode_tile "s_cf_a" 0) 
         (mode_tile "s_cf_av" 0) 
         (mode_tile "s_cf_b" 1) 
         (mode_tile "s_cf_s" 1)          
        ) 
        ((= s_val "s_m_area") 
         (mode_tile "s_cf_b" 0) 
         (mode_tile "s_cf_b" 2) 
         (mode_tile "s_cf_b" 3) 
         (mode_tile "s_cf_s" 0) 
         (mode_tile "s_m_mtot" 1) 
         (mode_tile "s_m_vtot" 1) 
         (mode_tile "s_cf_a" 1) 
         (mode_tile "s_cf_av" 1)        
        ) 
  ) 
) 
          
;计算主程序 
(defun cal () 
  (read_data) 
  (setq c_eds (- c_h s_dstc);混凝土构件截面有效高度 
        c_hw (chw c_h c_htf c_hcf c_eds);腹板高度 
        cf_h (cfh c_h c_hcf c_htf);抗剪碳纤维片材高度 
        c_me (cme c_sc);混凝土的弹性模量 
        c_f (fc c_sc);混凝土抗压强度设计值 
        c_t (ft c_sc);混凝土抗拉强度标准值 
        m_racfacua (racfacua m_ntot c_f c_b c_h);轴压比 
        s_me (sme s_f);钢筋的弹性模量 
        c_cbdcz (ccbdcz s_f s_me);相对界限受压区高度 
  ) 
  (setq m_qis (mqis c_f c_b c_eds c_hw m_vtot) 
        c_vcs (cvcs c_t c_b c_eds s_fv s_av s_s) 
  ) 
  (cond ((= m_info "beam") 
         (setq cf_atav (atav1 m_rssed cf_auta)) 
        ) 
        ((= m_info "colu") 
         (setq cf_atav (atav2 m_rssed m_racfacua cf_auta)) 
        ) 
  ) 
  (cond ((= m_con "force")          
         (shear_to_cfs) 
         (cfs_to_shear) 
        ) 
        ((= m_con "area") 
         (cfs_to_shear) 
        )        
  )   
  (cond ((> m_mbeg 0) 
         (setq m_rsc (rsc s_me c_me);钢筋弹性模量与混凝土弹性模量的比值 
               s_pr (pr s_at c_b c_eds);受拉钢筋配筋率 
               c_eta (ceta c_b c_h c_btf c_btf);有效受拉混凝土截面面积 
               c_smt (csmt c_b c_eds c_bcf c_hcf);受压翼缘加强系数 
               s_prceta (prceta s_at c_eta);按有效受拉混凝土截面面积计算的受拉钢筋配筋率 
               s_tsbeg (stsbeg m_mbeg s_at c_eds);在初始弯矩作用下受拉钢筋拉应力 
               s_ndtsc (ndtsc c_t s_tsbeg s_prceta);受拉钢筋拉应变不均匀系数 
               c_cam (cam c_smt m_rsc s_pr);受压边缘混凝土压应变综合系数 
               c_cabeg (ccabeg m_mbeg c_cam c_me c_b c_eds);混凝土初始压应变 
               s_tabeg (stabeg s_ndtsc m_mbeg c_eds s_at s_me);在初始弯矩作用下受拉钢筋拉应变 
               c_tabeg (ctabeg c_h c_eds c_cabeg s_tabeg);混凝土初始拉应变 
         ) 
        ) 
        (t (setq c_tabeg 0.0)) 
  ) 
  (setq cf_km (km cf_n cf_me cf_t);碳纤维片材厚度折减系数 
        cf_ata (ata cf_km cf_auta);碳纤维片材的允许拉应变 
        c_bdcz (bdcz cf_ata c_tabeg c_h);界限受压区高度 
  ) 
  (cond ((= m_con "force")          
         (setq c_x (cx1 m_mtot c_f c_b c_h c_eds c_t s_f s_at s_ac s_dstc));受压区高度 
         (cx_to_area) 
         (if (<= cf_a 0) 
           (progn 
             (setq cf_a 0) 
             (setq c_x (cx2 cf_a cf_me c_f c_b c_h c_tabeg s_f s_at s_ac)) 
             (cx_to_mon) 
           ) 
         ) 
        ) 
        ((= m_con "area") 
         (setq cf_a (* cf_b (* cf_t cf_n))) 
         (setq c_x (cx2 cf_a cf_me c_f c_b c_h c_tabeg s_f s_at s_ac)) 
         (cx_to_mon) 
        )        
  ) 
  (wcdcz c_x c_eds);写相对受压区高度 
  (wmmmax m_mmax);写构件允许弯矩设计值 
  (wmvmax m_vmax);写构件允许剪力设计值 
) 
 
;写抗弯碳纤维片材截面面积 
(defun wcfa (cf_a cf_n cf_t) 
  (setq l_cf_a '()) 
  (start_list "s_cf_a") 
  (cond ((= cf_a nil)          
         (add_list "**********") 
         (setq l_cf_a (cons nil l_cf_a)) 
        ) 
        ((> cf_a 0) 
         (setq cf_bb (* (1+ (fix (/ (/ (/ cf_a cf_n) cf_t) 10))) 10)) 
         (repeat 5           
           (add_list 
                (strcat (itoa cf_n) "×" (rtos cf_t) "×" (rtos cf_bb) " = " 
                        (rtos (* (* cf_n cf_t) cf_bb))) 
           ) 
           (setq l_cf_a (cons (* cf_bb (* cf_n cf_t)) l_cf_a) 
                 cf_bb (+ cf_bb 10) 
           )          
         )          
        ) 
        (t (add_list "0")) 
  ) 
  (end_list) 
) 
 
;写抗剪碳纤维片材截面面积 
(defun wcfav (cf_av cf_nv cf_t) 
  (setq l_cf_s '()) 
  (start_list "s_cf_av") 
  (cond ((= cf_s nil)          
         (add_list "**********") 
         (setq l_cf_s (cons nil l_cf_s)) 
        ) 
        ((> cf_s 0) 
         (setq cf_ss (* (1- (fix (/ cf_s 10))) 10)) 
         (repeat 5           
           (add_list 
                (strcat (itoa cf_nv) "×" (rtos cf_t) "×" (rtos cf_bv) " @ " (rtos cf_ss)) 
           ) 
           (setq l_cf_s (cons cf_ss l_cf_s) 
                 cf_ss (- cf_ss 10) 
           )          
         )          
        ) 
        (t (add_list "0")) 
  ) 
  (end_list) 
) 
 
;写相对受压区高度 
(defun wcdcz(c_x c_eds) 
  (cond ((/= c_x nil) 
         (set_tile "s_c_dcz" (strcat "相对受压区高度 = " (rtos (/ c_x c_eds) 2 4))) 
        ) 
        (t (set_tile "s_c_dcz" "相对受压区高度 =")) 
  ) 
) 
 
;写构件允许弯矩设计值 
(defun wmmmax(m_mmax) 
  (cond ((/= m_mmax nil) 
         (set_tile "s_m_mmax" (strcat "构件允许弯矩设计值 = " (rtos (/ m_mmax 1000000.0) 2 2) " (kN·m)")) 
        ) 
        (t (set_tile "s_m_mmax" "构件允许弯矩设计值 =")) 
  ) 
) 
 
;写构件允许剪力设计值 
(defun wmvmax(m_vmax) 
  (cond ((/= m_vmax nil) 
         (set_tile "s_m_vmax" (strcat "构件允许剪力设计值 = " (rtos (/ m_vmax 1000.0) 2 2) " (kN)")) 
        ) 
        (t (set_tile "s_m_vmax" "构件允许剪力设计值 =")) 
  ) 
) 
 
;选择抗弯碳纤维面积 
(defun cfsa (s_val) 
  (cond ((/= (last l_cf_a) "**********") 
         (setq cf_a (nth (- 4 (atoi s_val)) l_cf_a) 
               c_x (cx2 cf_a cf_me c_f c_b c_h c_tabeg s_f s_at s_ac) 
         ) 
         (cx_to_mon)          
        ) 
        (t 
         (setq c_x nil) 
         (setq m_mmax nil) 
        )        
  ) 
  (wcdcz c_x c_h);写相对受压区高度 
  (wmmmax m_mmax);写构件允许弯矩设计值 
) 
 
;选择抗剪碳纤维面积 
(defun cfsav (s_val) 
  (cond ((/= (last l_cf_s) "**********") 
         (setq cf_s (nth (- 4 (atoi s_val)) l_cf_s)) 
         (cfs_to_shear);构件允许剪力设计值          
        ) 
        (t 
         (setq cf_s nil) 
         (setq m_vmax nil) 
        )        
  ) 
  (wmvmax m_vmax);写构件允许弯矩设计值 
) 
 
;混凝土初始拉应变 
(defun ctabeg (c_h c_eds c_cabeg s_tabeg) 
  (- (/ (* c_h (+ c_cabeg s_tabeg)) c_eds) c_cabeg) 
) 
 
;在初始弯矩作用下受拉钢筋拉应力 
(defun stsbeg (m_mbeg s_at c_eds) 
  (/ m_mbeg (* (* s_at 0.87) c_eds)) 
) 
 
;受拉钢筋拉应变不均匀系数 
(defun ndtsc (c_t s_tsbeg s_pr) 
  (- 1.1 (/ (* 0.65 c_t) (* s_tsbeg s_pr))) 
) 
   
;受拉钢筋配筋率 
(defun pr (s_at c_b c_eds) (/ s_at (* c_b c_eds))) 
 
;有效受拉混凝土截面面积 
(defun ceta (c_b c_h c_btf c_htf) 
  (+ (* (* 0.5 c_b) c_h) (* (- c_btf c_b) c_htf)) 
) 
 
;按有效受拉混凝土截面面积计算的受拉钢筋配筋率 
(defun prceta (s_at c_eta) (/ s_at c_eta)) 
 
;受压翼缘加强系数 
(defun csmt (c_b c_eds c_bcf c_hcf) 
  (/ (* (- c_bcf c_b) c_hcf) (* c_b c_eds)) 
) 
 
;受压边缘混凝土压应变综合系数 
(defun cam (c_smt m_rsc s_pr) 
  (/ (* (* (+ 1 (* 3.5 c_smt)) m_rsc) s_pr) 
     (+ (* 0.2 (+ 1 (* 3.5 c_smt))) (* (* 6 m_rsc) s_pr)) 
  ) 
) 
 
;在初始弯矩作用下受拉钢筋拉应变 
(defun stabeg (s_ndtsc m_mbeg c_eds s_at s_me) 
  (/ (* s_ndtsc m_mbeg) (* 0.87 (* s_me (* s_at c_eds)))) 
) 
 
;混凝土初始压应变 
(defun ccabeg (m_mbeg c_cam c_me c_b c_eds) 
  (/ m_mbeg (* c_cam (* c_me (* c_b (* c_eds c_eds))))) 
) 
 
;混凝土初始拉应变 
(defun ctabeg (c_h c_eds c_cabeg s_tabeg) 
  (- (/ (* c_h (+ c_cabeg s_tabeg)) c_eds) c_cabeg) 
) 
                
;已知弯矩求受压区度度 
(defun cx1 (m_mtot c_f c_b c_h c_eds c_t s_f s_at s_ac s_dstc / a b c1 c2 c d) 
  (setq a (/ (* c_f c_b) 2.0) 
        b (* c_f (* c_b c_h)) 
        c1 (* s_f (* s_at s_dstc)) 
        c2 (* s_f (* s_ac (- c_h s_dstc))) 
        c (+ m_mtot (- c1 c2)) 
        d (- (* b b) (* 4 (* a c))) 
  ) 
  (cond ((>= d 0) (/ (- b (sqrt d)) (* 2 a))) 
        (t nil) 
  ) 
) 
 
;已知受压区度度求碳纤维片材截面面积 
(defun cx_to_area() 
  (setq m_mmax m_mtot) 
  (cond ((> c_x (* c_cbdcz c_eds));如果混凝土受压区高度大于界限受压区度度 
         (setq cf_a nil) 
         (setq m_mmax nil) 
         (alert "!受压区大于界限受压区高度") 
        ) 
        ((> c_x (* 2 s_dstc)) 
         (cond ((> c_x c_bdcz) 
                (setq cf_ta (ta c_x c_h c_tabeg);碳纤维片材的拉应变 
                      cf_a (area1 c_x c_f c_b s_f s_at s_ac cf_me cf_ta);碳纤维片材截面面积 
                ) 
               ) 
               (t (setq cf_a (area2 m_mtot c_h c_eds c_bdcz s_f s_at cf_me cf_ata))) 
         ) 
        ) 
        ((< c_x (* 2 s_dstc)) (setq cf_a (area3 m_mtot c_h c_eds s_f s_at s_dstc cf_me cf_ata))) 
        ((= c_x nil) 
         (setq cf_a nil) 
         (setq m_mmax nil) 
         (alert "!方程无解") 
        ) 
  )   
  (wcfa cf_a cf_n cf_t);写抗弯碳纤维片材截面面积 
) 
 
;已知纤维片材截面面积求受压区度度 
(defun cx2 (cf_a cf_me c_f c_b c_h c_tabeg s_f s_at s_ac / a b1 b2 b c d) 
  (setq a (* c_f c_b) 
        b1 (- (* s_f s_at) (* s_f s_ac)) 
        b2 (* (* cf_me cf_a) (+ 0.0033 c_tabeg)) 
        b (- b1 b2) 
        c (* -0.8 (* (* cf_me cf_a) (* 0.0033 c_h))) 
        d (- (* b b) (* 4.0 (* a c))) 
  ) 
  (cond ((>= d 0.0) (/ (+ b (sqrt d)) (* 2 a))) 
        (t nil) 
  ) 
) 
 
;已知受压区度度求构件允许弯矩设计值 
(defun cx_to_mon() 
  (cond ((> c_x (* c_cbdcz c_eds));如果混凝土受压区高度大于界限受压区度度 
         (alert "!受压区大于界限受压区高度") 
         (setq m_mmax nil) 
        ) 
        ((>= c_x (* 2 s_dstc)) 
         (cond ((> c_x c_bdcz) 
                (setq cf_ta (ta c_x c_h c_tabeg);碳纤维片材的拉应变 
                      m_mmax (mmax1 c_f c_b c_h c_eds s_f s_at s_ac s_dstc cf_me cf_ta cf_a);碳纤维片材截面面积 
                ) 
               ) 
               (t (setq m_mmax (mmax2 c_h c_eds c_bdcz s_f s_at cf_me cf_ata cf_a))) 
         ) 
        ) 
        ((< c_x (* 2 s_dstc)) (setq m_mmax (mmax3 c_eds s_f s_at s_dstc cf_me cf_ata cf_a))) 
        ((= c_x nil) (alert "!方程无解") (setq m_mmax nil)) 
  ) 
) 
 
;构件允许弯矩 
(defun mmax1 (c_f c_b c_h c_eds s_f s_at s_ac s_dstc cf_me cf_ta cf_a / m1 m2 m3) 
  (setq m1 (* c_f (* c_b (* c_x (- c_h (/ c_x 2))))) 
        m2 (* s_f (* s_ac (- c_eds s_dstc))) 
        m3 (* cf_me (* cf_ta (* cf_a s_dstc))) 
  ) 
  (+ m1 (+ m2 m3)) 
) 
 
(defun mmax2 (c_h c_eds c_bdcz s_f s_at cf_me cf_ata cf_a / m1 m2) 
  (setq m1 (* s_f (* s_at (- c_eds (* 0.5 c_bdcz)))) 
        m2 (* cf_me (* cf_ata (* cf_a (- c_h (* 0.5 c_bdcz))))) 
  ) 
  (+ m1 m2) 
) 
 
(defun mmax3 (c_eds s_f s_at s_dstc cf_me cf_ata cf_a / m1 m2) 
  (setq m1 (* s_f (* s_at (- c_eds s_dstc))) 
        m2 (* cf_me (* cf_ata (* cf_a (- c_h s_dstc)))) 
  ) 
  (+ m1 m2) 
) 
 
;碳纤维片材的拉应变 
(defun ta (c_x c_h c_tabeg) 
  (- (/ (* 0.8 (* 0.0033 c_h)) c_x) (+ 0.0033 c_tabeg)) 
) 
 
;碳纤维片材截面积 
(defun area1 (c_x c_f c_b s_f s_at s_ac cf_me cf_ta / a1 a2) 
  (setq a1 (- (* c_f (* c_b c_x)) (- (* s_f s_at) (* s_f s_ac))) 
        a2 (* cf_me cf_ta) 
  ) 
  (/ a1 a2) 
);受拉钢筋先屈服,然后受压区混凝土压坏,此时碳纤维片材未达到其允许拉变 
(defun area2 (m_mtot c_h c_eds c_bdcz s_f s_at cf_me cf_ata / a1 a2) 
  (setq a1 (- m_mtot (* (* s_f s_at) (- c_eds (* 0.5 c_bdcz)))) 
        a2 (* (* cf_me cf_ata) (- c_h (* 0.5 c_bdcz))) 
  ) 
  (/ a1 a2) 
);受拉钢筋先屈服,碳纤维片材达到其允许拉变,此时受压区混凝土尚未被压坏坏 
 
(defun area3 (m_mtot c_h c_eds s_f s_at s_dstc cf_me cf_ata / a1 a2) 
  (setq a1 (- m_mtot (* (* s_f s_at) (- c_eds s_dstc))) 
        a2 (* (* cf_me cf_ata) (- c_h s_dstc)) 
  ) 
  (/ a1 a2) 
);受拉钢筋先屈服,碳纤维片材达到其允许拉变,此时受压区混凝土尚未被压坏坏 
 
;碳纤维片材厚度折减系数 
(defun km (cf_n cf_me cf_t) (- 1 (/ (* (* cf_n cf_me) cf_t) 420000))) 
 
;界限受压区度度 
(defun bdcz (cf_ata c_tabeg c_h) 
  (* (/ (* 0.8 0.0033) (+ (+ 0.0033 cf_ata) c_tabeg)) c_h) 
) 
 
;抗弯碳纤维片材的允许拉应变 
(defun ata (cf_km cf_auta / k1 k2) 
  (setq k1 (/ (* 2.0 cf_auta) 3.0) 
        k2 (* cf_km cf_auta) 
  ) 
  (min k1 k2 0.01) 
) 
 
;混凝土抗压强度设计值 
(defun fc (c_sc) 
  (cond 
    ((>= c_sc 40) 19.1) 
    ((>= c_sc 35) (+ 16.7 (* 0.58 (- c_sc 35)))) 
    ((>= c_sc 30) (+ 14.3 (* 0.48 (- c_sc 30)))) 
    ((>= c_sc 25) (+ 11.9 (* 0.48 (- c_sc 25)))) 
    ((>= c_sc 20) (+ 9.6 (* 0.46 (- c_sc 20)))) 
    ((>= c_sc 15) (+ 7.2 (* 0.48 (- c_sc 15)))) 
    ((< c_sc 15) 7.2) 
  ) 
) 
 
;混凝土抗拉强度标准值 
(defun ft (c_sc) 
  (cond 
    ((>= c_sc 40) 2.39) 
    ((>= c_sc 35) (+ 2.20 (* 0.038 (- c_sc 35)))) 
    ((>= c_sc 30) (+ 2.01 (* 0.038 (- c_sc 30)))) 
    ((>= c_sc 25) (+ 1.78 (* 0.046 (- c_sc 25)))) 
    ((>= c_sc 20) (+ 1.54 (* 0.048 (- c_sc 20)))) 
    ((>= c_sc 15) (+ 1.27 (* 0.054 (- c_sc 15)))) 
    ((< c_sc 15) 1.27) 
  ) 
) 
 
;混凝土弹性模量 
(defun cme (c_sc) 
  (cond 
    ((>= c_sc 40) 3.25) 
    ((>= c_sc 35) (* (+ 3.15 (* 0.02 (- c_sc 35))) 10000)) 
    ((>= c_sc 30) (* (+ 3.00 (* 0.03 (- c_sc 30))) 10000)) 
    ((>= c_sc 25) (* (+ 2.80 (* 0.04 (- c_sc 25))) 10000)) 
    ((>= c_sc 20) (* (+ 2.55 (* 0.05 (- c_sc 20))) 10000)) 
    ((>= c_sc 15) (* (+ 2.20 (* 0.07 (- c_sc 15))) 10000)) 
    ((< c_sc 15) 2.20) 
  ) 
) 
 
;钢筋弹性模量 
(defun sme (s_f) 
  (cond 
    ((= s_f 210) 210000.0) 
    (t 200000.0) 
  ) 
) 
 
;钢筋弹性模量与混凝土弹性模量的比值 
(defun rsc (s_me c_me) (/ s_me c_me)) 
 
;相对界限受压区高度 
(defun ccbdcz(s_f s_me) 
  (/ 1 (+ 1 (/ s_f (* s_me 0.0033)))) 
) 
 
;轴压比 
(defun racfacua(m_ntot c_f c_b c_h) 
  (/ m_ntot (* c_f c_b c_h)) 
) 
 
;抗剪碳纤维片材的允许拉应变 
(defun atav1 (m_rssed cf_auta) 
  (/ (* 2 (+ 0.2 (* 0.12 m_rssed)) cf_auta) 3.0) 
) 
 
(defun atav2 (m_rssed m_racfacua cf_auta) 
  (/ (* 2 (+ 0.2 (* -0.3 m_racfacua) (* 0.12 m_rssed)) cf_auta) 3.0) 
) 
 
;构件斜截面条件 
(defun mqis (c_f c_b c_eds c_hw m_vtot) 
  (setq rhwb (/ c_hw c_b)) 
  (cond ((<= rhwb 4) 
         (cond ((<= m_vtot (* 0.25 c_f c_b c_eds)) 
                (setq m_qis 1) 
               ) 
               (t (setq m_qis 0)) 
         ) 
        ) 
        ((>= rhwb 6) 
         (cond ((<= m_vtot (* 0.2 c_f c_b c_eds)) 
                (setq m_qis 1) 
               ) 
               (t (setq m_qis 0)) 
         ) 
        ) 
        (t ((<= m_vtot (* c_f c_b c_eds (- 0.25 (* 0.025 (- rhwb 4))))) 
            (setq m_qis 1) 
           ) 
           (t (setq m_qis 0)) 
        ) 
  ) 
  (eval m_qis) 
) 
 
;腹板高度 
(defun chw (c_h c_htf c_hcf c_eds) 
  (cond ((and (/= c_htf 0) (/= c_hct 0)) 
         (setq c_hw (- c_h c_htf c_hcf)) 
        ) 
        ((/= c_htf 0) 
         (setq c_hw (- c_eds c_hcf)) 
        ) 
        ((/= c_hcf 0) 
         (setq c_hw (- c_eds c_htf)) 
        ) 
        (t (setq c_hw c_eds)) 
  ) 
) 
 
;抗剪碳纤维片材高度 
(defun cfh (c_h c_hcf c_htf) 
  (- c_h c_htf c_hcf) 
) 
 
;混凝土受剪承载力 
(defun cvcs (c_t c_b c_eds s_fv s_av s_s) 
  (+ (* 0.7 c_t c_b c_eds) (/ (* 1.25 s_fv s_av c_eds) s_s)) 
) 
 
;抗剪碳纤维片材净间距 
(defun cfs (m_vtot c_vcs cf_vcon cf_nv cf_t cf_bv cf_atav cf_me cf_h) 
  (- (/ (* cf_vcon 2 cf_nv cf_bv cf_t cf_atav cf_me cf_h) (- m_vtot c_vcs)) cf_bv) 
) 
 
;已知抗剪碳纤维片材净间距求构件允许剪力设计值 
(defun cfs_to_shear (/ v1 v2) 
  (cond ((= m_qis 0)          
         (setq m_vmax nil) 
         (alert "!截面抗剪能力不足") 
        ) 
        ((= m_qis 1) 
         (cond 
           ((/= cf_s 0) (setq v1 (* cf_vcon 2 cf_nv cf_bv cf_t cf_atav cf_me cf_h) 
                              v2 (+ cf_s cf_bv) 
                              cf_v (/ v1 v2) 
                        ) 
           ) 
           (t (setq cf_v 0)) 
         ) 
         (setq m_vmax (+ c_vcs cf_v)) 
        ) 
        (t (setq m_vmax nil)) 
  ) 
) 
 
;已知构件剪力求抗剪碳纤维片材净间距 
(defun shear_to_cfs () 
  (setq m_vmax m_vtot) 
  (cond ((= m_qis 0) 
         (setq cf_s nil) 
         (setq m_vmax nil) 
         (alert "!截面抗剪能力不足") 
        ) 
        ((= m_qis 1)          
         (cond ((< m_vtot c_vcs) (setq cf_s 0)) 
               (t (setq cf_s (cfs m_vtot c_vcs cf_vcon cf_nv cf_t cf_bv cf_atav cf_me cf_h))) 
         ) 
        )         
  )   
  (wcfav cf_av cf_nv cf_t);写抗剪碳纤维片材截面面积 
) 
 
  [/FONT]

aeo · 发表于 2004-4-4 00:21:21

好长呀，不是本专业，就不细看了.

alwaysbin你是原作者吗?

eachy · 发表于 2004-4-4 00:25:08

最好把 DCL 一并发上来，能讲解下更好了。

lsjjm · 发表于 2004-4-4 06:45:50

我不是搞建筑的, 说几句外行话. 用对话框输入数据, 一般适合于少量的数据. 否则对话框不但很大, 而且输入速度慢, 容易出错!?

阿禄 · 发表于 2004-4-5 16:38:15

最初由 eachy 发布
[B]最好把 DCL 一并发上来，能讲解下更好了。 [/B]

好的
有谁可以帮我讲一下它的流程吗?

星当家 · 发表于 2004-4-9 11:18:33

我们是同学,有急用,高手快看看,解释一下,有流程图最好了!!!

阿禄 · 发表于 2004-4-9 15:21:06

或者举例解释一下函数都是什么意思[/COLOR]

星当家 · 发表于 2004-4-10 20:23:23

哪位达人给看看把,小生在此谢过了!

账号		自动登录	找回密码
密码			立即注册

[求助] [求助]：关于AUTOLISP程序的问题

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子

浏览过的版块