[求助]：在CAD2002以上版本中的问题

lzy9788

请教各位，在CAD2002以上版本中双击鼠标能实现文字、属性块等的修改，我怎么样让双击鼠标来弹出我自己编的修改文字的对话框。
可以修改吗？？？

aidraft

仅供参考

[PHP]
;;来源：INTERNET
;;作者：ZOLTAN
;;
;;适用于mtext
(Command "_.UNDEFINE" "MTEDIT" )

(Defun C:MTEDIT ( / enPick )
(If (Cadr (SSGetFirst)) ;is MText already selected
  (SetQ enPick (SSName (SSGet ":S") 0) ) ;user double-clicked
  (SetQ enPick (Car (EntSel "\nSelect an MTEXT object: ")) ) ;user started MTEDIT command
)

(If enPick
  (If (And (= (Cdr (Assoc 0 (EntGet enPick))) "MTEXT") ;validate my object
           (GetXData enPick "QuickBag_Note")
      )
   (QB_EditNote enPick ) ;my own editor
   (MTEDIT enPick ) ;normal MTEXT editor
  )
)

(TerPri )
(Prin1 )
)
;
;;适用于属性块
(Command "_.UNDEFINE" "EATTEDIT" )

(Defun C:EATTEDIT ( / enPick bLoop )
(SetQ bLoop T )
(While bLoop
  (If (SetQ enPick (Car (EntSel "\nSelect a Block: ")) )
   (If (= (Cdr (Assoc 0 (EntGet enPick))) "INSERT") ;validate that object is a block
    (If (= (Cdr (Assoc 66 (EntGet enPick))) 1) ;validate that the block has attributes
     (ProgN
      (If (GetXData enPick "QuickBag_KeyNote") ;validate that the block is mine.
       (QB_EditKeyNote enPick ) ;my own editor
       (Command ".ACAD_EAttedit.EATTEDIT" enPick ) ;normal EATTEDIT editor
      )
      (SetQ bLoop nil) ;get out of the loop
     )
     (PrinC "\nThe selected block has no editable attributes." )
    )
   )
   (PrinC "\nError selecting entity." )
  )
)

(TerPri )
(Prin1 )
)
;
;;一般图元对象
(Command "_.UNDEFINE" "PROPERTIES" )

(Defun C:PROPERTIES ( / psPick enPick )
(If (SetQ psPick (Cadr (SSGetFirst))) ;is object already selected
  (ProgN
   (SetQ enPick (SSName psPick 0) )
   (If (GetXData enPick "QuickBag") ;validate my object
    (QB_Edit enPick ) ;my own editor
    (Command ".ACAD_OPM.PROPERTIES" ) ;open properties window
   )
  )
  (Command ".ACAD_OPM.PROPERTIES" ) ;user started PROPERTIES command
)

(TerPri )
(Prin1 )
)
[/PHP]