[求助]：如何取与某多义线有交点的线

zj-11

请教一个问题, 我想取与某方形多义线有交点的线, 取出线点表plst 用 (setq ss2 (ssget "cp" plst )),发现取到的线和它没有交点,请问原因?
或有其它办法取与某多义线有交点的线吗

陌生人

是虚线？

zj-11

lwpolyline 并非虚线

aidraft

;;此程序适用于不同形状的边界，还可得到交点值。
;;仅作参考，实际上按你的要求可能不用这么复杂。
(defun C:TT  (/ plineobj ss ss_found idx en en1)
  (vl-load-com)
  (setq        plineObj (vlax-ename->vla-object
                   (setq en (car (entsel "\n选择多义线: ")))))
  ;;可以选择任何图元(除Pviewport和PolygonMesh外)
  (setq ss (ssget "x" '((0 . "*LINE"))))
  ;;实际上可以任何图元
  (setq        ss_found (ssadd)
        idx         -1)
  (if ss
    (progn
      (repeat (sslength ss)
        (setq en1 (ssname ss (setq idx (1+ idx))))
        (if (and (VxGetInters
                   plineObj
                   (vlax-ename->vla-object en1)
                   acExtendNone)
                 (not (eq en en1)))
          (setq ss_found (ssadd en1 ss_found)))
        )
      (princ (strcat "\n找到 "
                     (itoa (sslength ss_found))
                     " 个相交图元。"))
      (SS_hilite ss_found 3)
      )
    (princ "\n没有找到相交图元.")
    )
  (princ)
  )
; From MENZI ENGINEERING GmbH, Switzerland
(defun VxGetInters  (Fst Nxt Mde / IntLst PntLst)
  (setq IntLst (vlax-invoke Fst "IntersectWith" Nxt Mde))
  (cond
    (IntLst
     (repeat (/ (length IntLst) 3)
       (setq PntLst (cons
                      (list
                        (car IntLst)
                        (cadr IntLst)
                        (caddr IntLst)
                        )
                      PntLst
                      )
             IntLst (cdddr IntLst)
             )
       )
     (reverse PntLst)
     )
    (T nil)
    )
  )
;; From GeoTool
(defun SS_hilite  (ss mode / ssl cnt)
  (if ss
    (progn
      (setq
        ssl (sslength ss)
        cnt 0
        )
      (repeat ssl
        (redraw (ssname ss cnt) mode)
        (setq cnt (1+ cnt))
        )
      ))
  )

lijiao

(SSGET "F" PLST)

shisj

谢谢aidraft ，我从你这里学到了知识