[LISP函数]：一个关于LISP的问题

madbull

在R2000＋版中，CAD可以把一个LISP编写的非系统命令变为系统命令。方法是：在最后一行(princ)之前加入(vlax-add-cmd "3darray" 'c:3darray)－－以3darray为例。据此，我编写了一个基于系统命令的LISP：(DEFUN C:3AR () (COMMAND "3DARRAY" "L" "" "R"))用来“三维阵列最后一个物体”。但是我奇怪的发现，只有先运行3darray命令之后，3AR命令才好使。这是为什么？怎样避免这种情况？

aeo

3darray不是基本命令.要先load (在support中3darray.lsp)
(DEFUN C:3AR () (load "3darray")(c:3DARRAY))     ;不带参数

要完成你的意思(DEFUN C:3AR () (COMMAND "3DARRAY" "L" "" "R"))
应该要这样写:

2. 
   
3. (DEFUN C:3AR ( / ss)(load "3darray")(setq ss(ssget "l"))(r-ARRAY))
   

<br /> (DEFUN C:3AR ( / ss)(load "3darray")(setq ss(ssget "l"))(r-ARRAY))<br />

madbull

aeo，谢谢，您的办法是好使的。但是我还有一个问题：把(DEFUN C:3AR ( / ss)(load "3darray")(setq ss(ssget "l"))(r-ARRAY))与3darray放在一个LISP文件中就不好使了，这是为什么？是不是(DEFUN C:3AR ( / ss)(load "3darray")(setq ss(ssget "l"))(r-ARRAY))与3darray只有放在两个文件中，3AR命令才能及时起作用？

aeo

放一个文件中也行,但要先加载.
其实点菜单命令,里面也先加载的.
最简单的办法是把这句话加到acad2000doc.lsp中.
在cad的support里.
用其他软件时可能不行.要找路径的第一个acad2000doc.lsp.

madbull

对不起，我还是不明白。是把(DEFUN C:3AR ( / ss)(load "3darray")(setq ss(ssget "l"))(r-ARRAY))这一句写在acad2000doc.lsp里吗？
实际情况是这样的：我有一段LISP，改线宽的。
;; This version of changing width and thickness routine depends on visual lisp support.
;; CWCT.LSP
;; Written by Qiu Feng, Zhejiang University. 2000

(if (car (atoms-family 1 '("vl-load-com")))
  (vl-load-com)
)

(defun cw_ucs_2_ent (p1 /)
  (setq p1 (strcat "*"
     (rtos (car p1) 1 20)
     ","
     (rtos (cadr p1) 1 20)
     ","
     (rtos (caddr p1) 1 20)
    )
  )
  (command "_.ucs" "_za" "*0.0,0.0,0.0" p1)
)

;; Change Width of Polyline
;; Support:
;; line, arc, circle, polyline, lightweightpolyline
(defun C:xw
       (/ i ss sslen obj pt cenpt thick width ucsicon rad entname lay)
  (setq ss (ssget))
  (if (null ss)
    (exit)
  )
  (setq i     0
sslen (sslength ss)
  )

  (if (null cw-width-save)
    (progn    ;then
      (setq width (getdist "\nNew Width:"))
      (while (null width) (setq width (getdist "\nNew Width:")))
    )
    (setq width
    (getdist (strcat "\nNew Width<" (rtos cw-width-save 2) ">:")
    )
    )
  )
  (if width
    (setq cw-width-save width)
  )
  (if (and cw-width-save (null width))
    (setq width cw-width-save)
  )

  (setvar "cmdecho" 0)
  (command "_.UNDO" "Auto" "off")
  (command "_.UNDO" "_GROUP")
  (setq ucsicon (getvar "ucsicon"))
  (setvar "ucsicon" 0)

  (while (< i (sslength ss))
    (setq entname (ssname ss i))
    (setq obj (vlax-ename->vla-object entname))

     ; change lines and arcs to polyline
    (if (or (= "AcDbLine" (vla-get-objectname obj))
     (= "AcDbArc" (vla-get-objectname obj))
)
      (progn
(setq pt (vlax-safearray->list
     (vlax-variant-value (vla-get-normal obj))
   )
)
(cw_ucs_2_ent pt)
(setq thick (vla-get-thickness obj))
(command "_.pedit" entname "Y" "")
(command "_.ucs" "_p")
(setq obj (vlax-ename->vla-object (entlast)))
(vla-put-thickness obj thick)
      )
    )

     ; change circle to polyline
    (if (= "AcDbCircle" (vla-get-objectname obj))
      (progn
(setq cenpt (vla-get-center obj)
       rad   (vla-get-radius obj)
       thick (vla-get-thickness obj)
       lay   (vla-get-layer obj)
)
(setq cenpt (vlax-safearray->list (vlax-variant-value cenpt)))
(setq pt (vlax-safearray->list
     (vlax-variant-value (vla-get-normal obj))
   )
)
(cw_ucs_2_ent pt)
(setq cenpt (trans cenpt 0 1))
(command "_.donut" (* 2 rad) (* 2 rad) "_non" cenpt "")
(vla-delete obj)
(command "_.ucs" "_p")
(setq obj (vlax-ename->vla-object (entlast)))
(vla-put-thickness obj thick)
(vla-put-layer obj lay)
      )
    )

     ; change polylines width
    (if (member (vla-get-objectname obj)
  '("AcDbPolyline" "AcDb2dPolyline")
)
      (vla-put-constantwidth obj width)
    )
    (setq i (1+ i))
  )

  (setvar "ucsicon" ucsicon)
  (setvar "cmdecho" 0)
  (command "_.UNDO" "END")
  (setvar "cmdecho" 1)
  (vlax-add-cmd "xw" 'c:xw)
  (princ)
)
我想象上个帖子中设置3AR命令一样，设置一个XWW命令。仿照您的东东，我是这样改的：(DEFUN C:XWW( / ss)(load "xw")(setq ss(ssget "l"))
但是我发现还是必需的先加载XW命令（这两个命令－XW与XWW－处于同一个LISP文件中）。
我该怎么办？

aeo

看来你要稍微学一下lisp了:)
说不明白的.
上面的,你要xww最后的一个实体:
把这个文件的:
(defun C:xw
(/ i ss sslen obj pt cenpt thick width ucsicon rad entname lay)
(setq ss (ssget))
(if (null ss)
(exit)
)
其中(setq ss (ssget))改为(setq  ss(ssget "L"))
把C:xw改为C:xww
存成另一个文件.和用这个文件一样,加载,xww就是你要的

madbull

对不起，我把您问烦了吧！！
谢谢您耐心的解答。回头有时间，我一定找两本LISP的书好好看看。