[求助]：想编一个选一个参照物来删除其它。。。

啵浪鼓

我想写一个这样的程序，先点选一个参照物，分析出它的颜色然后再框选到的物体如果是这个颜色的话将删除

但开始写时，发现一个小问题，如果该物体颜色是随层，将无法分辨出来它的颜色，请帮忙分析一下，谢谢

((-1 . <Entity name: 7ef61f90>) (0 . "LINE") (330 . <Entity
name: 7ef61cf8>) (5 . "EA") (100 . "AcDbEntity") (67 . 0) (410 . "Model") (8 .
"0") (100 . "AcDbLine") (10 872.954 447.364 0.0) (11 892.939 443.499 0.0) (210
0.0 0.0 1.0))

没有（62  . ?）

舟自横

其实你可以用VLISP来取得物体的颜色会比较方便一些
(VLA-GET-COLOR (SETQ EN (VLAX-ENAME->VLA-OBJECT (CAR(ENTSEL)))))
如果取得的颜色是256代表随层,你可以用(SSGET '((62 . 256)))来过滤
总之如果对象省略了62码就代表随层,其实就是(62 . 256)
DO YOU UNDERSTAND?

啵浪鼓

但是如此一来，只能知道他在(62 . 256)里面，我怎么去删除它呢？

回到主题，我是先用entsel选择一个物体得到它的当前颜色为2# yellow色，然后再框选所有物体如果是2#颜色就删除，也包括其它随层的物体也是2#颜色的物体一并删除。。。

而(SSGET '((62 . 256)))只能知道它是随层，但不知道它是不是2#颜色

你应该接触过pressCAD吧，里面有一功能就是"选颜色删图元"，我要做的就是用lisp来实现

david96007

可以通过图层的颜色解决啊!
如果是随层,就查询相应层的信息,不就可以得到颜色了吗?!

舟自横

[php]
(defun hy_leachcolorlist(en / eno color layer ccolor cord_laye layerlist
                         layerlist1 layername layercolor needlis);;;;參照物體顏色過濾表
  (if (= (type en) 'ENAME)
  (progn
  (setq eno (vlax-ename->vla-object en))
  (setq color (vla-get-color eno))
  (setq layer (vla-get-layer eno))
  (setq ccolor (cdr(assoc 62 (entget(tblobjname "layer" layer)))))
  (setq cord_layer (tblnext "layer" t))
  (setq layerlist nil layerlist1 nil)
  (while cord_layer
    (setq layername (cdr(assoc 2 cord_layer)))
    (setq layercolor (cdr(assoc 62 cord_layer)))
    (if (= layercolor color)(setq layerlist (cons (cons 8 layername) layerlist)))
    (if (= layercolor ccolor)(setq layerlist1 (cons (cons 8 layername) layerlist1)))
    (setq cord_layer (tblnext "layer"))
    )
  (if (/= color 256)
      (setq needlis (append '((-4 . "<or"))
                        (list(cons 62 color))
                        '((-4 . "<and")(62 . 256)(-4 . "<or"))
                        layerlist
                        '((-4 . "or>")(-4 . "and>")(-4 . "or>"))))
      (setq needlis (append '((-4 . "<or"))
                            (list '(-4 . "<and")(cons 8 layer)'(62 . 256)'(-4 . "and>"))
                             (list(cons 62 ccolor))
                            '((-4 . "<and")(62 . 256)(-4 . "<or"))
                            layerlist1
                            '((-4 . "or>")(-4 . "and>")(-4 . "or>"))
                            ))
            )
  ))
  (if (= (type en) 'INT) (progn
  (setq color EN)
  (setq cord_layer (tblnext "layer" t))
  (setq layerlist nil)
  (while cord_layer
    (setq layername (cdr(assoc 2 cord_layer)))
    (setq layercolor (cdr(assoc 62 cord_layer)))
    (if (= layercolor color)(setq layerlist (cons (cons 8 layername) layerlist)))
    (setq cord_layer (tblnext "layer"))
    )
  (if (/= color 256)
      (setq needlis (append '((-4 . "<or"))
                        (list(cons 62 color))
                        '((-4 . "<and")(62 . 256)(-4 . "<or"))
                        layerlist
                        '((-4 . "or>")(-4 . "and>")(-4 . "or>"))))
            )
  ))
  needlis
  )
就知道你会提这个问题...试一下这个吧....
她会产生你所选图元颜色的过滤列表
(SSGET (hy_leachcolorlist EN))就会根据选择你所选图元颜色
过滤列表EN为你选择的参照物...选择集都建立了.要想删除他们还不简单吗?
其余的不用我帮你写了吧??相信你自己能写出来..
EN 可以是实体也可以是颜色代码....
如建立2#色选择集(SSGET (hy_leachcolorlist 2))
[/php]