[求助]：小lsp就把我难倒了，请教安全退出的lsp设置。

陈小云

小妹刚学lisp，别笑话。呵呵。

请教如何设置lisp，使得启动命令后，开始或中途Esc和空格等取消操作能够安全退出。即没有错误提示，也不进行变量或值的更改。

正在看书中……
如果高手有空请帮忙解答一下。。

下面是两个小小测试程序。

;多段线编辑
(defun c:ee()
(setvar "cmdecho" 1)
(command "_pedit" "m" (ssget) "" "y" "j" "" "")
)


;第一点打断
(defun c:brf()
  (setvar "cmdecho" 1)
  (command "break" pause "f" pause "@")
  (setvar "cmdecho" 0)
  (princ)
)



[启动brf，后按Esc]

命令行提示：

命令: brf break 选择对象: *取消*
命令: ; 错误: *error* 函数中出错no function definition: SETOSM


[启动brf，后按空格]

命令行提示：

命令: brf break 选择对象:
命令: f 未知命令“F”。按 F1 查看帮助。

;然后，cmdecho变量被设置为1了。




[启动ee，后按Esc]

命令行提示：

命令: ee _pedit 选择多段线或 [多条(M)]: m
选择对象: *取消*
; 错误: *error* 函数中出错no function definition: SETOSM

选择对象: *取消*


[启动ee，后按空格]

命令行提示：

命令:  EE _pedit 选择多段线或 [多条(M)]: m
选择对象:
选择对象:
命令: EE 未知命令“EE”。按 F1 查看帮助。

命令: y 未知命令“Y”。按 F1 查看帮助。

命令: j 未知命令“J”。按 F1 查看帮助。

命令: EE 未知命令“EE”。按 F1 查看帮助。

命令: EE 未知命令“EE”。按 F1 查看帮助。

命令: nil

eachy

command 改成 vl-cmdf

Gu_xl

定义如下两个函数SetIErr,ReErr,在程序开始前使用SetIErr,结束时使用ReErr,例如：
(Defun Test ()
    (SetIerr)
     .
     .
     .
    (ReErr)
    (princ)
  )

定义函数如下：

