[求助]：什么函数可以得到全部块的块名？

jianqiang21c · 发表于 2003-5-12 10:54:20

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

什么函数可以得到全部块的块名？

newer · 发表于 2003-5-12 11:03:42

最初由 jianqiang21c 发布
[B]什么函数可以得到全部块的块名？ [/B]

ACAD里面没有没有一个现成的LISP函数，你可以自己用tblnext 遍历块表，得到他们，参考下下面的代码：

<normalfont>
(setq tf t nl nil)
(while (setq e (tblnext "block" tf))
(setq na (cdr (assoc 2 e))
tf nil
)
(setq nl (cons na nl))
)
(setq nl (reverse nl))
</normalfont>

lijiao · 发表于 2003-5-12 11:43:19

最初由 jianqiang21c 发布
[B]什么函数可以得到全部块的块名？ [/B]

[FONT=courier new]
(setq out nil)
(vlax-for blk (vla-get-blocks
(vla-get-ActiveDocument (vlax-get-acad-object))
)
(setq out (cons (vla-get-name blk) out))
)
(if out
(reverse out)
out
)
[/FONT]

jianqiang21c · 发表于 2003-5-12 14:58:09

高~~~，严重谢谢LIJIAO，不过图块列表中好象没这么多吧

LUCAS · 发表于 2003-5-12 15:48:14

在Vlisp中__模型空间与图纸空间视为图块的一种

lijiao · 发表于 2003-5-12 16:23:06

最初由 jianqiang21c 发布
[B]高~~~，严重谢谢LIJIAO，不过图块列表中好象没这么多吧 [/B]

能不能说说哪个是多余的。

jianqiang21c · 发表于 2003-5-12 17:26:33

就像这个一样(command ".block" "?" "")只要已经定义的块

ll_j · 发表于 2003-5-12 20:21:20

只要过滤掉“*D”（标注）、“*X”（填充）及“*U”（自定义无名块）打头的块名即可。

jianqiang21c · 发表于 2003-5-12 20:31:01

青铜长老指点一二吧：）

ll_j · 发表于 2003-5-12 20:52:05

接newer程序

(setq bll nil)
(mapcar
'(lambda (x)
(if (not (wcmatch x "`*[XUD]*"))
(setq bll (cons x bll))
)
)
nl
)

CUTEE · 发表于 2003-5-12 21:09:01

