[求助]：看似简单：COMMAND命令画line线，然后显示ok

doubao · 发表于 2005-8-3 23:34:43

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

请看这个程序：

(defun c:L()
  (command "._line" )
  (princ "ok! ")
)

能运行，但运行后的现象是先显示ok，然后才提示输入点。

编这个程序目的是要画完任意多线段后才显示ok，也就是彻底执行完AUTOCAD的LINE命令后再转回到LISP的（princ "ok"）。

其实这只是一个测试程序，真正的目的是想知道怎样在LISP程序里调用AUTOCAD命令而不用预置该命令的全部参数。例如INSERT命令，有很多选项，我希望人工任意组合选择这些选项里的某几项。  似乎用COMMAND不可能做到这一点。有没有什么好办法呢？

我不想用编程的方法选择所有可能的选项然后再分别传送到AUTOCAD的命令里。这样做就好比“重新发明轮子”，呵呵。

xyp1964 · 发表于 2005-8-4 00:26:24

[FONT=courier new](defun c:test ()
(if (setq pt1 (getpoint "\n起点<退出> : "))
(progn
(command "._line" pt1)
(while (setq pt2 (getpoint pt1 "\n下一点<退出> : "))
(command pt2)
(setq pt1 pt2)
)
(command)
)
)
(princ "\nOK!")
(princ)
)[/FONT]

fundoll · 发表于 2005-8-4 15:53:30

加个 "pause" 试试。

doubao · 发表于 2005-8-4 19:13:47

感谢楼上二位回复！

看了2楼的程序才知道 command 函数还可以这么用 : （command pt）

再仔细地看了一遍autolisp的帮助中对command 命令的解释，原文是这样的：

(command [arguments] ...)

The command function evaluates each argument and sends it to AutoCAD in response to successive prompts。（command 函数计算每个argument参数的值并按顺序传递给 AutoCAD 的提示）

原来一直以为command 函数的第一个参数一定是一个AutoCAD 的命令呢。其实command 函数只是把LISP 参数传递到AutoCAD中，本身并不执行任何AutoCAD 的命令。

好，虽然没有解决我的问题，但是搞清楚了一个概念。

网络水手 · 发表于 2005-8-5 08:33:55

(defun c:L()
(command "._line" pause pause "")
(princ "ok! ")
)

当没有pause时, lisp程序会一直执行, 直到最后.
pause的功能就是暂停程序执行, 完成后再执行pause后的代码!

xyp1964 · 发表于 2005-8-5 08:39:11

最初由网络水手发布
[B](defun c:L()
(command "._line" pause pause)
(princ "ok! ")
)

当没有pause时, lisp程序会一直执行, 直到最后.
pause的功能就是暂停程序执行, 等待用户的输入. 完成后再执行pause后的代码! [/B]

不能满足要求！
[php]l ._line Specify first point:
Specify next point or [Undo]:
Specify next point or [Undo]: ok! "ok! "

Specify next point or [Undo]:
Specify next point or [Close/Undo]:
Specify next point or [Close/Undo]:
Specify next point or [Close/Undo]:
Specify next point or [Close/Undo]:
Specify next point or [Close/Undo]:
Specify next point or [Close/Undo]:
Specify next point or [Close/Undo]:
Specify next point or [Close/Undo]:
Specify next point or [Close/Undo]:
Specify next point or [Close/Undo]:
Specify next point or [Close/Undo]:
Specify next point or [Close/Undo]:
[/php]

网络水手 · 发表于 2005-8-5 13:15:00

最初由 xyp1964 发布
[B][QUOTE]最初由网络水手发布
[B](defun c:L()
(command "._line" pause pause)
(princ "ok! ")
)

当没有pause时, lisp程序会一直执行, 直到最后.
pause的功能就是暂停程序执行, 等待用户的输入. 完... [/B]

上面我只是说明一下 pause 的情况,:
下面的如何?

(defun c:L(/ tt)
  (command "._line")
  (while (setq tt (getpoint))
(command tt)
)
  (command "")
  (princ "ok! ")
  (princ)
)

xyp1964 · 发表于 2005-8-5 16:09:47

最初由网络水手发布
[B][QUOTE]最初由 xyp1964 发布
[B][QUOTE]最初由网络水手发布
[B](defun c:L()
(command "._line" pause pause)
(princ "ok! ")
)

当没有pause时, lisp程序会一直执行, 直到最后.
pause的功... [/B]

自己试试，觉得好吗？

doubao · 发表于 2005-8-5 19:42:50

