[LISP程序]：请问高手一个问题，关于视口的打开与关闭的。

userzhluserzhl · 发表于 2006-4-1 22:56:19

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

请问高手一个问题，关于视口的打开与关闭的，我要孤立（只显示某个视口）和打开视，哪位高手能搞定？

ewenhui · 发表于 2006-4-2 16:05:23

用docbar（视口切换）

userzhluserzhl · 发表于 2006-4-2 20:43:22

楼上，我想你没有理解我的意思，我说的“视口”是在一个图纸空间中的不同的视口，而不是不同文件不同的视窗。你说的Docbar 我早就用过了。

雨箭风刀 · 发表于 2006-4-2 22:56:34

ActivePViewport 属性

指定图形中活动的图纸空间视口。
参阅 | 示例
语法
object.ActivePViewport
object
Document
使用该属性的对象。
ActivePViewport
PViewport 对象; 可读写
活动的图纸空间视口。
说明
视口必须首先使用该属性将其设为活动，这样才能看到该视口的任何修改。

eachy · 发表于 2006-4-2 23:05:01

先用 vports -〉off 视口，然后将视口线隐藏

userzhluserzhl · 发表于 2006-4-2 23:24:57

楼上，我想的是——我要孤立“我所选的”（只显示所选取的视口）和打开所有视口（不需要选取），不知怎么弄，还望指点。

eachy · 发表于 2006-4-3 09:39:12

没有优化，能用

