[求助]：有没有办法保存Area命令中的每段距离?

bolixin

要求结果为:???+????+????=????

xyp1964

[php]
;;;保存Area命令中的每段距离及最后值 <bolixin>
;;;结果为 : ???+????+????=????
(defun c:test ()
  (if (and (setq pt1 (getpoint "\n起点<退出> : "))
           (setq pt2 (getpoint pt1 "\n下一点<退出> : "))
      )
    (progn
      (setq dist (rtos (distance pt1 pt2) 2 3))
      (command "area" pt1)
      (while (setq pt2 (getpoint pt2 "\n下一点<退出> : "))
        (command pt2)
        (setq dist12 (distance pt1 pt2)
              pt1    pt2
              dist   (strcat dist "+" (rtos dist12 2 3))
        )
      )
    )
  )
  (command)
  (setq dist (strcat dist "=" (rtos (getvar "area") 2 3)))
  (princ dist)
  (princ)
)
[/php]
测试：

命令: test
起点<退出> :
下一点<退出> :
下一点<退出> :
下一点<退出> :
下一点<退出> :
下一点<退出> :
下一点<退出> :
下一点<退出> :
下一点<退出> :
下一点<退出> :  
422.712+645.313+451.243+466.441+482.463+347.603+337.903+417.802=106136.458

bolixin

xyp1964兄,谢谢!第二段距离的起点错了!能否修改?

xyp1964

[php]
(defun c:test (/ dist sm)
  (if (and (setq pt1 (getpoint "\n起点<退出> : "))
           (setq pt2 (getpoint pt1 "\n下一点<退出> : "))
      )
    (progn
      (setq dist  (distance pt1 pt2)
            distM dist
            dist  (rtos dist 2)
      )
      (command "area" pt1 pt2)
      (while (setq pt1 (getpoint pt2 "\n下一点<退出> : "))
        (command pt1)
        (setq dist12 (distance pt2 pt1)
              distM  (+ distM dist12)
              pt2    pt1
              dist   (strcat dist "+" (rtos dist12 2))
        )
      )
    )
  )
  (command)
  (setq dist (strcat "线长 : " dist "=" (rtos distM 2))
        sm (strcat "面积" " = " (rtos (getvar "area") 2))
        )
  (princ"\n")(princ dist)
  (princ"\n")(princ sm)
  (princ)
)
[/php]

bolixin

xyp1964兄,非常感谢你这么热心,!有时间联系我,如到深圳我请你吃饭.
lingzhixing168@126.com
QQ:375278076

onej

xyp1964 ,喜欢你的作风

PFD8667

xyp1964兄:
谢谢!是个实用的程序,但面积计算出来不对,不知为什么?

xyp1964

问题的关键：
(command )→ (command "")
[php]
(defun c:test (/ dist sm)
  (if (and (setq pt1 (getpoint "\n起点<退出> : "))
           (setq pt2 (getpoint pt1 "\n下一点<退出> : "))
      )
    (progn
      (setq dist  (distance pt1 pt2)
            distM dist
            dist  (rtos dist 2)
      )
      (command "area" pt1 pt2)
      (while (setq pt1 (getpoint pt2 "\n下一点<退出> : "))
        (command pt1)
        (setq dist12 (distance pt2 pt1)
              distM  (+ distM dist12)
              pt2    pt1
              dist   (strcat dist "+" (rtos dist12 2))
        )
      )
    )
  )
  (command "")
  (setq        aa   (getvar "area")
        sm   (strcat "面积" " = " (rtos aa 2))
        dist (strcat "线长 : " dist "=" (rtos distM 2))
  )
  (princ "\n")
  (princ dist)
  (princ "\n")
  (princ sm)
  (princ)
)
[/php]
测试：
Command: test
起点<退出> :
下一点<退出> :
下一点<退出> :
下一点<退出> :
下一点<退出> :
下一点<退出> :
线长 : 366.0177+126.2331+366.0177+126.2331=984.5017
面积 = 46203.5512

Command:  TEST
起点<退出> :
下一点<退出> :
下一点<退出> :
下一点<退出> :
下一点<退出> :
下一点<退出> :
线长 : 315.5827+409.5913+315.5827+409.5913=1450.348
面积 = 129259.9341