</normalfont>
(defun Insrt (Ent Lis)
(cond
((null Lis) (list Ent))
((< Ent (car Lis)) (cons Ent Lis))
(T (cons (car Lis) (Insrt Ent (cdr Lis))))
)
)
(defun today ()
(setq td (getvar "date"))
(setq time (* 86400.0 (- td (setq j (fix td)))))
(setq j (- j 1721119.0))
(setq y (fix (/ (1- (* 4 j)) 146097.0)))
(setq j (- (* j 4.0) 1.0 (* 146097.0 y)))
(setq d (fix (/ j 4.0)))
(setq j (fix (/ (+ (* 4.0 d) 3.0) 1461.0)))
(setq d (- (+ (* 4.0 d) 3.0) (* 1461.0 j)))
(setq d (fix (/ (+ d 4.0) 4.0)))
(setq m (fix (/ (- (* 5.0 d) 3) 153.0)))
(setq d (- (* 5.0 d) 3.0 (* 153.0 m)))
(setq d (fix (/ (+ d 5.0) 5.0)))
(setq y (+ (* 100.0 y) j))
(if (< m 10.0)
(setq m (+ m 3))
(progn
(setq m (- m 9))
(setq y (1+ y))
)
)
(setq datestr (strcat "\nToday's Date: "(itoa(fix m)) "/" (itoa(fix d)) "/" (itoa(fix y))))
(princ)
)
(defun myerror (s) ; If an error (such as CTRL-C) occurs
; while this command is active...
(if (/= s "Function cancelled")
(princ (strcat "\nError: " s))
)
(setvar "cmdecho" ocmd) ; Restore saved modes
(setvar "blipmode" oblp)
(setq *error* olderr) ; Restore old *error* handler
(princ)
)
(defun layer ( / c d f ln lt ly n x)
(princ (strcat "\nPrinting to file: " fname "..."))
(princ "\nLayer Name\tStatus\tOn/Off\tLock\tColor\tLinetype\n" dfile)
(setq x (tblnext "layer" T))
(setq lalist nil)
(while x
(setq
ly (cdr (assoc 2 x)) ; layer name
ln (cdr (assoc 6 x)) ; linetype name
c (cdr (assoc 62 x)) ; color number
f (cdr (assoc 70 x)) ; "frozen" flag
lt (tblsearch "ltype" ln) ; linetype table entry
)
(if (= (logand f 1) 1) (setq fstat "Frozen")(setq fstat "Thawed"))
(if (= (logand f 4) 4) (setq lstat "Locked")(setq lstat "NO"))
(if (< c 0) (setq cstat "Off")(setq cstat "On"))
(setq nextla
(strcat
ly "\t" ; layer name
fstat "\t" ; frozen/thawed
cstat "\t" ; on/off
lstat "\t" ; locked/unlocked
(itoa (abs c)) "\t" ; color number
ln "\n" ; linetype name
)
)
(setq lalist (Insrt nextla lalist))
(setq x (tblnext "layer"))
)
(foreach N lalist (princ N dfile))
(princ "\n\n" dfile)
)
;;; (LTYPE) - Dump the linetype table
(defun ltype ( / a cl d f lt n s x)
(princ "\nLinetype Name\n" dfile)
(setq ltlist nil)
(setq x (tblnext "LTYPE" T))
(while x
(setq nextlt
(strcat
(cdr (assoc 2 x)) "\t" ; linetype name
(cdr (assoc 3 x)) "\n" ; linetype description
)
)
(setq ltlist (Insrt nextlt ltlist))
(setq x (tblnext "LTYPE")) ; get next linetype entry
)
(foreach N ltlist (princ N dfile))
(princ "\n\n" dfile)
)
;;; (VIEW) - Dump the named view table
(defun view ( / c d h n v w x)
(princ "\nView Name\n" dfile)
(setq x (tblnext "VIEW" T))
(setq n 0)
(setq vwlist nil)
(while x
(setq n (1+ n)
nextvw (cdr (assoc 2 x)) ; view name
)
(setq vwlist (insrt nextvw vwlist))
(setq x (tblnext "VIEW" )) ; get next view entry
)
(if (/= n 0)
(foreach N vwlist (princ N dfile))
(princ "-None-" dfile)
)
(princ "\n\n" dfile)
)
;;; (STYLE) - Dump the text style table
(defun style ( / cs fb ff g h n o s w x)
(princ "\nText Style\tHeight\tWidth\tOblique\tFont\tBigfont\n" dfile)
(setq n 0)
(setq x (tblnext "style" T))
(setq stylist nil) ; get first style
(while x
(setq n (1+ n)
s (fld 2 x) ; style name
ff (fld 3 x) ; primary font file
fb (fld 4 x) ; big font file
h (fld 40 x) ; height
w (fld 41 x) ; width factor
o (fld 50 x) ; obliquing angle
)
(setq nextsty
(strcat
s ; edit style name
"\t" (rtos h 2 2) ; height
"\t" (rtos w 2 2) ; width factor
"\t" (angtos o 0 2) ; obliquing angle
"\t" ff ; primary font file
"\t" fb "\n" ; big font file
)
)
(setq stylist (insrt nextsty stylist))
(setq x(tblnext "style")) ; get next style entry
)
(if (= n 0) (princ "-None-" dfile)
(foreach N stylist (princ N dfile))
)
(princ "\n\n" dfile)
)
;;; (BLOCK) - Dump the block definition table
(defun block ( / b e ec ed et f n o x blklist xreflist nextblk nextxref)
(princ "\nBlock Name\tCount\n" dfile)
(setq n 0)
(setq x (tblnext "block" T))
(setq blklist nil) ; get first block definition
(while x
(setq n (1+ n)
b (fld 2 x) ; block name
f (fld 70 x) ; flags
)
;(if (= (logand f 4) 4)(setq btype "Xref")(setq btype "Block"))
;(if (= btype "Xref")(setq Xpath (fld 1 x))(setq Xpath " "))
(if (/= (logand f 1) 1)
(progn
(setq PWRss (ssget "X" (list (cons 2 b))))
(if pwrss (setq bcount (sslength pwrss))(setq bcount 0))
(if (= (logand f 4) 4)
(progn
(setq nextxref (strcat b "\t" (itoa bcount) "\t" (fld 1 x) "\n"))
(setq xreflist (insrt nextxref xreflist))
)
(progn
(setq nextblk (strcat b "\t" (itoa bcount) "\n"))
(setq blklist (insrt nextblk blklist))
)
)
)
)
(setq x (tblnext "block"))
)
(if (= n 0) (princ "-None-" dfile)
(foreach N blklist (princ N dfile))
)
(princ "\n\nXrefs\tCount\tPath\n" dfile)
(if (= n 0) (princ "-None-" dfile)
(foreach N xreflist (princ N dfile))
)
(princ "\n\n" dfile)
)
;;; (UCS) - Dump the UCS table
(defun ucs ( / n x na o xd yd)
(princ "\nUCS Name\n" dfile)
(setq n 0)
(setq x (tblnext "ucs" T))
(setq ucslist nil)
(while x
(setq n (1+ n)
nextucs (strcat (cdr (assoc 2 x)) "\n")
)
(setq ucslist (insrt nextucs ucslist))
(setq x (tblnext "ucs"))
)
(if (= n 0) (princ "-None-" dfile)
(foreach N ucslist (princ N dfile))
)
(princ "\n\n" dfile)
)
;;; (VPORT) - Dump the viewport table
(defun vport ( / n x na ll ur v)
(princ "\nViewport Name\n" dfile)
(setq n 0)
(setq x (tblnext "vport" T))
(setq vplist nil)
(while x
(setq n (1+ n)
nextvp (strcat (cdr (assoc 2 x)) "\n")
)
(setq vplist (insrt nextvp vplist))
(setq x (tblnext "vport"))
)
(if (= n 0) (princ "-None-" dfile)
(foreach N vplist (princ N dfile))
)
(princ "\n\n" dfile)
)
(defun appid ( / n x na ll ur v)
(princ "\nApplication ID (Xdata)\n" dfile)
(setq n 0)
(setq x (tblnext "appid" T))
(setq aplist nil)
(while x
(setq n (1+ n)
nextap (strcat (cdr (assoc 2 x)) "\n")
)
(setq aplist (insrt nextap aplist))
(setq x (tblnext "appid"))
)
(if (= n 0) (princ "-None-" dfile)
(foreach N aplist (princ N dfile))
)
(princ "\n\n" dfile)
)
(defun dimsty ( / n x na ll ur v)
(princ "\nDimension Styles\n" dfile)
(setq n 0)
(setq x (tblnext "dimstyle" T))
(setq dstylist nil)
(while x
(setq n (1+ n)
nextdsty (strcat (cdr (assoc 2 x)) "\n")
)
(setq dstylist (insrt nextdsty dstylist))
(setq x (tblnext "dimstyle"))
)
(if (= n 0) (princ "-None-" dfile)
(foreach N dstylist (princ N dfile))
)
(princ "\n\n" dfile)
)
;;; Return the value associated with a particular entity field
(defun fld (num lst)
(cdr (assoc num lst))
)
(defun C:PWRdoc (/ olderr ocmd oblp)
(setq olderr *error*
*error* myerror
)
(setq ocmd (getvar "cmdecho"))
(setq oblp (getvar "blipmode"))
(setvar "cmdecho" 0)
(setvar "regenmode" 0)
(setq dn (getvar "dwgname"))
(setq dir (getvar "dwgprefix"))
(setq fn (strcat dn ".rec"))
(princ "\nEnter Record File Name: <")
(princ fn)
(setq fname (getstring ">: "))
(if (< (strlen fname) 1) (setq fname fn))
(setq dfile (open fname "w"))
(today)
(princ datestr dfile)
(princ (strcat "\nDrawing Name: " dn) dfile)
(setq fmenu (getvar "menuname"))
(princ (strcat "\nMenu file: " fmenu "\n") dfile)
(layer)
(block)
(style)
(ltype)
(view)
(ucs)
(vport)
(appid)
(dimsty)
(setvar "cmdecho" ocmd)
(setvar "blipmode" oblp)
(setq *error* olderr) ; Restore old *error* handler
(close dfile)
(setq str (strcat "\nDrawing Information saved\nto file: " fname))
(alert str)
(princ "\nPWRdoc Done")
; (startapp "notepad" fname)
(princ)
)
</normalfont>

