[原创]：简单的多义线顶点写表 --- 2005 Table 试用

eachy

[PHP]
;; 简单的多义线顶点写表 --- 2005 Table 试用
;;  
;; 不用在CAD与Excel之间来回倒了
;;
;; 写表
(defun ea:addtable (pt row /)
  (setq        modelspace
         (vla-get-modelspace
           (vla-get-activedocument (vlax-get-acad-object))
         )
  )
  (vla-addtable
    modelspace
    (vlax-3d-point pt)                        ;插入点
    (vlax-make-variant row vlax-vblong)        ;行
    (vlax-make-variant 4 vlax-vblong)        ;列
    10.                                        ;行高
    60.                                        ;列宽
  )
)
;;测试部分, 不包括 Bulge
(defun c:test (/ elst e ptlst m)
  (if (setq e (entsel "\nSelect Polyline: "))
    (progn
      (setq elst (entget (car e)))
      (foreach i elst
        (if (= (car i) 10)
          (setq ptlst (cons (cdr i) ptlst))
        )
      );找到 Pline 的顶点表
      (setq tab        (ea:addtable (getvar "viewctr") (+ (length ptlst) 2))
            m        2
      )                                        ;把表加在屏幕中心
      (foreach p (reverse ptlst)
        (vla-SetText tab m 1 (rtos (car p) 2 3)) ;写 x 字串
        (vla-settext tab m 2 (rtos (cadr p) 2 3)) ;写 Y 字串
        (vla-setalignment                ;设置对齐方式
          tab
          (vlax-make-variant 1 vlax-vblong)
          acMiddleCenter
        )
        (setq m (1+ m))                        ;一行行写
      )
    )
  )
  (princ)
)
;;上表中数据绘制 Pline
(defun c:test1 (/ tbl obj m pts)
  (if (setq tbl (entsel "\n选择表: "))
    (progn
      (setq obj (vlax-ename->vla-object (car tbl))
            m 2)
      (repeat (- (vla-get-rows obj) 2)
        (setq pts (cons        (list (read (vla-gettext obj m 1))
                              (read (vla-gettext obj m 2))
                        )
                        pts
                  )
        )
        (setq m (1+ m))
      )
      (apply 'command (cons ".pline" pts))
      (command)
    )
  )
  (princ)
)[/PHP]

lsjjm

获取多义线顶点何不用acet-geom-vertex-list 函数, 更简洁!

eachy

最初由 lsjjm 发布
[B]获取多义线顶点何不用acet-geom-vertex-list 函数, 更简洁! [/B]

对 acet 的函数还不是很熟悉，记住了，下次会用的。

LUCAS

查看ACETAUTO.LSP可猜出ACET函數的大約用法!