[编程申请]：将选中的LINE直线两端各缩短150mm

lengliqun · 发表于 2006-5-25 09:25:05

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

求LSP程序，将选中的LINE直线两端各缩短150mm（希望能同时框选多条直线）。谢谢

yshf · 发表于 2006-5-25 12:41:05

请试用以下程序：

(Defun c:test()
(setq dd (getdist "\n缩短距离(以毫米为单位)<150mm>:")
p1 (getpoint "\n左上角点:")
p2 (getcorner p1 "\n右下角点:")
)
(if (= dd nil)(setq dd 150.0))
(if (setq ssa (ssget "w" p1 p2 '((0 . "LINE"))))
(progn
(setq i 0)
(repeat (sslength ssa)
(setq dxf (entget (ssname ssa i))
p10 (cdr (assoc 10 dxf))
p11 (cdr (assoc 11 dxf))
ang (angle p10 p11)
pt1 (polar p10 ang (/ dd 1000.0))
pt2 (polar p11 (+ ang pi) (/ dd 1000.0))
dxf (subst (cons 10 pt1) (assoc 10 dxf) dxf)
dxf (subst (cons 11 pt2) (assoc 11 dxf) dxf)
i (1+ i)
)
(entmod dxf)
)
)
)
(princ)
)

lengliqun · 发表于 2006-5-25 13:06:06

经cad2004测试，yshf大侠的LSP程序可用。

雨箭风刀 · 发表于 2006-5-25 15:04:48

[php]
;; spline仅支持缩短，ellipse和arc当延伸长度超过周期，不改变。
(Defun c:lenx(/ dd i ss a b)
(princ "\n 双向延伸曲线长度(支持*line,arc,ellipse)----by 雨箭风刀.2006.5")
(if (not *lenx)(setq *lenx 0.0))
(princ "\n双向延伸距离(负值缩短)<")(princ *lenx)
(setq dd (getdist ">:"))
(if dd (setq *lenx dd))
(if (setq i -1 ss (ssget '((0 . "*LINE,ELLIPSE,ARC"))))
   (while (setq e (ssname ss (setq i (1+ i))))
      (setq a (vlax-curve-getstartpoint e)
            b (vlax-curve-getendpoint e))
      (command ".lengthen" "de" *lenx (list e a)(list e b)"")
      )
)
(princ)
)
[/php]

xyp1964 · 发表于 2006-5-25 21:50:14

2楼：
(/ dd 1000.0)
没有道理也没有必要！

[FONT=courier new](defun c:test ()
(CMDLA0)
(if (null dist)
(setq dist 150.0)
)
(setq DIST (UDIST 1 "" "\n输入两端要缩短的距离<或直接量取>" DIST nil)
ss (ssget '((0 . "LINE")))
i -1
)
(while (setq s1 (ssname ss (setq i (1+ i))))
(if (> (xyp-get-CurveLength s1) (* DIST 2.0))
(progn
(setq p0 (xyp-get-dxf 10 s1)
p1 (xyp-get-dxf 11 s1)
ang (angle p0 p1)
)
(xyp-SUBUPD s1 10 (polar p0 ang dist))
(xyp-SUBUPD s1 11 (polar p1 ang (* dist -1.0)))
)
)
)
(CMDLA1)
)[/FONT]

yshf · 发表于 2006-5-26 07:51:14

请问xyp1964：以米为单位绘图，现在输入的是毫米，该如何处理？

yjh0123 · 发表于 2006-5-26 09:53:31

支持看来要好学下lisp编程

lengliqun · 发表于 2006-5-28 08:34:45

经cad2004测试，雨箭风刀的LSP程序可用。谢谢。

经cad2004测试，xyp1964 斑竹的LSP程序可用。谢谢。

xyp1964 · 发表于 2006-5-28 09:38:33

最初由 yshf 发布
[B]请问xyp1964：以米为单位绘图，现在输入的是毫米，该如何处理？ [/B]

当“以米为单位绘图，现在输入的是毫米”时，确实要(/ dd 1000.0)，不过帖子的主题没有这个限定，有了这个限定反而受约束。
问题：
当线长小于2×150时，线没有缩短反而加长了。

hzzhao · 发表于 2006-6-3 16:09:49

都可以用啊

yangist · 发表于 2013-6-9 17:26:24

我已经有LE~~~~~~~

账号		自动登录	找回密码
密码			立即注册

[编程申请]：将选中的LINE直线两端各缩短150mm

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子