;;written by eachy 2006.04.03
;; 隔离视口
(vl-load-com)
(defun c:tt (/ e el ss ssl i e1 el1 ha handle)
(if (and (setq e (car (entsel)))
(= (cdr (assoc 0 (setq el (entget e)))) "VIEWPORT")
(setq handle (cdr (assoc 5 el)))
)
(progn
(if (setq ss (ssget "x" '((0 . "viewport"))))
(progn
(setq ssl (sslength ss)
i -1
)
(repeat ssl
(setq e1 (ssname ss (setq i (1+ i)))
el1 (entget e1)
ha (cdr (assoc 5 el1))
)
(if (/= ha handle)
(progn
(command ".vports" "off" e1 "")
(vl-catch-all-apply
'vla-put-visible
(list (vlax-ename->vla-object e1)
:vlax-false
)
)
)
)
)
)
)
)
)
(princ)
)
;;显示全部视口
(defun c:t1 (/ ss ssl i e)
(if (setq ss (ssget "X" '((0 . "viewport"))))
(progn
(setq ssl (sslength ss)
i -1
)
(repeat ssl
(vla-put-visible
(vlax-ename->vla-object
(setq e (ssname ss (setq i (1+ i))))
)
:vlax-true
)
(command ".vports" "on" e "")
)
)
)
(princ)
)

;;written by eachy 2006.04.03 
;; 隔离视口 
(vl-load-com) 
(defun c:tt (/ e el ss ssl i e1 el1 ha handle) 
  (if (and (setq e (car (entsel))) 
           (= (cdr (assoc 0 (setq el (entget e)))) "VIEWPORT") 
           (setq handle (cdr (assoc 5 el))) 
      ) 
    (progn 
      (if (setq ss (ssget "x" '((0 . "viewport")))) 
        (progn 
          (setq        ssl (sslength ss) 
                i   -1 
          ) 
          (repeat ssl 
            (setq e1  (ssname ss (setq i (1+ i))) 
                  el1 (entget e1) 
                  ha  (cdr (assoc 5 el1)) 
            ) 
            (if        (/= ha handle) 
              (progn 
                (command ".vports" "off" e1 "") 
                (vl-catch-all-apply 
                  'vla-put-visible 
                  (list        (vlax-ename->vla-object e1) 
                        :vlax-false 
                  ) 
                ) 
 
              ) 
            ) 
          ) 
        ) 
      ) 
    ) 
  ) 
  (princ) 
) 
;;显示全部视口 
(defun c:t1 (/ ss ssl i e) 
  (if (setq ss (ssget "X" '((0 . "viewport")))) 
    (progn 
      (setq ssl        (sslength ss) 
            i        -1 
      ) 
      (repeat ssl 
        (vla-put-visible 
          (vlax-ename->vla-object 
            (setq e (ssname ss (setq i (1+ i)))) 
          ) 
          :vlax-true 
        ) 
        (command ".vports" "on" e "") 
      ) 
    ) 
  ) 
  (princ) 
)

userzhluserzhl · 发表于 2006-4-3 10:23:28

非常感谢eachy 斑竹！试试再说。

eachy · 发表于 2006-4-3 11:48:54

;;written by eachy from [url]www.xdcad.net[/url] 2006.04.03
;;仅处理当前 Layout 内的 Viewport
(vl-load-com)
(setvar "cmdecho" 0)
;;视口隔离
(defun c:LayoutISO (/ e el thisdrawing layout ss ssl i l1 lobj handle)
(if (and (= (getvar "tilemode") 0)
(setq e (car (entsel "\nPick Viewport Edge: ")))
(= (cdr (assoc 0 (setq el (entget e)))) "VIEWPORT")
)
(progn
(setq thisdrawing (vla-get-activedocument (vlax-get-acad-object))
layout (vla-get-name (vla-get-activelayout thisdrawing))
handle (assoc 5 el)
)
(if (setq ss (ssget "x" (list '(0 . "viewport") (cons 410 layout))))
(progn
(setq ssl (sslength ss)
i -1
)
(repeat ssl
(setq l1 (ssname ss (setq i (1+ i)))
lobj (vlax-ename->vla-object l1)
)
(if (not (equal (assoc 5 (entget l1)) handle))
(progn
(if (= (vla-get-visible lobj) :vlax-false)
(vla-put-visible lobj :vlax-true)
)
(command ".vports" "off" l1 "")
(vla-put-visible lobj :vlax-false)
)
)
)
)
)
)
)
(princ)
)
;;显示全部视口
(defun c:LayoutOn (/ thisdrawing layout ss ssl i e)
(setq thisdrawing (vla-get-activedocument (vlax-get-acad-object))
layout (vla-get-name (vla-get-activelayout thisdrawing))
)
(if (setq ss (ssget "x" (list '(0 . "viewport") (cons 410 layout))))
(progn
(setq ssl (sslength ss)
i -1
)
(repeat ssl
(setq e (ssname ss (setq i (1+ i))))
(vla-put-visible (vlax-ename->vla-object e) :vlax-true)
(command ".vports" "on" e "")
)
)
)
(princ)
)

;;written by eachy from [url]www.xdcad.net[/url]  2006.04.03 
;;仅处理当前 Layout 内的 Viewport 
(vl-load-com) 
(setvar "cmdecho" 0) 
;;视口隔离 
(defun c:LayoutISO (/ e el thisdrawing layout ss ssl i l1 lobj handle) 
  (if (and (= (getvar "tilemode") 0) 
           (setq e (car (entsel "\nPick Viewport Edge: "))) 
           (= (cdr (assoc 0 (setq el (entget e)))) "VIEWPORT") 
      ) 
    (progn 
      (setq thisdrawing        (vla-get-activedocument (vlax-get-acad-object)) 
            layout        (vla-get-name (vla-get-activelayout thisdrawing)) 
            handle        (assoc 5 el) 
      ) 
      (if (setq ss (ssget "x" (list '(0 . "viewport") (cons 410 layout)))) 
        (progn 
          (setq        ssl (sslength ss) 
                i   -1 
          ) 
          (repeat ssl 
            (setq l1   (ssname ss (setq i (1+ i))) 
                  lobj (vlax-ename->vla-object l1) 
            ) 
            (if        (not (equal (assoc 5 (entget l1)) handle)) 
              (progn 
                (if (= (vla-get-visible lobj) :vlax-false) 
                  (vla-put-visible lobj :vlax-true) 
                ) 
                (command ".vports" "off" l1 "") 
                (vla-put-visible lobj :vlax-false) 
              ) 
            ) 
          ) 
        ) 
      ) 
    ) 
  ) 
  (princ) 
) 
;;显示全部视口 
(defun c:LayoutOn (/ thisdrawing layout ss ssl i e) 
  (setq        thisdrawing (vla-get-activedocument (vlax-get-acad-object)) 
        layout            (vla-get-name (vla-get-activelayout thisdrawing)) 
  ) 
  (if (setq ss (ssget "x" (list '(0 . "viewport") (cons 410 layout)))) 
    (progn 
      (setq ssl        (sslength ss) 
            i        -1 
      ) 
      (repeat ssl 
        (setq e (ssname ss (setq i (1+ i)))) 
        (vla-put-visible (vlax-ename->vla-object e) :vlax-true) 
        (command ".vports" "on" e "") 
      ) 
    ) 
  ) 
  (princ) 
)

账号		自动登录	找回密码
密码			立即注册

[LISP程序]：请问高手一个问题，关于视口的打开与关闭的。

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子

浏览过的版块