</normalfont> 
(defun Insrt (Ent Lis) 
 (cond 
  ((null Lis) (list Ent)) 
  ((< Ent (car Lis)) (cons Ent Lis)) 
  (T (cons (car Lis) (Insrt Ent (cdr Lis)))) 
 ) 
) 
(defun today () 
  (setq td (getvar "date")) 
  (setq time (* 86400.0 (- td (setq j (fix td))))) 
  (setq j (- j 1721119.0)) 
  (setq y (fix (/ (1- (* 4 j)) 146097.0))) 
  (setq j (- (* j 4.0) 1.0 (* 146097.0 y))) 
  (setq d (fix (/ j 4.0))) 
  (setq j (fix (/ (+ (* 4.0 d) 3.0) 1461.0))) 
  (setq d (- (+ (* 4.0 d) 3.0) (* 1461.0 j))) 
  (setq d (fix (/ (+ d 4.0) 4.0))) 
  (setq m (fix (/ (- (* 5.0 d) 3) 153.0))) 
  (setq d (- (* 5.0 d) 3.0 (* 153.0 m))) 
  (setq d (fix (/ (+ d 5.0) 5.0))) 
  (setq y (+ (* 100.0 y) j)) 
  (if (< m 10.0) 
  (setq m (+ m 3)) 
   (progn   
   (setq m (- m 9)) 
   (setq y (1+ y)) 
   ) 
  ) 
(setq datestr (strcat "\nToday's Date: "(itoa(fix m)) "/" (itoa(fix d)) "/" (itoa(fix y)))) 
(princ) 
)       
(defun myerror (s)                    ; If an error (such as CTRL-C) occurs 
                                      ; while this command is active... 
  (if (/= s "Function cancelled") 
    (princ (strcat "\nError: " s)) 
  ) 
  (setvar "cmdecho" ocmd)             ; Restore saved modes 
  (setvar "blipmode" oblp) 
  (setq *error* olderr)               ; Restore old *error* handler 
  (princ) 
) 
 
