[求助]：怎样看透视

madbull

zhynt  兄说得对,第二种情况的确是CAD对问题.重装CAD之后,问题解决了.
第一种情况,在运行之前,我已经输入了焦距,但问题依旧.期待您改进这个BUG.
顺便说一句:我用的是R2002版.

madbull

zhynt兄,今天有时间,我又试了一下您改编的LSp.我发现在R14版本中,您改编的文件是完全好使的,但是在R2000以上版本时则会出现我所发现的问题。这可能与我提供的源文件有关－－11.LSP本来就取自天正3。不过我相信zhynt兄有能力处理好这个BUG。
另外，今天我还试了一下天正5中的透视功能，很不错，比较天正3又有了很大的改进。但是很遗憾，我没有找到相应的LSP文件，否则也许对您会有所帮助。不过，我发现天正5中的LSP文件都没有像天正3的LSP文件那样进行加密，然而选取其中的命令在天正5中执行却不好使（我的意思是说：比如我在其中的一个LSP文件中找到(defun c:chwin 这样一行文字，我把chwin拷贝下来，粘贴在天正5的命令行执行，却被认为是“未知命令”）。小弟道行甚浅，不解其中缘由，请大侠们指交一二。不求学得解密要领，但求增长知识。谢谢！！

zhynt

我今天又试了一下，却没有发现上述问题，真是奇怪。再有就是天正５有些命令使用了天正实体，在没有天正时是无法运行的，这个我也没有办法。抱歉。

madbull

zhynt 兄,我在R2002和R2004版中还是遇到了"透视图只能看到局部"的问题.
我猜想也许是相机点定位的问题吧.
麻烦您有时间在测试,改进一下,好吗?
求您了.

zhynt

暂时的解决方法是用ｄｖｉｅｗ命令：
dview回车
all回车
d回车
用鼠标调整距离。

eachy

这样试试，Lisp文件。Dpan命令无效，Dzoom命令输入整数或小数，缩小时不可省略0，如 0.5  0.6 ...
[php]
;(_@ld "wzqlib3d")
;(_@ld "dcllib")
(defun rs_error ()
  (set_tile "error" "")
)
(defun c:qview (/ lens z_cm z_tg tf_vp2 p_cm p_tg do_save do_lens_list
                  do_vp2 lens_list wzq wx is_sv_vw vw_name do_sv_vw
                  do_preview
               )
  (defun do_save ()
    (if (or
          (not p_cm)
          (not p_tg)
        )
      (progn
        (set_tile "error" "相机/目标位置未定义")
        (mode_tile "position" 2)
      )
      (progn
        (setq lens (distof (get_tile "lens"))
              z_cm (distof (get_tile "z_cm"))
              z_tg (distof (get_tile "z_tg"))
              tf_vp2 (get_tile "tf_vp2")
              tf_vp2 (= tf_vp2 "1")
              _lt_view (list lens z_cm z_tg tf_vp2 p_cm p_tg is_sv_vw
                             vw_name
                       )
        )
        (done_dialog 1)
      )
    )
  )
  (defun do_lens_list (reason value / data)
    (if (= 1 reason)
      (progn
        (setq data (nth (read value) lens_list)
              lens (read data)
        )
        (set_tile "lens" data)
      )
    )
  )
  (defun do_vp2 ()
    (setq tf_vp2 (= (get_tile "tf_vp2") "1"))
    (mode_tile "z_tg" (if tf_vp2
                        1
                        0
                      )
    )
  )
  (defun do_pick (/ wzq)
    (command ".ucs" "_w")
    (if (not (equal (getvar "viewdir") '(0 0 1) 1e-4))
      (progn
        (command ".plan" "_w")
        (setq wzq (getvar "viewsize"))
        (setq wzq (* 0.5 (min
                           1.0
                           (/ wzq (* 3 (caddr (getvar "extmax"))))
                         )
                  )
        )
        (setq wzq (strcat (rtos wzq 2 2) "X"))
        (command ".zoom" wzq)
      )
    )
    (if (or
          (not p_cm)
          (not p_tg)
        )
      (progn
        (setq p_cm (getpoint "\n请点取相机位置: "))
        (setq p_tg (getpoint p_cm "\n点取目标点: "))
      )
      (progn
        (grdraw p_cm p_tg 1 1)
        (setq wzq (getpoint "\n请点取相机位置 <上次值>: "))
        (if wzq
          (setq p_cm wzq
                p_tg (getpoint p_cm "\n点取目标点: ")
          )
        )
      )
    )
  )
  (defun do_sv_vw ()
    (mode_tile "vw_name" (if (= is_sv_vw "1")
                           0
                           1
                         )
    )
  )
  (defun do_vw (/ wx)
    (setq wx $value)
    (if (tblsearch "VIEW" wx)
      (progn
        (if (not (new_dialog "vw_cfm" _tde_id))
          (exit)
        )
        (if (= (start_dialog) 0)
          (mode_tile "vw_name" 2)
          (setq vw_name wx)
        )
      )
      (setq vw_name wx)
    )
  )
  (defun do_preview ()
    (if (or
          (not p_cm)
          (not p_tg)
        )
      (do_pick)
    )
    (if tf_vp2
      (setq z_tg z_cm)
    )
    (setq p_cm (list (car p_cm) (cadr p_cm) z_cm))
    (setq p_tg (list (car p_tg) (cadr p_tg) z_tg))
    (command ".DVIEW" "" "_D" 1.0 "_Z" lens "_PO" p_tg p_cm "_x")
  )
  (command ".VIEW" "_S" "_begin")
  (if (not (= 1 (boole 1 1 (getvar "viewmode"))))
    (progn
      (setq wzq (getvar "EXPERT"))
      (setvar "EXPERT" 4)
      (command ".view" "_s" "_TCHTMP")
      (setvar "EXPERT" wzq)
    )
  )
  (if _lt_view
    (mapcar 'set '(lens z_cm z_tg tf_vp2 p_cm p_tg is_sv_vw vw_name) _lt_view)
    (setq lens 18.0
          z_cm 1600.0
          z_tg z_cm
          tf_vp2 T
          is_sv_vw "1"
          vw_name "view1"
    )
  )
  (command ".ucs" "")
  (if (= (getvar "viewmode") 1)
    (setq p_tg (getvar "target")
          p_cm (mapcar'+ p_tg (getvar "viewdir"))
          lens (getvar "lenslength")
          z_cm (caddr p_cm)
          z_tg (caddr p_tg)
          tf_vp2 (equal z_cm z_tg _zro)
    )
  )
  (setq _tde_id (load_dialog "qview.dcl"))
  (setq what_next 5)
  (while (> what_next 2)
    (if (not (new_dialog "qview" _tde_id))
      (exit)
    )
    (setq lens_list (list "18" "28" "35" "50" "70"))
    (start_list "lens_list")
    (mapcar'add_list lens_list)
    (end_list)
    (set_tile "lens" (rtos lens 2 0))
    (set_tile "z_cm" (rtos z_cm))
    (set_tile "z_tg" (rtos z_tg))
    (set_tile "tf_vp2" (if tf_vp2
                         "1"
                         "0"
                       )
    )
    (set_tile "is_sv_vw" is_sv_vw)
    (set_tile "vw_name" vw_name)
    (do_sv_vw)
    (rs_error)
    (if tf_vp2
      (mode_tile "z_tg" 1)
    )
    (action_tile "lens" "(setq lens (distof $value))")
    (action_tile "z_cm" "(setq z_cm (distof $value))")
    (action_tile "z_tg" "(setq z_tg (distof $value))")
    (action_tile "tf_vp2" "(do_vp2)")
    (action_tile "lens_list" "(do_lens_list $reason $value)")
    (action_tile "position" "(done_dialog 3)")
    (action_tile "is_sv_vw" "(progn (setq is_sv_vw $value) (do_sv_vw))")
    (action_tile "vw_name" "(do_vw)")
    (action_tile "preview" "(done_dialog 4)")
    (action_tile "accept" "(do_save)")
    ;(action_tile "help" "(do_help \"QVIEW\")")
    (setq what_next (start_dialog))
    (cond
      ((= what_next 0)
        (command ".VIEW" "_R" "_begin" ".VIEW" "_D" "_begin")
      )
      ((= what_next 1)
        (do_preview)
        (command ".VIEW" "_S" vw_name ".VIEW" "_D" "_begin")
      )
      ((= what_next 3)
        (do_pick)
      )
      ((= what_next 4)
        (do_preview)
        (getint "\n按<回车>返回对话框.")
      )
    )
  )
  (princ)
)
(defun c:dvpan ()
  (setvar "highlight" 0)
  (command ".dview" "ALL" "")
  (setvar "highlight" 1)
  (princ "\n调整图面位置, 点取参考点:")
  (command "PA" pause)
  (princ "\n点取到点:")
  (command pause)
  (command "X")
  (princ)
)
(defun c:dzoom (/ k p_tg p_cm lens wzq)
  (if (= (getvar "viewmode") 1)
    (progn
      (command ".ucs" "")
      (setq p_tg (getvar "target")
            p_cm (mapcar'+ p_tg (getvar "viewdir"))
            lens (getvar "lenslength")
      )
      (setq k (getstring "\n请输入当前视图放大倍数: "))
      (if (and
            k
            (numberp (setq k (read k)))
          )
        (progn
          (setq wzq (distance p_cm p_tg))
          (setq lens (/ (* k lens wzq) (+ wzq (- lens) (* k lens))))
          (command ".DVIEW" "" "_D" 1.0 "_Z" lens "_PO" p_tg p_cm "_x")
        )
      )
    )
    (prompt "\n* 不在透视状态.")
  )
  (princ)
)
[/php]

eachy

DCL文件，存储为qview.dcl放到同一Support目录。

2. 
   
3. // 快速透视
   
4. qview : dialog {
   
5.   label = "快速透视";
   
6.   : column {
   
7.     : row {
   
8.       : column {
   
9.       : edit_box {
   
10.          edit_width = 6 ;
    
11.          key = "z_cm" ;
    
12.          label = "照相机标高C:" ;
    
13.          width = 6 ;
    
14.          mnemonic = "C";
    
15.       }
    
16.       : edit_box {
    
17.          edit_width = 6 ;
    
18.          key = "z_tg" ;
    
19.          label = "目标点标高T:" ;
    
20.          mnemonic = "T";
    
21.       }
    
22.       : button {
    
23.          key = "position" ;
    
24.          label = "相机/目标定位P<:" ;
    
25.          mnemonic = "P";
    
26.       }
    
27.       }
    
28.       : column {
    
29.         : row {
    
30.         : edit_box {
    
31.            edit_width = 3;
    
32.            key = "lens" ;
    
33.            label = "焦距L:" ;
    
34.            mnemonic = "L";
    
35.         }
    
36.         : popup_list {
    
37.            key = "lens_list" ;
    
38.            edit_width = 5;
    
39.         }
    
40.         }
    
41.         : toggle {
    
42.            key = "tf_vp2" ;
    
43.            label = "两点透视B" ;
    
44.            mnemonic = "B";
    
45.         }
    
46. 
    
47.         : button {
    
48.           key = "preview";
    
49.           label = "预演Y<";
    
50.           mnemonic = "Y";
    
51.           width = 8;
    
52.         }
    
53.       }
    
54.     }
    
55.     : row {
    
56.       : boxed_row {
    
57.         : toggle {
    
58.           label = "储存视图C";
    
59.           key = "is_sv_vw";
    
60.           mnemonic = "C";
    
61.         }
    
62.         : edit_box {
    
63.           label = "视图名V";
    
64.           key = "vw_name";
    
65.           mnemonic = "V";
    
66.         }
    
67.       }
    
68.   }
    
69.   ok_cancel ;
    
70.   }
    
71. }
    
72. 
    
73. vw_cfm : dialog {
    
74.   label = "视图储存信息";
    
75.   : column {
    
76.     : text {
    
77.       label = "已有同样视图名, 是否覆盖?";
    
78.     }
    
79.     spacer_1;
    
80.     : row {
    
81.       : button {
    
82.         label           = "覆盖";
    
83.         key             = "accept";
    
84.         is_default      = true;
    
85.       }
    
86.       : button {
    
87.         label           = "重输";
    
88.         key             = "cancel";
    
89.         is_cancel       = true;
    
90.       }
    
91.     }
    
92.   }
    
93. }

<br /> // 快速透视<br /> qview : dialog {<br />   label = "快速透视";<br />   : column {<br />     : row {<br />       : column {<br />       : edit_box {<br />          edit_width = 6 ;<br />          key = "z_cm" ;<br />          label = "照相机标高C:" ;<br />          width = 6 ;<br />          mnemonic = "C";<br />       }<br />       : edit_box {<br />          edit_width = 6 ;<br />          key = "z_tg" ;<br />          label = "目标点标高T:" ;<br />          mnemonic = "T";<br />       }<br />       : button {<br />          key = "position" ;<br />          label = "相机/目标定位P<:" ;<br />          mnemonic = "P";<br />       }<br />       }<br />       : column {<br />         : row {<br />         : edit_box {<br />            edit_width = 3;<br />            key = "lens" ;<br />            label = "焦距L:" ;<br />            mnemonic = "L";<br />         }<br />         : popup_list {<br />            key = "lens_list" ;<br />            edit_width = 5;<br />         }<br />         }<br />         : toggle {<br />            key = "tf_vp2" ;<br />            label = "两点透视B" ;<br />            mnemonic = "B";<br />         }<br /> <br />         : button {<br />           key = "preview";<br />           label = "预演Y<";<br />           mnemonic = "Y";<br />           width = 8;<br />         }<br />       }<br />     }<br />     : row {<br />       : boxed_row {<br />         : toggle {<br />           label = "储存视图C";<br />           key = "is_sv_vw";<br />           mnemonic = "C";<br />         }<br />         : edit_box {<br />           label = "视图名V";<br />           key = "vw_name";<br />           mnemonic = "V";<br />         }<br />       }<br />   }<br />   ok_cancel ;<br />   }<br /> }<br /> <br /> vw_cfm : dialog {<br />   label = "视图储存信息";<br />   : column {<br />     : text {<br />       label = "已有同样视图名, 是否覆盖?";<br />     }<br />     spacer_1;<br />     : row {<br />       : button {<br />         label           = "覆盖";<br />         key             = "accept";<br />         is_default      = true;<br />       }<br />       : button {<br />         label           = "重输";<br />         key             = "cancel";<br />         is_cancel       = true;<br />       }<br />     }<br />   }<br /> }

zhynt

嗨！弄来弄去又弄回来了，呵呵。这个程序我前面已经贴了。

madbull

eachy  兄,用了你的东东,问题依旧啊?还是在R2000+版本里出问题.

eachy

最初由 madbull 发布
[B]eachy  兄,用了你的东东,问题依旧啊?还是在R2000+版本里出问题. [/B]

不明白你是什么问题？这个东东仅仅是Dv的组合没有用其他的。

                               
登录/注册后可看大图

madbull

我的问题是:模型在线框模式下,无论目标点与相机点有多远,生成的透视都只能看见建筑的局部.(如图)

madbull

我再次用了这个LIP，产生了如下问题：

madbull

2

madbull

3
可否请各位大侠示下：究竟是我对这个程序使用错误，还是这个程序有问题？各位大侠能否对此程序加以改进？
谢谢！

梦断江南

能把图发上来么？