从上面的讨论以及实践，我们可以搞清 command 函数的概念以及 pause 的功能：

command 函数本质上是建立lisp程序和autocad之间的桥梁，不过是单向的，只能把参数从lisp程序传递到autocad；

pause 只是等待用户输入（一个pause 仅等待一次输入）。

能不能实现lisp程序和autocad之间的双向桥梁呢？也就是如何从 lisp程序发出请求，让autocad执行任意一条autocad命令（比如 LINE， PLINE， COPY 。。。。等等），在执行过程中，这条autocad命令的所有需要的参数均由用户自由输入（注意不是从lisp程序传递），等autocad执行完这条autocad命令后，再回到lisp程序。

再引申一下，怎样才能让程序知道autocad 执行完了某个autocad命令呢？

userzhluserzhl · 发表于 2005-8-5 20:14:46

又学会了一些函数，有哪位有没有把LSP的函数更形象的解释？

cy956 · 发表于 2005-8-5 20:35:20

最初由网络水手发布
[B](defun c:L()
(command "._line" pause pause)
(princ "ok! ")
)

没问题，可以执行。

doubao · 发表于 2005-8-6 16:01:21

执行是可以执行，但是事实上有问题。
xyp1964 版主在第六楼的帖子里已经明确给出了运行结果：

l ._line Specify first point:
Specify next point or [Undo]:                      ；点取了第一个点
Specify next point or [Undo]: ok! "ok! "       ；点取了第二个点后就显示了ok及返回值“ok”，说明LISP程序已经结束。

Specify next point or [Undo]:                ；接下来的提示实际上是autocad的line命令还没有结束，并不是lisp程序在运行
Specify next point or [Close/Undo]:
Specify next point or [Close/Undo]:
Specify next point or [Close/Undo]:
Specify next point or [Close/Undo]:
Specify next point or [Close/Undo]:
Specify next point or [Close/Undo]:
Specify next point or [Close/Undo]:
Specify next point or [Close/Undo]:
Specify next point or [Close/Undo]:
Specify next point or [Close/Undo]:
Specify next point or [Close/Undo]:
Specify next point or [Close/Undo]:

最开始输入的两个点是因为有两个pause。如果有3个pause，那么将会在点取3个点后显示ok。

----------

另外，在看了这个帖子（点击进入） 后，知道了用
vlr-command-reactor 函数可以最终解决autocad向lisp程序发出通知的问题。有兴趣的不妨去看一下，版主还给出了该函数的用法。

感谢 eachy 版主的加分鼓励！
并再次感谢 xyp1964 和aeo 两位版主的热心帮助！

titan_cad · 发表于 2005-8-9 10:10:36

最初由 doubao 发布
[B]从上面的讨论以及实践，我们可以搞清 command 函数的概念以及 pause 的功能：

command 函数本质上是建立lisp程序和autocad之间的桥梁，不过是单向的，只能把参数从lisp程序传递到autocad；

pause 只是等待?.. [/B]

再加一个问题,CAD执行被调用的命令时,怎么从LISP传递这个程序中的某个或者某些参数呢?

doubao · 发表于 2005-8-9 12:11:12

请举例说明一下情况

LUCAS · 发表于 2005-8-10 12:23:09

;;By LUCAS
;;不是看似簡單,是真的簡單!
;;但INSERT命令卻真的不是那麼簡單(插入帶屬性的blk或dwg)!
(defun C:L (/ *ERROR* ERR HOLDECHO OLD_ERROR)
(defun ERR (MSG)
(setvar "cmdecho" HOLDECHO)
(setq *ERROR* OLD_ERROR)
(princ)
)
(setq OLD_ERROR *ERROR*)
(setq *ERROR* ERR)
(setq HOLDECHO (getvar "cmdecho"))
(setvar "cmdecho" 0)
(prompt "\n指定第一點: ")
(command "_.line")
(setvar "cmdecho" 1)
(while (= 1 (getvar "cmdactive"))
(command PAUSE)
)
(prompt "\nOk! ")
(setq *ERROR* OLD_ERROR)
(setvar "cmdecho" HOLDECHO)
(princ)
)

账号		自动登录	找回密码
密码			立即注册

[求助] [求助]：看似简单：COMMAND命令画line线，然后显示ok

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子

浏览过的版块

[求助] [求助]：看似简单：COMMAND命令画line线， 然后显示ok

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子

浏览过的版块

[求助] [求助]：看似简单：COMMAND命令画line线，然后显示ok