(defun layer ( / c d f ln lt ly n x) 
  (princ (strcat "\nPrinting to file: " fname "...")) 
  (princ "\nLayer Name\tStatus\tOn/Off\tLock\tColor\tLinetype\n" dfile) 
  (setq x (tblnext "layer" T)) 
  (setq lalist nil) 
  (while x 
    (setq 
          ly (cdr (assoc 2 x))          ; layer name 
          ln (cdr (assoc 6 x))          ; linetype name 
          c  (cdr (assoc 62 x))         ; color number 
          f  (cdr (assoc 70 x))         ; "frozen" flag 
          lt (tblsearch "ltype" ln)     ; linetype table entry 
    ) 
 
   (if (= (logand f 1) 1) (setq fstat "Frozen")(setq fstat "Thawed"))   
   (if (= (logand f 4) 4) (setq lstat "Locked")(setq lstat "NO")) 
   (if (< c 0) (setq cstat "Off")(setq cstat "On")) 
    
    (setq nextla 
      (strcat 
        ly "\t"                         ; layer name 
        fstat "\t"                      ; frozen/thawed 
        cstat "\t"                      ; on/off 
        lstat "\t"                      ; locked/unlocked 
        (itoa (abs c)) "\t"             ; color number 
        ln "\n"                         ; linetype name 
      ) 
   ) 
  (setq lalist (Insrt nextla lalist)) 
  (setq x (tblnext "layer")) 
  ) 
  (foreach N lalist (princ N dfile)) 
(princ "\n\n" dfile) 
) 
 
 
;;;  (LTYPE) - Dump the linetype table 
 
(defun ltype ( / a cl d f lt n s x) 
  (princ "\nLinetype Name\n" dfile) 
  (setq ltlist nil) 
  (setq x (tblnext "LTYPE" T)) 
  (while x 
    (setq nextlt 
      (strcat 
        (cdr (assoc 2 x)) "\t" ; linetype name 
        (cdr (assoc 3 x)) "\n" ; linetype description 
      ) 
    ) 
    (setq ltlist (Insrt nextlt ltlist)) 
    (setq x (tblnext "LTYPE"))               ; get next linetype entry 
  ) 
(foreach N ltlist (princ N dfile)) 
(princ "\n\n" dfile) 
) 
 
 
;;;  (VIEW) - Dump the named view table 
 
(defun view ( / c d h n v w x) 
  (princ "\nView Name\n" dfile) 
  (setq x (tblnext "VIEW" T)) 
  (setq n 0) 
  (setq vwlist nil)                   
  (while x 
    (setq n  (1+ n) 
          nextvw  (cdr (assoc 2 x))               ; view name 
    ) 
    (setq vwlist (insrt nextvw vwlist)) 
    (setq x (tblnext  "VIEW" ))               ; get next view entry 
  ) 
 (if (/= n 0) 
     (foreach N vwlist (princ N dfile)) 
     (princ "-None-" dfile) 
 ) 
(princ "\n\n" dfile) 
) 
 
