[求助]：怎样实现使用ssget 选择后不用用户确定

zuqiang

怎样实现使用ssget 选择后不用用户确定？就象特性匹配命令一样，选择完后就执行程序，并连续选择？
请指教。

它山之石

1、用ENTSEL。
2、用（SSGET　“X”）
3、用（SSGET　“W”（点表）“”）；关键是在最后加“”自动结束[选择对象]提示

hi71400

1楼的意思不会会是只想要ssget每回只选一次?

ll_j

R2000以后的版本才开始支持这种功能：
(ssget ":S")

不过这仍然不能模拟特性匹配的选择方式，就是“支持关键字的选择集”。

狂刀

比特性匹配方式多一个undo功能。
即兴写成，不求完美，仅提供一个思路
[php]
;; by 狂刀@xdcad 2005.2.3
;;已知1要执行的函数 do , 2 过滤条件 fil
;; (tt 'mychc '((0 . "*LINE")))
;(setq do 'mychc fil '((0 . "*LINE")))
(defun tt (do fil / pt col)
  (setq *doc (vla-get-activedocument (vlax-get-acad-object))
         col (getint "\n线条颜色改为<随层>:"))
  (if (not col)(setq col 256))
  (while (or (initget "Undo")(setq pt (getpoint "\n选实体/U-回退/<退出>")) )
    (cond
      ((and (= 'STR (type pt)) (= "Undo" pt))
       (vl-cmdf ".u")
      )
      ((setq ss (ssget "c" pt pt fil))
       (vla-startundomark *doc)
       ((eval do) ss col)
       (vla-endundomark *doc)
      )
      ((setq ss (ssget "c" pt (getcorner pt) fil))
       (vla-startundomark *doc)
       ((eval do) ss col)
       (vla-endundomark *doc)
      )
      (T nil)
    )
  )
)
;;改变选集颜色.
;; ss 选集 col 颜色.
(defun mychc (ss col / n e ent)
  (setq n (sslength ss))
  (while (setq e (ssname ss (setq n (1- n))))
    (setq ent (entget e))
    (vla-put-color (vlax-ename->vla-object e) col)
  )
)
[/php]