[求助]：还没有解决的问题——急

xqyll

Dim ss As IAcadSelectionSet
   Dim FilterType(0) As Integer
   Dim FilterData(0) As Variant
   Dim pt As IAcadPoint
   Dim Ent As Object

   
   Set selObj = acadApp.ActiveDocument.SelectionSets.Add("tkk")
   FilterType(0) = 8
   FilterData(0) = "tk"
   selObj.select acSelectionSetAll, , , FilterType, FilterData
   

For Each Ent In selObj
MsgBox PT.Coordinates(0) & "," & PT.Coordinates(1) & "," & PT.Coordinates(2)

Next Ent

这是我想编写的一个捕获TK层里面所以的POINT的坐标的程序，却不知每次运行到PT.Coordinates(0) 处便会提示编译错误——错误的参数号或无效的属性赋值，不知怎么解决，谢谢各位大哥指点！*-*6

雪山飞狐(lzh)

Dim FilterType(1) As Integer, FilterData(1)
FilterType(0) = 0
FilterData(0) = "Point"
FilterType(1) = 8
FilterData(1) = "tk"
你的层里还有其他的对象，如直线，而它是没有Coordinates属性的

自由的鱼

Sub tt1()


Dim ss As IAcadSelectionSet
Dim FilterType(0) As Integer
Dim FilterData(0) As Variant
Dim pt As IAcadPoint
Dim Ent As Object
Dim selobj As AcadSelectionSet
Dim pnt As Variant

Set selobj = ThisDrawing.SelectionSets.Add("tdk12k")
FilterType(0) = 8
FilterData(0) = "tk"
selobj.Select acSelectionSetAll, , , FilterType, FilterData


For Each Ent In selobj
pnt = Ent.Coordinates
MsgBox pnt(0) & "," & pnt(1) & "," & pnt(2)

Next Ent

End Sub

xqyll

大哥，不行啊，每次运行到pnt = Ent.Coordinates处便提示要求对象，不知如何解决！谢谢了！

雪山飞狐(lzh)

二楼的回帖你为什么不看呢？

xqyll

大哥，你总得告诉我解决的办法啊！谢谢！

雪山飞狐(lzh)

Sub Test()

    Dim ss As AcadSelectionSet
    Dim ft(1) As Integer, fd(1) As Variant
    Dim i As AcadPoint
    Dim pnt As Variant
   
    ft(0) = 0: fd(0) = "Point"
    ft(1) = 8: fd(1) = "tk"
    Set ss = ThisDrawing.ActiveSelectionSet
    ss.Clear
    ss.Select acSelectionSetAll, , , ft, fd
   
    For Each i In ss
        pnt = i.Coordinates
        MsgBox pnt(0) & "," & pnt(1) & "," & pnt(2)
    Next i
   
End Sub
你要捕获TK层里面所以的POINT的坐标，必须设置有两个条件的过滤器

xqyll

谢谢这位大哥，我已经运行通过了，你真厉害！

雪山飞狐(lzh)

本来想引导你自己作出来的（我觉得自己作出来印象深），而且像这样的例子帮助里也有，帮助是最好的参考呀

xqyll

说得也是，只是我初学，急着把结果运行出来，以后就会自己慢慢来啦，另外想问这样读的坐标是该点本身的坐标，但是如果坐标系旋转后，再用"USC“命令”V“把图形设置为水平，用ID_POINT读取的坐标和刚才那个程序读取的坐标就不一致，不知是怎么回事！谢谢了！

雪山飞狐(lzh)

AutoCAD® ActiveX Automation 中的所有坐标都是在世界坐标系输入的，和UCS的相对坐标当然不同

xqyll

那能根据世界坐标求得那个相对坐标吗？

雪山飞狐(lzh)

帮助里的例子：
下面的子例程将创建新的 UCS，并将其设置为图形的活动 UCS。然后要求用户在图形中拾取一点，并返回该点的 WCS 和 UCS 坐标。

Sub Ch8_NewUCS()

    ' 定义所需的变量

    Dim ucsObj As AcadUCS

    Dim origin(0 To 2) As Double

    Dim xAxisPnt(0 To 2) As Double

    Dim yAxisPnt(0 To 2) As Double

    ' 定义 UCS 点

    origin(0) = 4:origin(1) = 5:origin(2) = 3

    xAxisPnt(0) = 5:xAxisPnt(1) = 5:xAxisPnt(2) = 3

    yAxisPnt(0) = 4:yAxisPnt(1) = 6:yAxisPnt(2) = 3

   

    ' 将 UCS 添加到

    ' UserCoordinatesSystems 集合

    Set ucsObj = ThisDrawing.UserCoordinateSystems. _

             Add(origin, xAxisPnt, yAxisPnt, "New_UCS")

    ' 显示 UCS 图标

    ThisDrawing.ActiveViewport.UCSIconAtOrigin = True

    ThisDrawing.ActiveViewport.UCSIconOn = True

   

    ' 使新的 UCS 成为活动的 UCS

    ThisDrawing.ActiveUCS = ucsObj

    MsgBox "The current UCS is :" & ThisDrawing.ActiveUCS.Name _

            & vbCrLf & " Pick a point in the drawing."

        

    ' 找出某一点的 WCS 和 UCS 坐标

    Dim WCSPnt As Variant

    Dim UCSPnt As Variant

   

    WCSPnt = ThisDrawing.Utility.GetPoint(, "Enter a point: ")

    UCSPnt = ThisDrawing.Utility.TranslateCoordinates _

             (WCSPnt, acWorld, acUCS, False)

   

    MsgBox "The WCS coordinates are:" & WCSPnt(0) & ", " _

             & WCSPnt(1) & ", " & WCSPnt(2) & vbCrLf & _

             "The UCS coordinates are:" & UCSPnt(0) & ", " _

             & UCSPnt(1) & ", " & UCSPnt(2)

End Sub

xqyll

那不知VBA能否求得和CAD的内部命令ID_POINT求得的坐标一致的算法呢！谢谢了

雪山飞狐(lzh)

上面的了例子就是这样的，在VBA里获取的点用Utility.TranslateCoordinates 函数返回在UCS中的坐标