;;;  (STYLE) - Dump the text style table 
 
(defun style ( / cs fb ff g h n o s w x) 
  (princ "\nText Style\tHeight\tWidth\tOblique\tFont\tBigfont\n" dfile) 
  (setq n  0) 
  (setq x (tblnext "style" T)) 
  (setq stylist nil)                  ; get first style 
  (while x 
    (setq n  (1+ n) 
          s  (fld  2 x)               ; style name 
          ff (fld  3 x)               ; primary font file 
          fb (fld  4 x)               ; big font file 
          h  (fld 40 x)               ; height 
          w  (fld 41 x)               ; width factor 
          o  (fld 50 x)               ; obliquing angle 
    ) 
    (setq nextsty 
      (strcat 
        s                      ; edit style name 
        "\t" (rtos h 2 2)      ; height 
        "\t" (rtos w 2 2)      ; width factor 
        "\t" (angtos o 0 2)    ; obliquing angle 
        "\t" ff               ; primary font file 
        "\t" fb  "\n"         ; big font file 
      ) 
    ) 
    (setq stylist (insrt nextsty stylist)) 
    (setq x(tblnext "style"))               ; get next style entry 
  ) 
  (if (= n 0) (princ "-None-" dfile) 
              (foreach N stylist (princ N dfile)) 
   )             
(princ "\n\n" dfile) 
) 
 
 
;;;  (BLOCK) - Dump the block definition table 
 
(defun block ( / b e ec ed et f n o x blklist xreflist nextblk nextxref) 
  (princ "\nBlock Name\tCount\n" dfile) 
  (setq n 0) 
  (setq x (tblnext "block" T)) 
  (setq blklist nil)                   ; get first block definition 
  (while x 
    (setq n  (1+ n) 
          b  (fld  2 x)               ; block name 
          f  (fld 70 x)               ; flags 
    ) 
    ;(if (= (logand f 4) 4)(setq btype "Xref")(setq btype "Block")) 
    ;(if (= btype "Xref")(setq Xpath (fld 1 x))(setq Xpath " ")) 
  (if (/= (logand f 1) 1) 
  (progn 
    (setq PWRss (ssget "X" (list (cons 2 b))))    
    (if pwrss (setq bcount (sslength pwrss))(setq bcount 0)) 
     (if (= (logand f 4) 4) 
       (progn 
       (setq nextxref (strcat b "\t" (itoa bcount) "\t" (fld 1 x) "\n")) 
       (setq xreflist (insrt nextxref xreflist)) 
       ) 
       (progn 
       (setq nextblk (strcat b "\t" (itoa bcount) "\n")) 
       (setq blklist (insrt nextblk blklist)) 
       ) 
     ) 
   ) 
   ) 
   (setq x (tblnext "block")) 
  ) 
  (if (= n 0) (princ "-None-" dfile) 
              (foreach N blklist (princ N dfile)) 
  )             
  (princ "\n\nXrefs\tCount\tPath\n" dfile) 
  (if (= n 0) (princ "-None-" dfile) 
              (foreach N xreflist (princ N dfile)) 
  )             
(princ "\n\n" dfile) 
) 
 
;;;  (UCS) - Dump the UCS table 
 
(defun ucs ( / n x na o xd yd) 
  (princ "\nUCS Name\n" dfile) 
  (setq n  0) 
  (setq x (tblnext "ucs" T)) 
  (setq ucslist nil)                   
  (while x 
    (setq n  (1+ n) 
          nextucs (strcat (cdr (assoc 2 x)) "\n") 
    ) 
    (setq ucslist (insrt nextucs ucslist)) 
    (setq x (tblnext "ucs"))                
  ) 
(if (= n 0) (princ "-None-" dfile) 
            (foreach N ucslist (princ N dfile)) 
) 
(princ "\n\n" dfile) 
) 
 
;;;  (VPORT) - Dump the viewport table 
 
(defun vport ( / n x na ll ur v) 
  (princ "\nViewport Name\n" dfile) 
  (setq n  0) 
  (setq x  (tblnext "vport" T))            
  (setq vplist nil) 
  (while x 
    (setq n  (1+ n) 
          nextvp (strcat (cdr (assoc 2 x)) "\n")                
    ) 
    (setq vplist (insrt nextvp vplist)) 
    (setq x (tblnext "vport"))         
  ) 
  (if (= n 0) (princ "-None-" dfile) 
            (foreach N vplist (princ N dfile)) 
  ) 
(princ "\n\n" dfile) 
) 
 
