[求助]：修改插入图块的命令。(完成)

梦断江南 · 发表于 2004-10-15 11:54:23

给你来个加强版的

;| c:sbi = 用设置的比例插入块-----------------------------ok!---梦断江南.2004.10
;功能: 1.可设置全局比例(按"*"号).
2.显示当前全局比例.
3.按全局比例插入图块,保持动态.只需定义插入点和转角.
4.当输入文件名有误,可调用对话框选取要插入的dwg图形.
|;
(defun c:sbi (/ *x *y *z k)
(if (not *blksc)(setq *blksc '(1 1 1)))
(prnblksc *blksc)
(setq k (getstring "\n输入块名/ * 设置 /<退出> :"))
(cond
((= "*" k) ;;设置参数.
(setq *blksc (mapcar
'(lambda(a b c)
(if (progn (mapcar 'princ (list"\n输入块插入比例" c "<" (eval b)))
(set a (getdist ">:"))
)
(eval a)
(eval b)
)
)
(list 'x 'y 'z)
(list '*x '*y '*z)
(list "X=" "Y=" "Z=")
)
)
(c:sbi);;自身调用.
)
((/= "" K)
(if (findfile (strcat k ".dwg"))
(vl-cmdf ".insert" k "x" *x "y" *y "z" *z)
(progn (princ (strcat "\n !没有找到块文件 " k))
(initget "X ")
(setq k (getkword "\nX-退出/<从列表选择文件>:"))
(cond
((not k)(setq k (getfiled "" "" "dwg;dxf" 4))
(vl-cmdf ".insert" k "x" *x "y" *y "z" *z))
(T nil)
)
)
)
)
(T nil)
)(princ)
)
;;
(defun prnblksc (*blksc)
(setq *x (car *blksc) *y (cadr *blksc) *z (caddr *blksc))
(mapcar 'princ (list "\n当前块插入比例设置:" " X=" *x " Y=" *y " Z=" *z))
(princ)
)

;| c:sbi = 用设置的比例插入块-----------------------------ok!---梦断江南.2004.10 
;功能:     1.可设置全局比例(按"*"号). 
           2.显示当前全局比例. 
           3.按全局比例插入图块,保持动态.只需定义插入点和转角. 
           4.当输入文件名有误,可调用对话框选取要插入的dwg图形. 
|; 
(defun c:sbi (/ *x *y *z k) 
  (if (not *blksc)(setq *blksc '(1 1 1))) 
  (prnblksc *blksc) 
  (setq k (getstring "\n输入块名/ * 设置 /<退出> :")) 
  (cond 
    ((= "*" k) ;;设置参数. 
       (setq *blksc (mapcar 
                      '(lambda(a b c) 
                         (if (progn (mapcar 'princ (list"\n输入块插入比例"  c "<" (eval b))) 
                                    (set a (getdist ">:")) 
                             ) 
                             (eval a) 
                             (eval b) 
                         ) 
                       ) 
                      (list 'x 'y 'z) 
                      (list '*x '*y '*z) 
                      (list "X=" "Y=" "Z=") 
                    ) 
        ) 
       (c:sbi);;自身调用. 
    ) 
    ((/= "" K) 
       (if (findfile (strcat k ".dwg")) 
           (vl-cmdf ".insert" k "x" *x "y" *y "z" *z) 
           (progn (princ (strcat "\n !没有找到块文件 " k)) 
             (initget "X  ") 
             (setq k (getkword "\nX-退出/<从列表选择文件>:")) 
             (cond 
               ((not k)(setq k (getfiled "" "" "dwg;dxf" 4)) 
                (vl-cmdf ".insert" k "x" *x "y" *y "z" *z)) 
               (T nil) 
             ) 
           ) 
        ) 
    ) 
    (T nil) 
  )(princ) 
) 
;; 
(defun prnblksc (*blksc) 
  (setq *x (car *blksc) *y (cadr *blksc) *z (caddr *blksc)) 
  (mapcar 'princ (list "\n当前块插入比例设置:" " X=" *x "  Y=" *y "  Z=" *z)) 
  (princ) 
)

海豚 · 发表于 2004-10-15 15:03:49

我们已经正是用这个命令替换INSERT命令了，谢谢楼上各位。
版主，还有一个小问题看能否优化，一般改变比例，在输入X比例后，Y和Z比例都是按X多的，是否可以缺省回车就按X的比例，如果不同才要输入。当然，有了这个命令后，要改变得情况并不多，所以并不影响大局。
再次谢谢各位的热心帮助。

梦断江南 · 发表于 2004-10-15 18:20:56

可以,我上面的程序是用上一次的默认值.
可以改,但是现在手上有点事情,晚上吧.

算了,也快.

;| c:sbi = 用设置的比例插入块(xyz等比版本)-----------------------------ok!---梦断江南.2004.10
本程序专为插入xyz等比块制作.
|;
(defun c:sbi (/ a k)
(if (not *blksc)(setq *blksc 1))
(mapcar 'princ (list "\n当前插入块比例 X = " *blksc))
(setq k (getstring "\n输入块名/ * 设置 /<退出> :"))
(cond
((= "*" k) ;;设置参数.
(setq *blksc (if (progn (mapcar 'princ (list"\n输入块插入比例 X= <" *blksc))
(setq a (getdist ">:"))
)
a
*blksc
)
)
(c:sbi);;自身调用.
)
((/= "" K)
(if (findfile (strcat k ".dwg"))
(vl-cmdf ".insert" k "x" *blksc "y" *blksc "z" *blksc)
(progn (princ (strcat "\n !没有找到块文件 " k))
(initget "X ")
(setq k (getkword "\nX-退出/<从列表选择文件>:"))
(cond
((not k)(setq k (getfiled "" "" "dwg;dxf" 4))
(vl-cmdf ".insert" k "x" *blksc "y" *blksc "z" *blksc))
(T nil)
)
)
)
)
(T nil)
)(princ)
)
;;
(princ "c:sbi 用设置的比例插入块(xyz等比版本)-by-梦断江南.2004.10")
(princ "欢迎到xdcad论坛: [url]http://www.xdcad.net/forum/[/url]")(princ)

;| c:sbi = 用设置的比例插入块(xyz等比版本)-----------------------------ok!---梦断江南.2004.10 
本程序专为插入xyz等比块制作. 
|; 
(defun c:sbi (/ a k) 
  (if (not *blksc)(setq *blksc 1)) 
  (mapcar 'princ (list "\n当前插入块比例 X = " *blksc)) 
  (setq k (getstring "\n输入块名/ * 设置 /<退出> :")) 
  (cond 
    ((= "*" k) ;;设置参数. 
       (setq *blksc  (if (progn (mapcar 'princ (list"\n输入块插入比例 X= <" *blksc)) 
                                (setq a (getdist ">:")) 
                         ) 
                         a 
                         *blksc 
                     ) 
        ) 
       (c:sbi);;自身调用. 
    ) 
    ((/= "" K) 
       (if (findfile (strcat k ".dwg")) 
           (vl-cmdf ".insert" k "x" *blksc "y" *blksc "z" *blksc) 
           (progn (princ (strcat "\n !没有找到块文件 " k)) 
             (initget "X  ") 
             (setq k (getkword "\nX-退出/<从列表选择文件>:")) 
             (cond 
               ((not k)(setq k (getfiled "" "" "dwg;dxf" 4)) 
                (vl-cmdf ".insert" k "x" *blksc "y" *blksc "z" *blksc)) 
               (T nil) 
             ) 
           ) 
        ) 
    ) 
    (T nil) 
  )(princ) 
) 
;; 
(princ "c:sbi 用设置的比例插入块(xyz等比版本)-by-梦断江南.2004.10") 
(princ "欢迎到xdcad论坛: [url]http://www.xdcad.net/forum/[/url]")(princ)

xyp1964 · 发表于 2004-10-15 22:56:50

最初由 aidraft 发布
[B];;;xyp1964, 对不起，没经你同意便改了你的程序。。。
;;;注：程序还没有完善，不要问捕捉了。
(defun c:bbb (/ pt1)
  (if (= no1 nil)
(setq no1 1)
)
  (princ "\n\t当前图块比例为")
  (princ no... [/B]

只要好用对谁都是一件有益的事！学习！

海豚 · 发表于 2004-10-16 12:07:45

版主，还忘了一个问题，这个程序不象INSERT，图块名每次都要重新输入，不太方便，因为连续插入同一个名字的图快机会是很多的，如果都要输入，还是不方便。
希望如果第一次使用该命令，则必须输入块名，如果接下来再插入图块，回车则按上一次，输入则按新图块名。

梦断江南 · 发表于 2004-10-16 17:52:17

试试

海豚 · 发表于 2004-10-17 12:05:39

最初由梦断江南发布
[B]试试 [/B]

不行啊
另外，我一般把命令设到左手，所以希望能预留用PGP文件，把命令设为SR。谢谢

ll_j · 发表于 2004-10-17 13:59:22

最初由海豚发布
[B]
不行啊
另外，我一般把命令设到左手，所以希望能预留用PGP文件，把命令设为SR。谢谢 [/B]

不知算不算“大马虎”，程序是sbi，命令也是sbi，你执行sdi，还说程序不行？

海豚 · 发表于 2004-10-17 15:22:55

对，是大马虎，对不起，刚好也有SDI的命令，太巧了。
但是还是不行，开图运行第一次，你输入任何图块名，他都会自己退出。运行第二次时，它还是插入上一次的图块，也就是说，必须再运行一次，才能正确插入想要的程序。
另外版主能否不编译程序，因为我想把命令由SBI改为SR，所以在ACAD.PGP里加了一行SR, *SBI，结果在命令行输入SR，就会出现
Initializing...
Initializing...
Initializing...Function cancelled
直到按CANCEL键。

梦断江南 · 发表于 2004-10-17 17:13:39

调了一下,应该可以了.
你要自己定义命令可以这样:
(defun c:sr () (c:sbi))
这个和sbi.fas同时加载就可以了

[swf w=750 h=600]http://www.xdcad.net/article/upload/file/291_20041017173923_sbi=插入设置默认比例的块.swf [/swf]

Free-Lancer · 发表于 2004-10-18 11:16:26

;;增强插入图块
(defun c:Fins (/ myerr olderr myinsert p tf)
(defun myerr (msg)
(if (= (type msg) 'STR)
(princ "\n*取消*")
)
(command ".undo" "e")
(princ)
)
(defun myinsert (lastent / e el)
(initdia)
(vl-cmdf ".ddinsert")
(while (/= (getvar "cmdnames") "") (command pause))
(if (and (setq e (entlast))
(not (equal e lastent))
)
(setq el (entget e)
*myinsert*
(cdr (assoc 2 el))
*xscalefactor*
(cdr (assoc 41 el))
*yscalefactor*
(cdr (assoc 42 el))
*zscalefactor*
(cdr (assoc 43 el))
)
)
)
(setvar "cmdecho" 0)
(setq olderr *error*
*error* myerr
)
(command ".undo" "be")
(setq tf t)
(while tf
(if (or (= (getvar "insname") "")
(not *myinsert*)
(not *xscalefactor*)
(not *yscalefactor*)
(not *zscalefactor*)
)
(myinsert (entlast))
(progn
(princ (strcat "\n当前块["
*myinsert*
"], X比例: "
(vl-princ-to-string *xscalefactor*)
", Y比例: "
(vl-princ-to-string *yscalefactor*)
", Z比例: "
(vl-princ-to-string *zscalefactor*)
)
)
(initget 6 "S")
(setq p (getpoint "\n插入点[S - 设置]<回车退出>: "))
(cond
((= (type p) 'LIST)
(vl-cmdf ".insert" *myinsert* p
"XYZ" *xscalefactor* *yscalefactor*
*zscalefactor* pause
)
)
((= p "S")
(myinsert (entlast))
)
(t (setq tf nil))
)
)
)
)
(command ".undo" "e")
(setq *error* olderr
myerr nil
)
(princ)
)

;;增强插入图块 
(defun c:Fins (/ myerr olderr myinsert p tf) 
  (defun myerr (msg) 
    (if        (= (type msg) 'STR) 
      (princ "\n*取消*") 
    ) 
    (command ".undo" "e") 
    (princ) 
  ) 
  (defun myinsert (lastent / e el) 
    (initdia) 
    (vl-cmdf ".ddinsert") 
    (while (/= (getvar "cmdnames") "") (command pause)) 
    (if        (and (setq e (entlast)) 
             (not (equal e lastent)) 
        ) 
      (setq el (entget e) 
            *myinsert* 
             (cdr (assoc 2 el)) 
            *xscalefactor* 
             (cdr (assoc 41 el)) 
            *yscalefactor* 
             (cdr (assoc 42 el)) 
            *zscalefactor* 
             (cdr (assoc 43 el)) 
      ) 
    ) 
  ) 
  (setvar "cmdecho" 0) 
  (setq        olderr        *error* 
        *error*        myerr 
  ) 
  (command ".undo" "be") 
  (setq tf t) 
  (while tf 
    (if        (or (= (getvar "insname") "") 
            (not *myinsert*) 
            (not *xscalefactor*) 
            (not *yscalefactor*) 
            (not *zscalefactor*) 
        ) 
      (myinsert (entlast)) 
      (progn 
        (princ (strcat "\n当前块[" 
                       *myinsert* 
                       "], X比例: " 
                       (vl-princ-to-string *xscalefactor*) 
                       ", Y比例: " 
                       (vl-princ-to-string *yscalefactor*) 
                       ", Z比例: " 
                       (vl-princ-to-string *zscalefactor*) 
               ) 
        ) 
        (initget 6 "S") 
        (setq p (getpoint "\n插入点[S - 设置]<回车退出>: ")) 
        (cond 
          ((= (type p) 'LIST) 
           (vl-cmdf ".insert"            *myinsert*            p 
                    "XYZ"            *xscalefactor*  *yscalefactor* 
                    *zscalefactor*  pause 
                   ) 
          ) 
          ((= p "S") 
           (myinsert (entlast)) 
          ) 
          (t (setq tf nil)) 
        ) 
      ) 
    ) 
  ) 
  (command ".undo" "e") 
  (setq        *error*        olderr 
        myerr        nil 
  ) 
  (princ) 
)

hmh888888 · 发表于 2004-11-19 16:51:52

建议可以设定角度默认值，并且有26楼的连续插入功能

bluesky1000 · 发表于 2004-11-19 17:19:15

那个增强插入图块的程序不错。

账号		自动登录	找回密码
密码			立即注册

[求助] [求助]：修改插入图块的命令。(完成)

浏览过的版块