[求助]：想一想怎么编一个这样程序

xxming

member函数：搜索表中是否包含某表达式，并从该表达式的第一次出现处返回表的其余部分。
那么:搜索表中是否包含某表达式,并从该表达式的第一次出现处返回表的前面部分”程序该怎么编？

舟自横

很简单:
(DEFUN reversemember(ITEM yourlist / needlist);;if item in yourlist
   (setq yourlist (reverse yourlist))
   (setq needlist (member item yourlist));;如果你不想ITEM在其中则  
                             ;;(setq needlist (cdr(member item yourlist)))
   (setq needlist (reverse needlist))
  needlist
)

that's all!!!

zxq0220

最初由 舟自横 发布
[B]很简单:
(DEFUN reversemember(ITEM yourlist / needlist);;if item in yourlist
   (setq yourlist (reverse yourlist))
   (setq needlist (member item yourlist));;如果你不想ITEM在其中则  
              ... [/B]

若表中的ITEM有二个以上，就可能返回最后一个ITEM之前的表。

舟自横

那样的情况你可以想得到只可能是第一项会是重复的
你可以将上面程序返回的列表去掉第一个重复项,那样的
程序想大虾你自己也应该想得出来吧!
另给一个去掉列表中所有重复项功能的函数供参考:
(defun hy_erasedouble(nlist / needlist)
  (setq needlist nlist)
  (foreach item nlist (setq needlist (append (list item) (vl-remove item needlist)))
    )
  (reverse needlist))

xxming

ok,明白谢谢

狂刀

同意3楼,2楼程序不完善,例子
(1 2 3 4 3 5)
reverse = 5 3 4 3 2 1
member 3 = 3 4 3 2 1
reverse = 1 2 3 4 3
与要求的结果 1 2 有误
"你可以将上面程序返回的列表去掉第一个重复项,"
但是如果3不止是2个呢?比如
( 1 2 3 4 3 5 3 6 3 3 4 3 2)

试试我这个:
(defun tt (x lst / a )
(while (not (equal x (setq a (car lst))))
    (setq lst2 (cons a lst2)
            lst (cdr lst))
) (reverse lst2)
)

zxq0220

最初由 狂刀 发布
[B]同意3楼,2楼程序不完善,例子
(1 2 3 4 3 5)
reverse = 5 3 4 3 2 1
member 3 = 3 4 3 2 1
reverse = 1 2 3 4 3
与要求的结果 1 2 有误
"你可以将上面程序返回的列表去掉第一个重复项,"
但是如果3不止是2个呢?...但是如果3不止是2个呢?...
试试我这个:
(defun tt (x lst / a )
(while (not (equal x (setq a (car lst))))
(setq lst2 (cons a lst2)
lst (cdr lst))
) (reverse lst2)
)[/B]

但您的程序在表项不是数字或字符串时判断会出错！

狂刀

why？？？ 理由？

(defun tt (x lst / a lst2)
  (while (not (equal x (setq a (car lst))))
    (setq lst2 (cons a lst2)
          lst  (cdr lst)
    )
  )
  (reverse lst2)
)

;;测试
(tt '(2 3) '(1 "b" (2 3) 5 (2 3) "aa"))  ->(1 "b")
(tt 5 '(1 "b" (2 3) 5 (2 3) "aa")) ->(1 "b" (2 3))
(tt "aa" '(1 "b" (2 3) 5 (2 3) "aa")) ->(1 "b" (2 3) 5 (2 3))

zxq0220

是我未经仔细测试。但您的程序在表项不存在时会死循环！
进行更改如下：

(defun tt (x lst / a lst2)
(while (and (not (equal x (setq a (car lst)))) (> (length lst) 0))
(setq lst2 (cons a lst2)
lst (cdr lst)
)
)
(reverse lst2)
)

狂刀

2. 
   
3. (defun tt (x lst / a lst2)
   
4.   (while (and lst (not (equal x (setq a (car lst)))))  ;;will be ok
   
5.     (setq lst2 (cons a lst2)
   
6.               lst (cdr lst)
   
7.     )
   
8.   )
   
9.   (reverse lst2)
   
10. )
    

<br /> (defun tt (x lst / a lst2)<br />   (while (and lst (not (equal x (setq a (car lst)))))  ;;will be ok<br />     (setq lst2 (cons a lst2)<br />               lst (cdr lst)<br />     )<br />   )<br />   (reverse lst2)<br /> )<br />

aeo

(length lst) - (length (member x lst))
个数知道了，下面就简单了.

panzhongw

楼上的都不错，相比之下我的就原始了，不过拿出来给大家看看
(defun zw-fmember (dl dla / dlb n1 n2 dlp i)
       (setq dlb (member dla dl))
       (setq n1 (length dl) i 0)
       (setq n2 (length dlb))
       (setq dlp '())
       (repeat (- n1 n2)
               (setq dlc (nth i dl))
               (setq dlp (append (list dlc) dlp))
               (setq i (+ i 1))
       );;repeat
       (reverse dlp)
);;defun

justin2000

向大家多學習

DEA

你们都是高手，我向你们学习。

winabcd

11楼想法很好，实现也容易
我认为此法很好，简单易行。