[求助]：有没有计算多个直线长度的工具

lhj743

我以前在这里申请过，忘了哪位好心朋友帮忙的了。
反正曲线、复合线都可以用，拿来大家共享！

jxcjep_ydm

当前层线段求和：输入命令后点选线段不行，不适应太多线段和线段长度相差太大的情况（因为不好选）。有先筛选出线段然后输入命令求和的程序吗？

2006的打印纸张横向设置灵活性太差，用页面里的操作太繁，有好办法吗？象2004的最好，用惯了！


能对圆、圆弧、线段的长度求和的程序:
注意：圆、圆弧、线段的长度一起求和
      对其他对象无效
使用方法：
加载Sum_line.lsp
（也可以把Sum_line.lsp加入启动组）
运行abk
提示选对象：可以点选、框选
确定：显示X个对象及长度和
缺点：不能先选对象后命令
（附上传程序）

activeman

让我 try

kill99

谢谢，我正需要这个程序

abbs0511visa

谢谢！
试验一下，楼主太好了！

zml84

只要有长度就可以提取
[PHP]
;;功能：练习 获取对象长度信息
(vl-load-com)
(defun C:TT (/ SS SUM I OBJ TMP LEN)
    (princ "\n请选择对象...")
    (if (setq SS (ssget))
(progn
     ;;初始化
     (setq SUM 0
   I 0
     )
     ;;逐个对象进行量取
     (repeat (sslength SS)
(setq OBJ (vlax-ename->vla-object (ssname SS I)))
(if (setq TMP (vlax-curve-getendparam OBJ))
     (setq LEN (vlax-curve-getdistatparam OBJ TMP)
   SUM (+ SUM LEN)
     )
     (princ (strcat "\n第" (itoa (1+ I)) "个对象被舍弃。")
     )
)
(setq I (1+ I))
     )
     ;;显示结果
     (if (= SUM 0)
(princ "\n没有量取到长度。")
(alert
     (princ (strcat "所选实体的总长度为：" (rtos SUM 2 3))
     )
)
     )
)
    )
    (princ)
)
;|;;
后记：上面代码的精髓在于：
     (setq LEN (vlax-curve-getdistatparam OBJ (vlax-curve-getendparam OBJ)))
     请与下句对比便知：
     (setq LEN vla-get-Length OBJ)
;;|;[/PHP]
http://www.acad.net.cn/viewthread.php?tid=468&extra=page%3D1

love028

通过两端点求出长度，再相加

leidiang

太通用了未必是好事

weidongwm

阳光算量2.5.0

sosilitoo

(defun C:LV (/ CURVE TLEN SS N SUMLEN)
(vl-load-com)
(setq SUMLEN 0)
(setq SS (ssget '((0 . "CIRCLE,ELLIPSE,LINE,*POLYLINE,SPLINE,ARC"))))
(setq N 0)
(setq TLENMAX 0)
(setq TLENMIN 1000000000000)
(repeat (sslength SS)
(setq CURVE (vlax-ename->vla-object (ssname SS N)))
(setq TLEN (vlax-curve-getdistatparam
CURVE
(vlax-curve-getendparam CURVE)
)
)
(PRINC (strcat "\n长度: " (rtos tlen 2 3)))
(setq SUMLEN (+ SUMLEN TLEN))
(IF (< TLENMAX TLEN)
       (setq TLENMAX TLEN)
)
(IF (> TLENMIN TLEN)
       (setq TLENMIN TLEN)
)
(setq N (1+ N))
(setq PINJUN (/ SUMLEN N))
)
(PRINC (strcat "\n "))
(PRINC (strcat "\n          总段数: " (rtos N 2 0)))
(PRINC (strcat "\n         MAX长度: " (rtos TLENMAX 2 3)))
(PRINC (strcat "\n         MIN长度: " (rtos TLENMIN 2 3)))
(PRINC (strcat "\n "))
(PRINC (strcat "\n          总长度: " (rtos SUMLEN 2 3)))
(PRINC (strcat "\n          平均长: " (rtos PINJUN 2 3)))
(princ)
)

计算结果

长度: 194.266
长度: 117.763
长度: 93.492
长度: 141.477
长度: 110.827

          总段数: 5
         MAX长度: 194.266
         MIN长度: 93.492

          总长度: 657.824
          平均长: 131.565

清谷

好用！，顶

ljttjl

http://ljttjl.ys168.com  20081130目录下载  分类统计线长程序

qxy2007

是个好东东