[求助]：批处理数据！！！

danik

批处理数据！！！
就是说我平面图的标高要同时要增加同一个值，有没有不用一个一个改的方法！（我的标高都不一样）

lt_zzy

[PHP](defun c:add33()
  (setvar "cmdecho"0)
  (command "undo" "group")
  (princ"\n请选择被加数:")
  (setq c1 (single_select  '((0 . "TEXT")) T))
  (if c1
     (redraw c1 3)
  )
  (setq c11 (entget c1))              ;;;返回实体关联表
  (setq result (cdr (assoc 1 c11)))
  (setq result (atof result))               ;;;将文本转化为数字  
  (princ"\n请选择加数:")
  (setq a (ssget '((0 . "TEXT"))))
  (setq na (sslength a))
  (setvar "dimzin" 0)
  (setq number 0)
  (repeat na
    (setq a1 (ssname a number))         ;;;取得选择集中的第number个实体
    (setq a11 (entget a1))              ;;;返回实体关联表
    (setq number1 a11)
    (setq a11 (cdr (assoc 1 a11)))      ;;;返回一个数字的生态名称
    (setq a11 (atof a11))               ;;;将文本转化为数字
    (setq a11 (+ a11 result))        ;;;计算两数之积
    (setq a11 (rtos a11 2 3))     ;;;将计算结果转化为字符串
    (setq a11 (cons 1 a11))       ;;;组成关联表的表项
    (setq a11 (subst a11 (assoc 1 number1) number1));用新表项替换旧表项
    (entmod a11)                     ;实体更新
    (setq number (1+ number))
  )
  (redraw c1 4)
  (command "undo" "end")
  (setvar"cmdecho"1)
  (princ)
)[/PHP]

lt_zzy

[PHP](defun single_select ( flt flag / a p1 p2 ss ss2 flag2)

(while (not flag2)
(setvar "highlight" 0)
(if (entnext)
    (progn
     (command "_.select" (entnext) "")
     (command "_.undo" "1");clear any selection sets
    );progn then
);if
(setvar "highlight" 1)
(command "_.select" "_si")
(setvar "cmdecho" 1)
(command pause)

(setq ss2 (ssget "p")
       p1 (getvar "lastpoint")
       p1 (trans p1 1 (getvar "viewdir"))
        a (* (getvar "pickbox") (pixel_unit))
       p2 (list (- (car p1) a) (- (cadr p1) a) 0.0)
       p1 (list (+ (car p1) a) (+ (cadr p1) a) 0.0)
       p1 (trans p1 (getvar "viewdir") 1)   
       p2 (trans p2 (getvar "viewdir") 1)   
);setq
(if (and ss2
         (or (setq ss (ssget "p" flt))
             (setq ss (ssget "c" p1 p2 flt))   
         );or
    );and
    (progn
     (setq ss (ssname ss 0))
     (if flag
         (setq flag2 T)
         (progn
          (if (b_layer_locked (cdr (assoc 8 (entget ss))))
              (progn
               (setq flag2 nil)
               (princ "\nThat object is on a locked layer!")
              );progn
              (setq flag2 T);else got something and its on an UN-locked layer
          );if
         );progn else locked layer selection is not allowed
     );if
    );progn
    (progn
     (if ss2
         (princ "\nInvalid selection.")
         (setq flag2 T);they just exited with enter
     );if
    );progn
);if
(setvar "cmdecho" 0)
);while
ss
);defun single_select
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;pixel_unit
;returns the size of a single pixel in drawing units.
;value depends on current zoom factor.
;
;pixunit/viewsize = one pixel/yscreensize
;
;pixunit=viewsize/yscreensize
;
(defun pixel_unit ( / x y x1 y1)
(setq  y (getvar "viewsize")
       x1 (car (getvar "screensize"))
       y1 (cadr (getvar "screensize"))
        x (* y (/ x1 y1))
);setq
(max (abs (/ y y1))
      (abs (/ x x1))
);max
);defun pixel_unit[/PHP]

danik

不是很明白，能解释解释吗？？