[求助]：是否有获取曲线长度的LISP函数

hsslyl · 发表于 2005-10-28 20:35:09

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

例如：应用(vlax-curve-getarea 图元名)可以获取该图元的面积，请问，是否有类似的获取曲线长度的LISP函数（不用(getvar "perimeter")）？

xyp1964 · 发表于 2005-10-28 20:56:14

[php](vlax-curve-getDistAtParam ename (vlax-curve-getEndParam ename))[/php]

hsslyl · 发表于 2005-10-30 02:25:45

不行啊！xyp1964，出现错误提示：出错：无法获取 ObjectID: nil!
望指点，谢谢！

xyp1964 · 发表于 2005-10-30 08:41:02

[FONT=courier new]
(defun c:test ()
(setq ename (car (entsel"\n选择曲线 : ")))
(vlax-curve-getDistAtParam
ename
(vlax-curve-getEndParam ename)
)
)[/FONT]

hsslyl · 发表于 2005-10-30 15:37:23

谢谢！不好意思，原来是我粗心了，ename变量名输错，值为nil，导致出错。

xyp1964 · 发表于 2005-10-30 17:44:17

最初由 hsslyl 发布
[B]谢谢！不好意思，原来是我粗心了，ename变量名输错，值为nil，导致出错。 [/B]

利用以上内容自定义成通用函数：

[FONT=courier new]
;;;曲线长度
;;;xyp-get-CurveLength
(defun xyp-get-CurveLength (ename)
(vlax-curve-getDistAtParam
ename
(vlax-curve-getEndParam ename)
)
)[/FONT]

yunzhong80 · 发表于 2005-10-31 15:30:06

;;;-----------------------------------------------------
;;;计算线加总长度
;;;-----------------------------------------------------
(defun C:LENOF (/ CURVE TLEN SS N SUMLEN)
  (vl-load-com) ;将Visual LISP扩展功能加载到Visual LISP
  (setq SUMLEN 0)
  (setq SS (ssget '((0 . "CIRCLE,ELLIPSE,LINE,*POLYLINE,SPLINE,ARC"))))
  (setq N 0)
  (repeat (sslength SS)                               ;对循环体中的每一个表达式进行指定次数的求值计算
(setq CURVE (vlax-ename->vla-object (ssname SS N)))  ;将Visual LISP类型的对象名转换为VLA对象
(setq TLEN (vlax-curve-getDistAtParam             ;返回曲线从开始到指定参数的曲线段的长度
CURVE
(vlax-curve-getEndParam CURVE)                         ;返回曲线端点的参数
   )
)
(setq SUMLEN (+ SUMLEN TLEN))
(setq N (1+ N))
  )
  (print (strcat "总长度: " (rtos SUMLEN 2 5)))
  (princ)
)

利用代码可以增加程序的可读性：by xyp1964[/COLOR]

[FONT=courier new]
;;;-----------------------------------------------------
;;;计算线加总长度
;;;-----------------------------------------------------
(defun C:LENOF (/ CURVE TLEN SS N SUMLEN)
(vl-load-com) ;将Visual LISP扩展功能加载到Visual LISP
(setq SS (ssget '((0 . "CIRCLE,ELLIPSE,*LINE,ARC")))
N 0
SUMLEN 0
)
(repeat (sslength SS) ;对循环体中的每一个表达式进行指定次数的求值计算
(setq CURVE (vlax-ename->vla-object (ssname SS N)) ;将Visual LISP类型的对象名转换为VLA对象
TLEN (vlax-curve-getDistAtParam CURVE ;返回曲线从开始到指定参数的曲线段的长度
(vlax-curve-getEndParam CURVE) ;返回曲线端点的参数
)
SUMLEN (+ SUMLEN TLEN)
N (1+ N)
)
)
(print (strcat "总长度: " (rtos SUMLEN 2 5)))
(princ)
)[/FONT]

xyp1964 · 发表于 2005-10-31 17:55:47

楼上改写：

[FONT=courier new](defun C:test (/ ss SUMLEN n leng S1)
(vl-load-com)
(setq SS (ssget '((0 . "CIRCLE,ELLIPSE,*LINE,ARC")))
SUMLEN 0
n -1
)
(while (setq s1 (ssname SS (setq n (1+ n))))
(setq leng (xyp-get-CurveLength s1)
SUMLEN (+ SUMLEN leng)
)
)
(princ "\n总长度: ")
(princ (rtos SUMLEN 2 4))
(princ)
)
(defun xyp-get-CurveLength (ename)
(vlax-curve-getDistAtParam
ename
(vlax-curve-getEndParam ename)
)
)
[/FONT]

狂刀 · 发表于 2005-10-31 22:47:35

用完area命令
(getvar "perimeter")
也算是一种方法吧，参考

账号		自动登录	找回密码
密码			立即注册

[求助] [求助]：是否有获取曲线长度的LISP函数

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子