[求助]：怎么获得文本的端点坐标

fengjianwei

怎么获得文本的端点坐标 左端点、右端点、中心坐标

雨箭风刀

用textbox

fengjianwei

textbox返回的坐标是相对的 不是真实的坐标

TYEEXDD

用（ENTGET），有些点可能需要计算

lidejun_55

晓东有这个函数

xyp1964

[php]
语法
(xyp-get-MinMaxPoint sname mode)

功能及参数
功能：此函数取得实体最小外接矩形的九点坐标。
参数：sname为实体名；mode参数＝1～9，上中下9位码；其他均为左下角点。

返回值：点表

;;;指定对象最小外接矩形的九点坐标
;;;mode＝1～9，上中下9位码；其他均为左下角点
;;; 7        8         9
;;;  ------------------
;;;  |                |
;;;  |                |
;;;  |                |
;;; 4|       5        |6
;;;  |                |
;;;  |                |
;;;  |                |
;;;  ------------------
;;; 1        2         3


范例

;;;图中所有对象在窗口中央逐一显示（按任意键显示下一对象）
(defun c:test ()
  (CMDLA0)
  (setvar "osmode" 0)
  (command "select" "all" "")
  (setq        ss (ssget "P")
        i  -1
  )
  (while (setq s1 (ssname ss (setq i (1+ i))))
    (setq pt1 (xyp-get-MinMaxPoint s1 1)
          pt9 (xyp-get-MinMaxPoint s1 9)
    )
    (command "zoom" "w" pt1 pt9)
    (princ "\n按任意键显示下一对象，ESC退出! ")
    (setq ukw t)
    (while ukw
      (setq MOTION (grread t 15 0)
            CODE   (car MOTION)
      )
      (if (or (= code 2)
              (= code 3)
              (= code 25)
          )
        (setq ukw nil)
      )
    )
  )
  (CMDLA1)
)


源码

(defun xyp-get-MinMaxPoint (ename  mode          /         pointmax      pointmin
                            dx           dy          pt1         pt2        pt3    pt4
                            pt5           pt6          pt7         pt8        pt9    point
                           )
  (vla-getboundingbox
    (vlax-ename->vla-object ename)
    'minpoint
    'maxpoint
  )
  (setq        pointmax (vlax-safearray->list maxpoint)
        pointmin (vlax-safearray->list minpoint)
        dx         (/ (- (car pointmax) (car pointmin)) 2.0)
        dy         (/ (- (cadr pointmax) (cadr pointmin)) 2.0)
        pt1         pointmin
        pt2         (polar pt1 0 dx)
        pt3         (polar pt2 0 dx)
        pt4         (polar pt1 (* pi 0.5) dy)
        pt5         (polar pt4 0 dx)
        pt6         (polar pt5 0 dx)
        pt7         (polar pt4 (* pi 0.5) dy)
        pt8         (polar pt7 0 dx)
        pt9         pointmax
  )
  (cond        ((= mode 1) (setq point pt1))
        ((= mode 2) (setq point pt2))
        ((= mode 3) (setq point pt3))
        ((= mode 4) (setq point pt4))
        ((= mode 5) (setq point pt5))
        ((= mode 6) (setq point pt6))
        ((= mode 7) (setq point pt7))
        ((= mode 8) (setq point pt8))
        ((= mode 9) (setq point pt9))
        (t (setq point pt1))
  )
  point
)
[/php]

m123456

长见识,谢了

phoenixdjq

文字的群码中的插入点就是端点
群码的号，好像是10

fengjianwei

真是高手啊

chenjian1

;;;取得文字符串 text-name 的参数子程序
(defun sub-get-text-data (text-name)
  (setq text-data (entget text-name))
  (setq textbasept (cdr (assoc 10 text-data))) ; 取得字符串位置
  (setq textbasept (trans textbasept 0 1)) ;转为ucs
  (setq texthight (cdr (assoc 40 text-data))) ; 取得字符串高度
  (setq txt (cdr (assoc 1 text-data)))        ; 取得字符串内容
  (setq txtsty (cdr (assoc 7 text-data))) ; 取得字符串样式
  (setq txtlen (strlen txt))                ; 取得字符串长度
  (setq txt1 (substr txt 1 1))                ; 取得字符串子串1
  (if (> txtlen 1)
    (setq txt12 (substr txt 1 2))        ; 取得字符串子串12
  )
  (if (> txtlen 2)
    (setq txt3 (substr txt 3 1))        ; 取得字符串子串3
  )
  (if (> txtlen 3)
    (setq txt4 (substr txt 4 1))        ; 取得字符串子串4
  )
  (if (> txtlen 4)
    (setq txt5 (substr txt 5 1))        ; 取得字符串子串5
  )
  (if (> txtlen 5)
    (setq txt6 (substr txt 6 (- txtlen 5))) ; 取得字符串子串6及以后
  )
)