[求助]：entmak 建立windows字体样式的问题.

xshrimp

[php]
;|
(gps->chk_style styname styshx stybig)
(gps->chk_style 字体样式名 西文字体名  中文字体名 )
检查给定字体名是否存在不存在则建立
存在则检查是否与给定字体名相同不同则修改该字体样式,修改默认字高为0.
设置完字体样式默认字高为0
优点:
避免了有的字体例如"hztxt0.shx"就不支持 "是否垂直? <N>"而造成command设置style命令出错的问题.
|;
(defun gps->chk_style (styname styshx stybig / chksty ent_list stybig2 styheight styshx2)
(if (null stybig) (setq stybig "")) ;使用windows 字体时.
(setq chksty (tblsearch "style" styname))
(if (null chksty)
    (ENTMAKE (LIST
           '(0 . "STYLE")                       ;对象名称
           '(100 . "AcDbSymbolTableRecord")
           '(100 . "AcDbTextStyleTableRecord")  ;子类标记
           (cons 2  styname)    ;字体样式名
           '(70 . 0)            ;标注位码
           '(40 . 0.0)          ;文字高度
           '(41 . 0.70)         ;宽度系数
           '(50 . 0.0)          ;字斜角
           '(71 . 0)            ;文字生成标注位码2＝反向，4＝颠倒
           (cons 3  styshx)     ;西文字体名
           (cons 4  stybig)     ;中文字体名
         ) ;_ end LIST
    ) ;_ end ENTMAKE
   ;检查存在字体样式与给定参数是否相等.
    (progn
    (setq ent_list (entget (tblobjname "style" styname)))
    (setq styshx2 (dxf 3 ent_list) stybig2 (dxf 4 ent_list) styheight (dxf 40 ent_list))
    ;检查中西文字体是否相同、及默认字高是否为0.
    (if (or (/= styshx styshx2) (/= stybig stybig2) (/= styheight 0))
            (progn
              (setq ent_list (subst (cons 40 0.0) (assoc 40 ent_list) ent_list))
              (setq ent_list (subst (cons 3 styshx) (assoc 3 ent_list) ent_list))
              (setq ent_list (subst (cons 4 stybig) (assoc 4 ent_list) ent_list))
              (entmod ent_list)      
            )
     )   
    );end progn
);end if
(setvar "textstyle" styname) ;当前文字样式
)[/php]

e.g.
(gps->chk_style "hxz" "hztxt_e.shx" "hztxt.shx")
(gps->chk_style "complex" "complex.shx" "") ;无中文字体名.

(gps->chk_style "黑体"   "SIMHEI.TTF" "")
(gps->chk_style "仿宋"   "SIMFANG.TTF" "")
(gps->chk_style "楷体"   "SIMKAI.TTF" "")
----------------------------------------------------------------------------
(gps->chk_style "宋体"   "SimSun.ttf" "")
(gps->chk_style "新宋体" "NSimSun.ttf" "")
---------------------------------------------------------------------------
黑体、仿宋、楷体建立都可以成功!!

问题.只有宋体、新宋体不成功............

windows字体
系统只有SimSun.ttc 不是SimSun.ttf.?什么?
SimSun.ttf   宋体     ;有问题????为什么!!!!!!
NSimSun.ttf  新宋

SIMKAI.TTF   楷体_bg2312
SIMFANG.TTF  仿宋_bg2312
SIMHEI.TTF   黑体.