[LISP函数]：SET 函数有什么用？

doubao · 发表于 2005-9-4 21:21:37

我做了一个试验：

在一个新图里做了三个块，
块 111  是一个矩形，然后矩阵为70000个
块 222  是一个圆，然后矩阵为50000个
块 333  是一个椭圆，然后矩阵为40000个

结果:

用set函数编的统计程序（11楼程序）大约用了 17 秒，

用13楼程序大约用了 550 秒。

(感谢版主加分!)

其实13楼程序也可以改进一下为累加器方式的。

ll_j · 发表于 2005-9-5 12:01:35

实际上13楼的程序就是累加器的问题，我修改了一下，速度比11楼的程序快一些：
[php](defun c:sumblk (/ ss sl i ent  bnm bl)
  ;;
  (if (setq ss (ssget '((0 . "insert"))))
(progn
   (setq sl (sslength ss)
      i  0
   )
   (setq t1 (getvar "cdate")) ;;;;
   (repeat sl
(setq ent (entget (ssname ss i))
      i    (1+ i)
      bnm (strcat "EA_" (cdr (assoc 2 ent)))
)
(if (eval (read bnm))
   (set (read bnm) (1+ (eval (read bnm))))
   (set (read bnm) 1)
)
(setq bl (if (not (vl-position bnm bl))
   (cons bnm bl)
   bl
   )
)
   )
   (if bl
(progn (mapcar '(lambda (x)
   (princ (strcat "\n图块" (substr x 4) "数量: "))
   (princ (eval (read x)))
)
         bl
         )
         (mapcar '(lambda (x) (set (read x) nil)) bl);_这个要定义到 *error* 中释放变量
         (setq bl nil);_也要加入到 *error* 中
)
   )
)
  )
   (setq t2 (getvar "cdate")) ;;;;
   (princ "\n") ;;;;
   (princ (rtos (* 100000 (- t2 t1) 2 8)))  ;;;;
  (princ)
)

;| Written By Eachy 2004.1.12
功能: 图块数量统计;;
说明: 根据点取的典型图块统计, 可以多选 ;;
|;
(defun c:Ea:BlkNum  (/ ss ssl i bn bl pos)
  (princ "\n拾取统计范围[All - 全选].....")
  (if (setq ss (ssget '((0 . "insert"))))
(progn
   (setq ssl (sslength ss)
      i -1
   )
   (setq t1 (getvar "cdate")) ;;;;
   (repeat ssl
(setq bn (cdr (assoc 2 (entget (ssname ss (setq i (1+ i)))))))
(if bl
   (if (setq pos (assoc bn bl))
      (setq bl (subst (cons bn pos) pos bl))
      (setq bl (append (list (list bn)) bl))
   )
   (setq bl (list (list bn)))
)
   )
   (mapcar '(lambda (x)
   (princ (strcat "\n图块" (car x) "数量: "))
   (princ (length x))
         )
      bl
   )
)
  )
   (setq t2 (getvar "cdate")) ;;;;
   (princ "\n") ;;;;
   (princ (rtos (* 100000 (- t2 t1) 2 8)))  ;;;;
  (princ)
)

;;;;修改程序
(defun c:BlkNum  (/ ss ssl i bn bl pos)
  (princ "\n拾取统计范围[All - 全选].....")
  (if (setq ss (ssget '((0 . "insert"))))
(progn
   (setq ssl (sslength ss)
      i -1
   )
   (setq t1 (getvar "cdate")) ;;;;
   (repeat ssl
(setq bn (cdr (assoc 2 (entget (ssname ss (setq i (1+ i)))))))
(if bl
   (if (setq pos (assoc bn bl))
      (setq bl (subst (cons bn (1+ (cdr pos))) pos bl))
      (setq bl (cons (cons bn 1) bl))
   )
   (setq bl (list (cons bn 1)))
)
   )
   (mapcar '(lambda (x)
   (princ (strcat "\n图块" (car x) "数量: "))
   (princ (cdr x))
         )
      bl
   )
)
  )
   (setq t2 (getvar "cdate")) ;;;;
   (princ "\n") ;;;;
   (princ (rtos (* 100000 (- t2 t1) 2 8)))  ;;;;
  (princ)
)[/php]

前面是原来程序，最后一段是修改后程序。

其实很简单，“setq”是对一个（或多个）固定名称的变量赋值，而“set”是对一个不定名称的变量赋值，即名称也是可以运算得到的，其实这样更占用内部资源，且不利于释放，所以应该是不得已而为之。

eachy · 发表于 2005-9-5 12:09:36

如果有数量很多的不同图块，每个块的数量少，这时的表用 Assoc 检索不知不觉效率如何

ll_j · 发表于 2005-9-5 12:30:45

最初由 eachy 发布
[B]如果有数量很多的不同图块，每个块的数量少，这时的表用 Assoc 检索不知不觉效率如何 [/B]

使用assoc检索应该是比较高效率的，同样使用vl-position函数也是检索，程序中替换是容易的，但与set函数无关，也许vl函数在al函数基础上有较多的优化，会快一些也不一定。程序还涉及其它函数以及算法，影响速度的主要因数应该是算法而不是函数。

eachy · 发表于 2005-9-5 14:23:47

的确，算法很重要，不过对Lisp程序除了算法之外，在批量处理的时候还要对函数进行比选，使用高效的函数，积少成多，最终才能得到Lisp方法的最高效程序。

doubao · 发表于 2005-9-5 17:00:54

ll_j 指出 “set 是对一个不定名称的变量赋值，即名称也是可以运算得到的，其实这样更占用内部资源，且不利于释放，所以应该是不得已而为之。”

这段话引出两个问题

1、什么时候“不得已而为之”用SET函数？还有其他更好的例子么？

2、有没有什么好的办法释放由SET函数设置的变量？

ll_j · 发表于 2005-9-5 20:06:53

最初由 doubao 发布
[B]ll_j 指出 “set 是对一个不定名称的变量赋值，即名称也是可以运算得到的，其实这样更占用内部资源，且不利于释放，所以应该是不得已而为之。”

这段话引出两个问题

1、什么时候“不得已而为之”用SET函数？ ... [/B]

1.更好的例子无法举，用到时的确会感到乐趣，就是联机帮助中所说的“间接”赋值。我所记得的论坛最早提到set函数是关于“数组”的，具体不记得了，大意就是将“内容1”赋值到如变量“P1”，“内容2”赋值到变量“P2”....，就如：

...
(setq i (1+ i) j (1+ j))
(set (read (strcat "p" (itoa i))) (* 3 j^2))
...

当然，这个例子最好的解决办法还是使用表，但有时的确会有“字符串”、“序列”与“值”存在“联动”关系，使用一下set可能大大精简代码。
2.关于释放，不是没有办法，可以再“制造”这个“序列”（如P1、P2...），然后逐个赋值为nil，在c:sumblk函数中，“(mapcar '(lambda (x) (set (read x) nil)) bl)”就是释放变量，前提是这些变量名（就是“EA_块名”）已经被预先收集在一个表中了。

doubao · 发表于 2005-9-5 20:46:44

有点开窍了。多谢 ll_j ！！！

狂刀 · 发表于 2005-9-5 21:39:40

[FONT=courier new]
(defun c:bkc2 (/ i ss e nm sym lst )
(princ "\nbkc全图块统计-v2.0b(set方法)\n 选择块<回车全选>:")
(or(setq ss (ssget '((0 . "INSERT"))))
(setq ss (ssget "x" '((0 . "INSERT"))))
);;
(setq i -1)
(while (setq e (ssname ss (setq i (1+ i))))
;;(setq nm (cdr(assoc 2 (entget e)))
(setq nm (strcat "块" (cdr(assoc 2 (entget e))))
sym (read nm))
(if (eval sym)
(set sym (1+ (eval sym)))
(progn
(set sym 1)
(setq lst (cons sym lst))
)
)
)
(princ "\n 块名数量 ")
(mapcar '(lambda(x)(print x)(princ "　数量为　")(princ (eval x))) lst)
(mapcar '(lambda(x)(set x nil)) lst)
(princ)
)
[/FONT]

eachy · 发表于 2005-9-5 23:20:56

假如块名中有纯数字的或者有 “PI” “TYPE” 。。。。

狂刀 · 发表于 2005-9-6 00:09:49

哦，忘了
(setq nm (cdr(assoc 2 (entget e)))
改为　
(setq nm (strcat "块" (cdr(assoc 2 (entget e))))
就ok (已更新)
再贴一个，也是用表先保存块名（不删同名项），然后计数（ｍａｐｃａｒ一句），效率不知道怎么样，输出结果块名排序，看起来美观一点：），与大家分享。

[FONT=courier new]
(defun c:bkc (/ i fil ss e nms nm lst)
(princ "\nbkc全图块统计-v2.0---狂刀.2005.8m \n 选择块<回车全选>:")
(setq i -1 fil '((0 . "INSERT")))
(or(setq ss (ssget fil))
(setq ss (ssget "x" fil))
)
(while (setq e (ssname ss (setq i (1+ i))))
(setq nms (cons (cdr(assoc 2 (entget e))) nms))
)
(setq nms (vl-sort nms '<));;排序.
(setq nm (car nms) i 0 lst nil)
(mapcar '(lambda(x)(if (= nm x)(setq i(1+ i))(setq lst (cons (list nm i) lst) i 1 nm x))) nms)
(princ "\n 块名数量 ");;
(mapcar '(lambda(x)(print (car x))(princ " ")(princ (cadr x))) lst);;
(princ);; lst 返回值可改为表用于程序中.
)　
[/FONT]

账号		自动登录	找回密码
密码			立即注册