(defun appid ( / n x na ll ur v) 
  (princ "\nApplication ID (Xdata)\n" dfile) 
  (setq n  0) 
  (setq x  (tblnext "appid" T))            
  (setq aplist nil) 
  (while x 
    (setq n  (1+ n) 
          nextap (strcat (cdr (assoc 2 x)) "\n")                
    ) 
    (setq aplist (insrt nextap aplist)) 
    (setq x (tblnext "appid"))         
  ) 
  (if (= n 0) (princ "-None-" dfile) 
            (foreach N aplist (princ N dfile)) 
  ) 
(princ "\n\n" dfile) 
) 
 
 
(defun dimsty ( / n x na ll ur v) 
  (princ "\nDimension Styles\n" dfile) 
  (setq n  0) 
  (setq x  (tblnext "dimstyle" T))            
  (setq dstylist nil) 
  (while x 
    (setq n  (1+ n) 
          nextdsty (strcat (cdr (assoc 2 x)) "\n")                
    ) 
    (setq dstylist (insrt nextdsty dstylist)) 
    (setq x (tblnext "dimstyle"))         
  ) 
  (if (= n 0) (princ "-None-" dfile) 
            (foreach N dstylist (princ N dfile)) 
  ) 
(princ "\n\n" dfile) 
) 
 
;;;  Return the value associated with a particular entity field 
 
(defun fld (num lst) 
  (cdr (assoc num lst)) 
) 
 
(defun C:PWRdoc (/ olderr ocmd oblp) 
  (setq olderr  *error* 
        *error* myerror 
  ) 
  (setq ocmd (getvar "cmdecho")) 
  (setq oblp (getvar "blipmode")) 
  (setvar "cmdecho" 0) 
  (setvar "regenmode" 0) 
  (setq dn (getvar "dwgname")) 
  (setq dir (getvar "dwgprefix")) 
  (setq fn (strcat dn ".rec")) 
  (princ "\nEnter Record File Name: <") 
  (princ fn) 
  (setq fname (getstring ">: ")) 
  (if (< (strlen fname) 1) (setq fname fn)) 
  (setq dfile (open fname "w")) 
  (today) 
  (princ datestr dfile) 
  (princ (strcat "\nDrawing Name: " dn) dfile) 
  (setq fmenu (getvar "menuname")) 
  (princ (strcat "\nMenu file: " fmenu "\n") dfile) 
  (layer) 
  (block) 
  (style) 
  (ltype) 
  (view) 
  (ucs) 
  (vport) 
  (appid) 
  (dimsty) 
  (setvar "cmdecho" ocmd) 
  (setvar "blipmode" oblp) 
  (setq *error* olderr)               ; Restore old *error* handler 
  (close dfile) 
  (setq str (strcat "\nDrawing Information saved\nto file: " fname)) 
  (alert str) 
  (princ "\nPWRdoc Done") 
;  (startapp "notepad" fname) 
  (princ) 
) 
</normalfont>

tuger · 发表于 2003-5-12 23:46:10

用ai_table 这个函数就可以了，
(load "ai_utils.lsp")
(setq table_list (ai_table "block" 14))
返回的table_list就是图中所有块的名称列表。
ai_utils.lsp这个文件在r14的support目录下有，

jianqiang21c · 发表于 2003-5-13 12:01:48

tuger真是爱死你了：）

newer · 发表于 2003-5-13 12:34:06

最初由 jianqiang21c 发布
[B]tuger真是爱死你了：） [/B]

mm,怎么连谢谢都不说啊，我可是第一个回答你的啊，以后不帮你了，都是写程序的人，差距怎么就那么大呢。

jianqiang21c · 发表于 2003-5-13 13:37:18

newer GG实在对不起，这只能怪CUTEE 了，写了那么长看的头皮都麻，造成可视距离下降，千万别不帮我呀：），在次只能表示严重的歉意（还有青铜长老袄），和最沉痛的遗憾~~~~~~
鸣谢赞助商XDCAD提供这次道歉的场所

账号		自动登录	找回密码
密码			立即注册

[求助] [求助]：什么函数可以得到全部块的块名？

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子

Re: [求助]：什么函数可以得到全部块的块名？

Re: [求助]：什么函数可以得到全部块的块名？