(DEFUN SetIErr (/ sv)
  (if (or (= 'LIST (type *Error*)))
         (alert "ERROR  :THE LAST (SETiERR) FUNCTION HAS NO (ReErr)!")
        (PROGN
          (SETQ *SVARL* '())
          (FOREACH SV *SYSVARNL*
            (SETQ *SVARL* (CONS (GETVAR SV) *SVARL*))
            )
          (FOREACH SV '("ATTDIA" "BLIPMODE" "CMDECHO" "DIMZIN"
                        "OSMODE" "ORTHOMODE" "MIRRTEXT")
            (SETVAR SV 0)
            )
          
          (SETVAR "EXPERT" 5)
         (SETVAR "CECOLOR" "BYLAYER")
         (SETVAR "celtype" "BYLAYER")
        ; (if SetScale () (InitMap))

          (defun *error* (st) (if selections (cancel-s)) (reerr)(princ))
          )
         )
    )

(defun ReErr ()
  (if (or (= 'LIST (type *error*)) (= 'SUBR (type *error*)) (= 'USUBR (type *error*)))
         (PROGN (MAPCAR 'SETVAR *SYSVARNL* (REVERSE *SVARL*))
           (SETQ  *Error* nil)
           )
         (ALERT "ERROR  : NO (SETIERR)!")
         )
(PRINC)
   )

陈小云

感谢两位帮忙。努力中……

xyp1964

对于SetIErr函数将OSMODE设为0并不好，只有画线取点时才需设为0。

yjrun

自定义错误函数应该可以解决这个问题的.

winabcd

当程序出错时自动运行/转入出错处理程序，
可由用户定义的错误处理函数
(*error* string)

如果 *error* 不为 nil，则当 AutoLISP 的错误条件出现时，就会执行其中的定义，并由 AutoCAD 传给它一个包含错误信息的字符串作为参数。
用户 *error* 函数可以不带参数调用 command 函数（如 (command)）。这样可以取消前面由 command 函数执行的 AutoCAD 命令。

返回值

除使用 vl-exit-with-value 外，本函数无返回值。

样例

如下函数与标准 AutoLISP 出错处理执行相同的任务，打印“错误：”和错误信息：

(defun *error* (msg)
  (princ "错误：")
  (princ msg)
  (princ)

)

陈小云

能用不同的方法加入出错处理，完善这两个程序吗？边城实在不行。谢谢啦。到现在还没学会。平时也没能挤出点时间好好学学。

;多段线编辑
(defun c:ee()
(setvar "cmdecho" 1)
(command "_pedit" "m" (ssget) "" "y" "j" "" "")
)

;第一点打断
(defun c:brf()
(setvar "cmdecho" 1)
(command "break" pause "f" pause "@")
(setvar "cmdecho" 0)
(princ)
)

zml84

COMMAND 函数内部最好不要出现交互操作。其参数放到command函数执行之前完成。
对command执行的条件进行判断，把不能执行的条件过滤掉。

把8楼的代码修改后，如下：
[PHP]

;;;多段线编辑
(defun c:ee (/ s1)
    (setq CMDOLD (getvar "CMDECHO"))
    (setvar "CMDECHO" 0)

    (princ "\n将多条线连接。\n请选择要添加的对象...")
    (setq s1 (ssget))
    (if        (= nil s1)
        (princ "\n选择集为空，正常退出。")
        (command "_pedit" "m" s1 "" "y" "j" "" "")
    )

    (setvar "CMDECHO" CMDOLD)
    (princ)
)


;;;第一点打断
(defun c:brf (/ ENT1 PT)
    (setq CMDOLD (getvar "CMDECHO"))
    (setvar "CMDECHO" 0)

    (if        (setq ENT1 (entsel "请选择一个对象: "))
        (if (SETQ PT
                     (getpoint "\n指定打断点：")
            )
            (command "break" ENT1 "f" PT "@")
        )
    )

    (setvar "CMDECHO" CMDOLD)
    (princ)
)

;;;自定义错误处理函数
(defun *error* (msg)
    (princ "MY错误：")
    (princ msg)
    (if        (or (= CMDOLD 0) (= CMDOLD 1))
        (setvar "CMDECHO" CMDOLD)
    )
    (princ)
)
[/PHP]

陈小云

先谢谢 zml84  了。另外也同样谢谢热心的朋友。
这段“自定义错误处理函数”程序在一些小程序里面可以通用吗？

另外，我想恢复默认的错误处理和捕捉，按照下面（打下划线部分）做可以吗？



;;;多段线编辑
(defun c:ee (/ s1)
    [U](setq os (getvar "osmode") olderr *error*)[/U]
    (setq CMDOLD (getvar "CMDECHO"))
    (setvar "CMDECHO" 0)

    (princ "\n将多条线连接。\n请选择要添加的对象...")
    (setq s1 (ssget))
    (if        (= nil s1)
        (princ "\n选择集为空，正常退出。")
        (command "_pedit" "m" s1 "" "y" "j" "" "")
    )

    (setvar "CMDECHO" CMDOLD)
    [U](setq *error* olderr)[/U]
    [U](setvar "osmode" os)[/U]     
    (princ)
)


;;;第一点打断
(defun c:brf (/ ENT1 PT)
    (setq os (getvar "osmode") olderr *error*)
    (setq CMDOLD (getvar "CMDECHO"))
    (setvar "CMDECHO" 0)

    (if        (setq ENT1 (entsel "请选择一个对象: "))
        (if (SETQ PT
                     (getpoint "\n指定打断点：")
            )
            (command "break" ENT1 "f" PT "@")
        )
    )

    (setvar "CMDECHO" CMDOLD)
    (setq *error* olderr)
    (setvar "osmode" os)
    (princ)
)

;;;自定义错误处理函数
(defun *error* (msg)
    (princ "MY错误：")
    (princ msg)
    (if        (or (= CMDOLD 0) (= CMDOLD 1))
        (setvar "CMDECHO" CMDOLD)
    )
    (princ)
)

zml84

我想你可能已经通过测试，你的这个思想是完全可以的。
<br>
可以到通用函数板块中找到好多诸如此类的好东东。
积极吸收前人的经验，在学习中就可以少走弯路。