[求助]：帮我看看：经过修改的文本输出程序总是显示有“错误: 参数类型错误: lentityp

xxming

(DEFUN C:TEXT-OUT() (SETQ GOP (SSGET '((0 . "TEXT" ))))
                    (setq file_id (getfiled "\n选择文件" "c:/" "txt" 1))  
                    (SETQ FILE_D (OPEN file_id "W"))
                    (SETQ I 0)
                    (while (<= I (SSLENGTH GOP))
                      (SETQ ENT (SSNAME GOP I))
                      (SETQ ENT1 (ENTGET ENT))
                      (IF (/= (CDR(ASSOC 0 ENT1)) "TEXT")
                        (PRINC "\N选择的不是文字")
                        (write-line (cdr(assoc 1 ent1)) file_d))
                    (SETQ I (+ 1 I)))
                    (close file_d)
(princ))
(prompt "\n文本输出程序,键入:text-out执行程序.-----程序设计:小谢")
(princ)

xyp1964

程序中有多余的判断，如：(IF (/= (CDR(ASSOC 0 ENT1)) "TEXT")，……
最好能按文本对齐点的Y坐标顺序输出。
[php]
(DEFUN C:test (/ ss file_id FILE_tx i s1 tx)
  (SETQ        file_id        (getfiled "\n选择文件" "c:/" "txt" 1)
        ss        (SSGET '((0 . "TEXT")))
        FILE_tx        (OPEN file_id "W")
        I        -1
  )
  (while (setq s1 (ssname ss (setq i (1+ i))))
    (setq tx (cdr (ASSOC 1 (entget s1))))
    (write-line tx file_tx)
  )
  (close file_tx)
  (princ)
)
[/php]

xxming

2楼楼主你能帮我解释这是什么意思吗：

程序中有多余的判断，如：(IF (/= (CDR(ASSOC 0 ENT1)) "TEXT")，……
最好能按文本对齐点的Y坐标顺序输出

xyp1964

利用(SETQ GOP (SSGET '((0 . "TEXT" ))))已经将非text图元过滤掉。
[php]
(DEFUN C:TEXT-OUT ()
;;;(SETQ GOP (SSGET '((0 . "TEXT"))));此句向下移动到输出文件之后更人性化
  (setq        file_id        (getfiled "\n选择文件" "c:/" "txt" 1)
        GOP        (SSGET '((0 . "TEXT")))
        FILE_D        (OPEN file_id "W")
        I        0
  )
;;;(while (<= I (SSLENGTH GOP))
;;;此处应该使用 “<” 而不是“<=”，出错的原因就在于此！
;;;I 不能等于 (SSLENGTH GOP) !!!
  (while (< I (SSLENGTH GOP))
    (SETQ                                ;ENT  (SSNAME GOP I)
                                        ;ENT1 (ENTGET ENT)
      ENT1 (ENTGET (SSNAME GOP I))
    )
;;;(IF        (/= (CDR (ASSOC 0 ENT1)) "TEXT");此句无用
;;;(PRINC "\N选择的不是文字");此句无用
    (write-line (cdr (assoc 1 ent1)) file_d)
;;;);此句无用
    (SETQ I (1+ I))
  )
  (close file_d)
  (princ)
)
(prompt "\n文本输出程序,键入:text-out执行程序.-----程序设计:小谢")
(princ)
[/php]

xxming

;;;);此句无用
    (SETQ I (1+ I))
  )
  这句应保留不然会死循环

xyp1964

;;;);此句无用
指的是右括号！